Wake of Gods Forum | Форум Во Имя Богов

!#IF:V805/0 V944/0 V945/0 V946/0 V947/0 V948/0;
!#VRv1:C0/0/0/0/0/0;
!#UN:P800/?v1 P801/?v2 P802/?v3 P803/?v4 P804/?v5;
!#IF&v1=1:V944/1;
!#IF&v2=1:V945/1;
!#IF&v3=1:V946/1;
!#IF&v4=1:V947/1;
!#IF&v5=1:V948/1;

!?CM;
!!UN:P904/1 P905/0;
!!OB9808:T?v9828 U?v9829;
!!UN:P904/0 P905/?y99 P905/0;
!!FU&y99=0:E;
!!VRv9828:S-1;
!!VRv9829:S-1;

; СМЕШАННЫЕ НЕЙТРАЛЫ
!?FU22553;
!!VRz22&x1<5:S^1-4^;
!!VRz22&x1>4/x1<10:S^5-9^;
!!VRz22&x1>9/x1<20:S^10-19^;
!!VRz22&x1>19/x1<50:S^20-49^;
!!VRz22&x1>49/x1<100:S^50-99^;
!!VRz22&x1>99/x1<250:S^100-249^;
!!VRz22&x1>249/x1<500:S^250-499^;
!!VRz22&x1>499/x1<1000:S^500-999^;
!!VRz22&x1>999:S^1000+^;

!?CM&v9828=54/945;
!!VRv1:Cv9808/v9809/v9810;
!!PO1:N?y1;
!!OW:C?y-1; текущий игрок
!!FU29984:Py-1/4; перевод цвета игрока в биты [v4 - result]
!!TRv1/v2/v3:V?y-2; видимость точки
!!VRy-2:&v4; проверка на видимость
!!FU|y1<>7/y-2=0:E;
!!CM:R0;
!!PO1:V0/?y4 V1/?y6 V2/?y8;
!!VRy4&y4<0:+65536;
!!VRy5:Sy4:256;
!!VRy4:%256;
!!VRy6&y6<0:+65536;
!!VRy7:Sy6:256;
!!VRy6:%256;
!!VRy8&y8<0:+65536;
!!VRy9:Sy8:256;
!!VRy8:%256;
!!FU22505:P2/7;
!!OW:A-1/?y50;
!!IF:V3/0;
!!if&y50<>-1:;
    !!HEy50:S3/?y51;
    !!VRy51:*3;
    !!HEy50:P?y52/?y53/?y54;
    !!VRy52:-v9808;
    !!VRy52&y52<0:*-1;
    !!VRy53:-v9809;
    !!VRy53&y53<0:*-1;
    !!FU22504:Py52/y53/10;
    !!IF&v10<=y51:V3/1;
!!en:;
!!MO1:G?y2;
!!OB1:U?y3;
!!VRy40:S3;
!!VRy40&v9805=2:S5;
!!VRy40&v9805=3:S7;
!!MA:Fy3/?y19;
!!VRy19:*y2;
!!VRy19::y40;
!!if&v9805>=1:;
    !!VRy21:Sy2:y40;
    !!UN:N3/10/y3/1;
    !!FU22553&y21>0/-3:Py21;
    !!VRz9&y21>0/3:S^
{%Y21} %Z10^;
    !!VRz9&y21>0/-3:S^
{%Z22} %Z10^;
    !!MA:Fy4/?y20;
    !!VRy21:Sy19:y20;
    !!MA:Fy5/?y22;
    !!VRy23:Sy19:y22;
    !!UN:N3/10/y4/1;
    !!FU22553&y21>0/-3:Py21;
    !!VRz2&y21>0/3:S^
{%Y21} %Z10^;
    !!VRz2&y21>0/-3:S^
{%Z22} %Z10^;
    !!UN:N3/10/y5/1;
    !!FU22553&y23>0/-3:Py23;
    !!VRz3&y23>0/3:S^
{%Y23} %Z10^;
    !!VRz3&y23>0/-3:S^
{%Z22} %Z10^;
!!en:;
!!if&v9805>=2:;
    !!MA:Fy6/?y20;
    !!VRy21:Sy19:y20;
    !!MA:Fy7/?y22;
    !!VRy23:Sy19:y22;
    !!UN:N3/10/y6/1;
    !!FU22553&y21>0/-3:Py21;
    !!VRz4&y21>0/3:S^
{%Y21} %Z10^;
    !!VRz4&y21>0/-3:S^
{%Z22} %Z10^;
    !!UN:N3/10/y7/1;
    !!FU22553&y23>0/-3:Py23;
    !!VRz5&y23>0/3:S^
{%Y23} %Z10^;
    !!VRz5&y23>0/-3:S^
{%Z22} %Z10^;
!!en:;
!!if&v9805=3:;
    !!MA:Fy8/?y20;
    !!VRy21:Sy19:y20;
    !!MA:Fy9/?y22;
    !!VRy23:Sy19:y22;
    !!UN:N3/10/y8/1;
    !!FU22553&y21>0/-3:Py21;
    !!VRz6&y21>0/3:S^
{%Y21} %Z10^;
    !!VRz6&y21>0/-3:S^
{%Z22} %Z10^;
    !!UN:N3/10/y9/1;
    !!FU22553&y23>0/-3:Py23;
    !!VRz7&y23>0/3:S^
{%Y23} %Z10^;
    !!VRz7&y23>0/-3:S^
{%Z22} %Z10^;
!!en:;
!!VRz8:S^%Z199135
%Z9%Z2%Z3%Z4%Z5%Z6%Z7^;
!!IF:Q1/21/y3/4/z8;

!?BA0&v9711=1/945;
!!OB998:T?y1;
!!FU&y1<>54:E;
!!PO998:N?y1;
!!FU&y1<>7:E;
!!PO998:V0/?y4 V1/?y6 V2/?y8;
!!VRy4&y4<0:+65536;
!!VRy5:Sy4:256;
!!VRy4:%256;
!!VRy6&y6<0:+65536;
!!VRy7:Sy6:256;
!!VRy6:%256;
!!VRy8&y8<0:+65536;
!!VRy9:Sy8:256;
!!VRy8:%256;
!!MO998:G?y2;
!!OB998:U?y3;
!!VRy40:S3;
!!VRy40&v9805=2:S5;
!!VRy40&v9805=3:S7;
!!VRy99:Sy2:y40;
!!BA:M1/0/y3/y99 M1/1/-1/0 M1/2/-1/0 M1/3/-1/0 M1/4/-1/0 M1/5/-1/0 M1/6/-1/0;
; <## ЗАПЛАТКА НА ИСПРАВЛЕНИЕ БАГА: 0 НЕЙТРАЛОВ 30.05.09 [5.17] ##>
!!BA&y99=0:M1/0/-1/0;
!!MA:Fy3/?y19;
!!VRy19:*y2;
!!VRv9830:%y40;
!!VRy19::y40;
!!if&v9805>=1:;
    !!MA:Fy4/?y20;
    !!VRy21:Sy19:y20;
    !!VRy77:Sy19%y20;
    !!VRv9830:+y77;
    !!MA:Fy5/?y22;
    !!VRy23:Sy19:y22;
    !!VRy77:Sy19%y22;
    !!VRv9830:+y77;
    !!BA&y21>0:M1/1/y4/y21;
    !!BA&y23>0:M1/2/y5/y23;
!!en:;
!!if&v9805>=2:;
    !!MA:Fy6/?y20;
    !!VRy21:Sy19:y20;
    !!VRy77:Sy19%y20;
    !!VRv9830:+y77;
    !!MA:Fy7/?y22;
    !!VRy23:Sy19:y22;
    !!VRy77:Sy19%y22;
    !!VRv9830:+y77;
    !!BA&y21>0:M1/3/y6/y21;
    !!BA&y23>0:M1/4/y7/y23;
!!en:;
!!if&v9805=3:;
    !!MA:Fy8/?y20;
    !!VRy21:Sy19:y20;
    !!VRy77:Sy19%y20;
    !!VRv9830:+y77;
    !!MA:Fy9/?y22;
    !!VRy23:Sy19:y22;
    !!VRy77:Sy19%y22;
    !!VRv9830:+y77;
    !!BA&y21>0:M1/5/y8/y21;
    !!BA&y23>0:M1/6/y9/y23;
!!en:;

!?BA1|v9711=1/v9711=8;
!!PO998:N?y1;
!!FU&y1<>7/y1<>10:E;
!!if&v9804=1:;
    !!VRv2:Cv998/v999/v1000;
    !!PO2:N0 H?y2;
    !!FU&y2=255:E;
    !!VRy2:-1;
    !!IF&1000:Q1/8/y2/1/z199136;
    !!HE-1:A4/y2;
    !!PO2:H255;
    !!FU:E;
!!en:;
!!if&v9711=1/945:;
    !!BA:M1/0/?y1/?y2 M1/1/?y3/?y4 M1/2/?y5/?y6 M1/3/?y7/?y8 M1/4/?y9/?y10 M1/5/?y11/?y12 M1/6/?y13/?y14;
    !!VRy16:S0;
    !!MA&y2<>0:Fy1/?y15;
    !!VRy15:*y2;
    !!VRy16&y2<>0:+y15;
    !!MA&y4<>0:Fy3/?y15;
    !!VRy15:*y4;
    !!VRy16&y4<>0:+y15;
    !!MA&y6<>0:Fy5/?y15;
    !!VRy15:*y6;
    !!VRy16&y6<>0:+y15;
    !!MA&y8<>0:Fy7/?y15;
    !!VRy15:*y8;
    !!VRy16&y8<>0:+y15;
    !!MA&y10<>0:Fy9/?y15;
    !!VRy15:*y10;
    !!VRy16&y10<>0:+y15;
    !!MA&y12<>0:Fy11/?y15;
    !!VRy15:*y12;
    !!VRy16&y12<>0:+y15;
    !!MA&y14<>0:Fy13/?y15;
    !!VRy15:*y14;
    !!VRy16&y14<>0:+y15;
    !!VRy16:+v9830;
    !!OB998:U?y15;
    !!MA:Fy15/?y17;
    !!VRy18:Sy16:y17;
    !!BA:M1/0/y15/y18 M1/1/-1/0 M1/2/-1/0 M1/3/-1/0 M1/4/-1/0 M1/5/-1/0 M1/6/-1/0;
!!en:;

!?FU22551;
; кол-во монстров на карте
; тип арта
; номер арта
; шанс 1..100
!!UN:U54/-1/-1/2;
!!PO2:N7;
; <## ГЕНЕРАЦИЯ СЛУЧАЙНЫХ ПРИЗОВЫХ АРТЕФАКТОВ 28.04.09 [22.49]
!!PO2:H?y11;
!!if&y11=255:;
    !!VRy12:S1 R99;
    !!VRy11:S254;
    !!VRy10:S0;
    !!VRy10&y12<=20:S2; мелкие
    !!VRy10&y12<=10:S4; средние
    !!VRy10&y12<=5:S8; крупные арты
    !!UN&y10<>0:J6/y10/?y11;
    !!VRy11:+1;
    !!PO2:Hy11;
!!en:;
; ##>
!!OB2:U?y1;
!!MO2:G?y2;
!!MA:Ly1/?y99;
!!VRy3:S8-y99;
!!VRy3&y3<1:S1;
!!VRy3&y3=8:S5;
!!VRy2:*y3;
!!MO2:Gy2;
!!VRy4:S0 R144;
!!VRy4|y4=122/y4=124/y4=126/y4=128:S143;
!!VRy5:S0 R144;
!!VRy5|y5=122/y5=124/y5=126/y5=128:S143;
!!VRy6:S0 R144;
!!VRy6|y6=122/y6=124/y6=126/y6=128:S143;
!!VRy7:S0 R144;
!!VRy7|y7=122/y7=124/y7=126/y7=128:S143;
!!VRy8:S0 R144;
!!VRy8|y8=122/y8=124/y8=126/y8=128:S143;
!!VRy9:S0 R144;
!!VRy9|y9=122/y9=124/y9=126/y9=128:S143;
!!VRy5:*256+y4;
!!VRy7:*256+y6;
!!VRy9:*256+y8;
!!PO2:V0/y5 V1/y7 V2/y9;

!?TM1&v2392=1/v2391=1/945;
; кол-во монстров на карте
!!UN:U54/-1/?v600;
!!FU&v600=0:E;
!!VRv2:C-1/0/0;
!!VRy2:S0 T2000000000 R1/y2;
!!DO22551/1/v600/1:P;

!?OB91&1000;При посещении человеком объекта...
   !!OBv998/v999/v1000 : M-1/1/0;Убираем стандартное собщение.
   !!POv998/v999/v1000 : N?y-1;Проверяем, посещён ли объект.
   !!IF&y-1=1 : M^Надпись неразборчива.^;Если объект посещён, выводим сообщение.
   !!FU&y-1=1 : E;Если объект посещён, выходим из триггера.
   !!VRz10 : S^Куда пойдёшь?^;Устанавливаем текст вопроса.
   !!VRz11 : S^Налево.^;Устанавливаем текст 1 варианта ответа.
   !!VRz12 : S^Направо.^;Устанавливаем текст 2 варианта ответа.
   !!VRz13 : S^Прямо.^;Устанавливаем текст 3 варианта ответа.
   !!VRz14 : S^Прочь отсюда.^;Устанавливаем текст 4 варианта ответа.
   !!IF:G1/5001/0/10/11/12/13/14;Вызываем диалог.
   !!FU&v5001=8 : E;Если выбран 4 вариант ответа, выходим из триггера.
   !!VRy-1 : R165;Генерируем случайный номер монстра.
   !!VRy-1&y-1>121 : Sy-1+1;Исключаем 1 неиспользуемого монстра.
   !!VRy-1&y-1>123 : Sy-1+1;Исключаем 2 неиспользуемого монстра.
   !!VRy-1&y-1>125 : Sy-1+1;Исключаем 3 неиспользуемого монстра.
   !!VRy-1&y-1>127 : Sy-1+1;Исключаем 4 неиспользуемого монстра.
   !!VRy-1&y-1>144 : Sy-1+5;Исключаем боевые машины и стрелковые башни.
   !!VRy-1&y-1>159 : Sy-1+4;Исключаем Эмиссаров.
   !!VRy-1&y-1>173 : Sy-1+18;Исключаем командиров.
   !!MA : Cy-1/6/?y-2;Считываем стоимость монстра.
   !!VRy-3 : S30000:y-2;Вычисляем количество монстров исходя из стоимости.
   !!HE-1 : Tv998/v999/v1000/y-1/y-3;Вызываем сражение с этими монстрами.
   !!HE-1 : O?y-1;Проверяем, победил ли герой (проверяем его хозяина после битвы), если нет - в переменную попадёт -1.
   !!FU&y-1=-1 : E;Если герой проиграл, выходим из триггера.
   !!VRy-1 : R2;Генерируем случайный номер награды.
   !!IF&y-1=0 : M^Вы получаете по 10 каждого ресурса!^;Если номер награды равен 1, выводим сообщение.
   !!OW&y-1=0 : R-1/0/d10 R-1/1/d10 R-1/2/d10 R-1/3/d10 R-1/4/d10 R-1/5/d10;Если номер награды равен 1, даём игроку по 10 каждого ресурса.
   !!IF&y-1=1 : M^Вы получаете 40 кабанов!^;Если номер награды равен 2, выводим сообщение.
   !!HE-1&y-1=1 : C2/140/40/1;Если номер награды равен 2, даём герою 40 кабанов.
   !!IF&y-1=2 : M^Вы получаете Голубку Удачи!^;Если номер награды равен 3, выводим сообщение.
   !!HE-1&y-1=2 : A4/48;Если номер награды равен 3, даём герою Голубку удачи.
   !!POv998/v999/v1000 : N1;Устанавливаем объекту флаг посещённости.

!#TM51 : S30/30/7/1;Устанавливаем таймер на 30 день.

!?TM51;При срабатывании таймера...
   !!VRv62 : S-1;Подготавливаем x-координату к поиску координат шахт.
   !!UN : U53/-1/?y1;Считаем количество шахт на карте.
   !!DO91/1/y1/1 : P53;Запускаем цикл, находящий и устанавливающий все шахты на карте.

!?FU91;Функция поиска и установки шахты.
   !!UN : Ux1/-1/-1/62;Находим координаты шахты.
   !!MNv62/v63/v64 : O-1;Делаем шахту нейтральной.
   !!VRy1 : R165;Генерируем случайный номер монстра.
   !!VRy1&y1>121 : Sy1+1;Исключаем 1 неиспользуемого монстра.
   !!VRy1&y1>123 : Sy1+1;Исключаем 2 неиспользуемого монстра.
   !!VRy1&y1>125 : Sy1+1;Исключаем 3 неиспользуемого монстра.
   !!VRy1&y1>127 : Sy1+1;Исключаем 4 неиспользуемого монстра.
   !!VRy1&y1>144 : Sy1+5;Исключаем боевые машины и стрелковые башни.
   !!VRy1&y1>159 : Sy1+4;Исключаем Эмиссаров.
   !!VRy1&y1>173 : Sy1+18;Исключаем командиров.
   !!MA : Cy1/6/?y2;Считываем стоимость монстра.
   !!VRy3 : S30000:y2;Вычисляем количество монстров исходя из стоимости.
   !!MNv62/v63/v64 : M0/-1/0;Обнуляем охрану шахты.
   !!MNv62/v63/v64 : M1/-1/0;Обнуляем охрану шахты.
   !!MNv62/v63/v64 : M2/-1/0;Обнуляем охрану шахты.
   !!MNv62/v63/v64 : M3/y1/y3;Устанавливаем этих монстров на охрану шахты.
   !!MNv62/v63/v64 : M4/-1/0;Обнуляем охрану шахты.
   !!MNv62/v63/v64 : M5/-1/0;Обнуляем охрану шахты.
   !!MNv62/v63/v64 : M6/-1/0;Обнуляем охрану шахты.