ZVSE
!?BG&v997>-1;
!!BG:A?v2;
!!BG&v2=7:N?v3;
!!BMv3&v2=7:T?v4;
!!BG&v2=7/v4=41:E?v5;
!!BMv5&v2=7/v4=41:P?v6;
!!FU|v2<>7/v4<>41/v6<=-1:E;
!!VRv7:S0 R3;
!!BMv3&v7=0:C42/v6/2/0/1;
!!BMv3&v7=1:C45/v6/2/0/1;
!!BMv3&v7=2:C54/v6/2/0/1;
!!BMv3&v7=3:C62/v6/2/0/1;

********************************************************************************​*******
!#UN:C7961093/1/1;
!#UN:C7960905/1/01;
!#UN:C7960117/1/1;
!#MA:B130/3;
монстр 130 колдует Случайное не обязательно дружественное заклинание на дружественный отряд ....
отряд выбираешь сам
********************************************************************************​*******

** активация при действии в бою ********************************************************************************​************
** Опция: 890 Волшебная стрела маны
!?BG0;
!!UN:P890/?y1; [проверяем включена ли опция 890 в y1]
!!FU&y1=0:E; [выход, если опция не включена]
!!BG:A?y1; [y1 - тип действия (1 - герой колдует заклинание)]
!!BG&y1=1:S?y2; [y2 - номер заклинания (если герой колдует)]
!!FU|y2<>15/y1<>1:E; [Выход если герой не колдует волшебную стрелу]
!!BG:H?y1; [y1 - номер героя]
!!HEy1:I?y2; [y2 - количество маны]
!!HEy1:Fd/d/?y3/d; [y3 - сила магии героя]
!!HEy1:S14/?y4; [y4 - Уровень навыка Огня героя (0..3)]
!!HEy1:S15/?y5; [y5 - Уровень навыка Воздуха героя (0..3)]
!!HEy1:S16/?y6; [y6 - Уровень навыка Воды героя (0..3)]
!!HEy1:S17/?y7; [y7 - Уровень навыка Земли героя (0..3)]
!!VRy4&y4<y5:Sy5; [---------------------------------------------]
!!VRy4&y4<y6:Sy6; [y4 - бонус к урону зависящий от максимального]
!!VRy4&y4<y7:Sy7; [из уровней Школ магии (Мана*0...Мана*3) ]
!!VRy4:*y2; [---------------------------------------------]
!!HEy1&y1=138:Ed/?y5; [y5 - Уровень героя, если это Циэль (спец по волшебной. стреле)]
!!VRy6:Sy3 *y2 +y4; [Расчет базового урона SP*Mana (+Mana) (+Mana*2) (+Mana*3)]
!!VRy7&y1=138:Sy6 *y5 :20; [Расчет бонуса урона для Циэль (+5% за уровень)]
!!VRy6&y1=138:+y7; [Корректировка базового урона для Циэль, y6 = новый урон]
!!HEy1:O?y8; [y8 - номер игрока]
!!OW:Iy8/?y9; [y9=1 для ИИ, 0 для человека]
!!VRv750:S0; [обнуление v750]
!!VRz880&y9=0:Sz179011; [для игрока-человека получаем текст вопроса в z880]
!!IF&y9=0:Q1/9/15/2/z880; [для игрока-человека вопрос: вложить ли всю ману в заклинание]
!!VRv750|1/y9=1:Sy6; [v750 - новый урон Волшебной стрелы]
   
** активация перед расчетом сопротивления ********************************************************************************​************
** Опция: 890 Волшебная стрела маны
!?MR0;
!!UN:P890/?y1; [проверяем включена ли опция 890 в y1]
!!FU&y1=0:E; [выход, если опция не включена]
!!BG:A?y1; [y1 - тип действия (1 - герой колдует заклинание)]
!!BG&y1=1:S?y2; [y2 - номер заклинания (если герой колдует)]
!!FU|y2<>15/v750=0:E; [Выход если герой не колдует волшебную стрелу или если новый урон Волшебной стрелы = 0]
!!MR:D?y1; [y1 - базовый урон заклинания]
!!BG:H?y2; [y2 - номер героя]
!!BG:E?y3; [y3 - номер целевого стека]
!!MR&y1<v750:Dv750; [Установка нового базового урона заклинания, если он не меньше стандартного]
!!HEy2&y1<v750:I0; [Обнуление маны героя]
!!BMy3&y1<v750:V64 V64; [Дополнительная анимация на целевом стеке]
!!VRv750:S0; [обнуление v750]

ZVSE
ERMS_ScriptName=Guardians
ERMS_ScriptAuthor=Sav
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=30.9(September).2010
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=Русский or русский (native)
ERMS_ScriptUsedFunctions=90-91
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
!?BR&v997=-1/1000;В начале боя человека...
    !!DO90/0/41/1:P9/0;Вызываем цикл, вызывающий стражу всех стеков.
    !!BU:R;Обновляем.

;Функции вызова стражи.
!?FU90;Функция поиска гексов для стражи.
    !!BMx16:T?y7;Проверяем тип монстра.
    !!FU&y7<>x1:E;Если монстр не подходит, выходим из функции.
    !!BMx16:P?y7;Считываем позицию монстра.
    !!VRy8:Sy7:17;Вычисляем ряд позиции монстра.
    !!VRy9:Sy8%2;Вычисляем чётность ряда позиции монстра.
    !!VRy1:Sy7-1;Вычисляем позицию 1 стражи.
    !!VRy2&y9=0:Sy7-17;Вычисляем позицию 2 стражи, в зависимости от чётности ряда позиции монстра.
    !!VRy2&y9=1:Sy7-18;Вычисляем позицию 2 стражи, в зависимости от чётности ряда позиции монстра.
    !!VRy3:Sy2+1;Вычисляем позицию 3 стражи.
    !!VRy4:Sy7+1;Вычисляем позицию 4 стражи.
    !!VRy5:Sy2+35;Вычисляем позицию 5 стражи.
    !!VRy6:Sy5-1;Вычисляем позицию 6 стражи.
    !!BMx16:B?y10;Считываем количество монстров.
    !!BMx16:I?y11;Считываем сторону монстра.
    !!DO91/1/6/1:Py1/y2/y3/y4/y5/y6/y10/x2/y11;Вызываем цикл, вызывающий стражу на каждую клетку.
!?FU91;Функция постановки стражи на гекс.
    !!VRy1:Sxx16%17;Считываем столбец позиции монстра.
    !!FU&y1=0|y1=16/xx16<1/xx16>185:E;Если гекс вне поля боя, завершаем функцию.
    !!BU:Oxx16/?y1;Проверяем, нет ли препятствий на гексе.
    !!FU&y1>0:E;Если на гексе есть препятствия, завершаем функцию.
    !!BU:Exx16/?y1;Проверяем, нет ли стека на гексе.
    !!BMy1&y1>-1:T?y2;Если на гексе есть стек, проверяем тип монстра стека.
    !!BMy1&y1>-1/y2=x8:Ndx7;Если на гексе есть стек и его тип монстра - нужный, добавляем туда нужное количество монстров.
    !!FU&y1>-1:E;Если на гексе есть стек, завершаем функцию.
    !!BU:Sx8/x7/xx16/x9/-1/0;Вызываем стражу на гекс.

вот пример - пусть Монах в начале каждого раунда поочерёдно обкастовывает Лечением все стеки Мечников:
   
!?BR&v997>=0;
!!VRv10:S-1;
!!DO10/0/20/1:P;
!!DO11/0/20/1&v10>-1:P;

!?FU10;
!!BMx16:T?y1;
!!BMx16&y1=8:N?y2;
!!BMx16&y1=8/y2>=1:I?y3;
!!VRv10&y1=8/y2>=1/y3=0:Sx16;

!?FU11;
!!BMx16:T?y1;
!!BMx16&y1=6:N?y2;
!!BMx16&y1=6/y2>0:I?y3;
!!BMx16&y1=6/y2>0/y3=0:P?y4;
!!BMv10&y1=6/y2>0/y3=0/x16<>v10:C37/y4/0/0/1;

Данный скрипт сработает только для левого (атакующего) героя
********************************************************************************​*********
Если на любых - то тогда всё намного проще. Тупо заставляем того монаха колдовать на себя Экспертное лечение, и всё:

!?BR&v997>=0;
!!DO10/0/20/1:P;

!?FU10;
!!BMx16:T?y1;
!!BMx16&y1=8:N?y2;
!!BMx16&y1=8/y2>=1:I?y3;
!!BMx16&y1=8/y2>=1/y3=0:P?y4;
!!BMx16&y1=8/y2>=1/y3=0:C37/y4/3/0/1;


*************************************************************