Threaded Mode | Linear Mode

Berserker · 24.10.2020 02:42

Заменяем:

!?CM5; кликаем
!!VRv1:C0/0/0;
!!CM:F?(clickFlag:y); какой флаг клика
!!FU&(clickFlag)<>4:E; если не Cntrl+ЛКМ - выход
!!CM:P?v1/?v2/?v3; координаты клика
!!OB1:T?(objType:y); тип объекта
; если кликнул на палатку
!!FU(Tent)&(objType)=10:P21;

На:

!?FU(OnAdventureMapLeftMouseClick);
!!CM:F?(clickFlags:y);
!!FU&(clickFlags)<>(MOUSE_FLAG_CTRL):E;
!!CM:P?(x:y)/?(y:y)/?(z:y);
!!OB(x)/(y)/(z):T?(objType:y);
; Обработать (handle) щелчок по палатке ключника с передачей координат в функцию
!!FU(serg_HandleKeymastersTentClick)&(objType)=(OBJ_KEYMASTERS_TENT):P(x)/(y)/(z);

Berserker · 24.10.2020 02:50

!?FU(Tent);
!!OB1:U?(colTent:y); узнаю подтип палатки (цвет)
!!re i/0/7: ;
!!SN:W^%i_%(colTent)^/?yx1;
!!VRx1:+1;
!!en: ;
; в сообщении просто цветом чисел выделяем игроков
!!IF:M^ {~Salmon}СКОЛЬКО РАЗ ИГРОКИ ПОСЕТИЛИ ПАЛАТКУ{~}
{-----------------------------------------------------------------------------------------}
{~OrangeRed}%Y21{~} {~DodgerBlue}%Y22{~} {~Peru}%Y23{~} {~Green}%Y24{~} {~Orange}%Y25{~} {~BlueViolet}%Y26{~} {~SkyBlue}%Y27{~} {~HotPink}%Y28{~}^;

Заменить на:

!?FU(serg_HandleKeymastersTentClick);
; Функция принимает 3 параметра: x/y/z
!#VA(x:x) (y:x) (z:x);
!!OB(x)/(y)/(z):U?(tentColor:y);
; Выделим массив из 8 счётчиков посещений по цвету игроков
!#VA(visits[8]:y);
; Пройдёмся по элементам массива
; Здесь и далее суффикт "Ptr" означает Pointer (указатель), то есть переменная реально хранит индекс другой переменной
!!re i/(PLAYER_FIRST)/(PLAYER_LAST):;
!!VR(visitPtr:y):S(@visits) +i; @visits - это индекс первого элемента массива, его виртуальный «адрес» (@)
; Если прибавить к нему номер итерации i, получим индекс текущего элемента в массиве
!!SN:W^serg_tent_visits_%(tentColor)_%i^/?y(visitPtr);
!!en: ;
; в сообщении просто цветом чисел выделяем игроков
!!IF:M^ {~Salmon}СКОЛЬКО РАЗ ИГРОКИ ПОСЕТИЛИ ПАЛАТКУ{~}
{-----------------------------------------------------------------------------------------}
{~OrangeRed}%(visits[0]){~} {~DodgerBlue}%(visits[1]){~} {~Peru}%(visits[2]){~} {~Green}%(visits[3]){~} {~Orange}%(visits[4]){~} {~BlueViolet}%(visits[5]){~} {~SkyBlue}%(visits[6]){~} {~HotPink}%(visits[7]){~}^;

SergOz · 24.10.2020 03:00

Berserker, да, точно - в функцию можно передать координаты через х1, х2, х3.
Насчёт всего остального понял. Спасибо!

P.S. А вот с циклом нужно разобраться. Много нового.

Berserker · 24.10.2020 03:16

Смотри, я прохожусь от i = цвет первого игрока до цвет последнего игрока
Вот эти константы:

!#DC(PLAYER_FIRST) = 0;
!#DC(PLAYER_RED) = 0;
!#DC(PLAYER_BLUE) = 1;
!#DC(PLAYER_TAN) = 2;
!#DC(PLAYER_GREEN) = 3;
!#DC(PLAYER_ORANGE) = 4;
!#DC(PLAYER_PURPLE) = 5;
!#DC(PLAYER_TEAL) = 6;
!#DC(PLAYER_PINK) = 7;
!#DC(PLAYER_LAST) = 7;

Далее, тебе нужен был массив из 8 счётчиков. Скажем, visits[8] выделит
[y20, y21, y22, y23, y24, y25, y26, y27] под это дело.

visits[0], где 0 - логический индекс элемента в массиве (всегда от нуля), скомпилируется в y20.
visits[1] в y21 и т.д.

А @visits или @visits[0] скомпилируется в индекс без y-префикса: 20.

@visits[0] = 20
@visits[7] = 27.

Тогда данная строка просто вычислит индекс y-переменной счётчика для i-го игрока
!!VR(visitPtr:y):S(@visits) +i;
=>
!!VR(visitPtr:y):S20 +i;

А значит y(visitPtr) означает y20..y27 поочерёдно. То есть буквально y-переменная с индексом, хранимым как число в переменной (visitPtr)

SergOz · 24.10.2020 03:23

Berserker, а с какой версии Эры начинают работать !?OB(OBJ_KEYMASTERS_TENT); и другие константы?
И где можно скачать эту версию, если нет доступа к Яндексу?

Bes · 24.10.2020 03:29

Вот же...

(24.10.2020 01:32)Berserker Wrote: Обновление: https://dropmefiles.com/PSvrC

Berserker · 24.10.2020 04:14

С 3.0.1, если не ошибаюсь. Но мод Era Erm Framework (должен быть включён) обновляется с каждым релизом Эры.

Berserker · 25.10.2020 06:25

Задача: сделать возможным переопределять глобальные переменные мода из json-конфига с поддержкой констант.
Требования: Era 3.2.0+, Erm Framework Mod 3.2.0+
Решение:

; ============== PUBLIC ==============
; Объявляем сами переменные и даём им в коде значения по умолчанию
!#VRi^mix_minNumNeutralStacks^:S1; Minimum number of mixed neutral stacks in battle.
!#VRi^mix_maxNumNeutralStacks^:S4; Maximum Number of mixed neutral stacks in battle.
!#VRi^mix_neutralStackSpread^:S(MIX_SPREAD_SPACE_BETWEEN); Default spread strategy for neutral stacks.
!#VRi^mix_neutralStackScale^:S125; Multiplier for original neutrals quantity on adventure map in percents.
!#VRi^mix_netralStackScaleForHuman^:S200; Additional multiplier of neutrals power only for humans in percents.
!#VRi^mix_noNeutralsMorale^:S(TRUE); If true, neutrals will have no morale at all.
!#VRi^mix_generateMonstersByFactions^:S(TRUE); If true, additional generated monsters will belong to the same faction.
!#VAi^mix_allowAlliedFactions^:S(TRUE); If true, allied faction monsters will also be generated.
!#VRi^mix_moveNeutralsToFactions^:S(TRUE); If true, all WoG neutral monsters will be assigned a faction / town.
!#VRi^mix_registerRegularMonsters^:S(TRUE); If true, all regular WoG creatures are registered and will become accessible for generation.
!#VRi^mix_registerFactionAllies^:S(TRUE); If true, configurates each faction allies and their association level.
; ============ END PUBLIC ============
; Позволяет переопределять переменных в json-конфиге (из папки Lang)
!?FU(mix_LoadGlobalConfig);
; Loads global settings from json
!!FU(NewStrArray):P?(configRules:y); создали временный массив строк
; Заполнили массив именами глобальных переменных, значения которых можно переопределять
!!FU(Array_Push):P(configRules)/^minNumNeutralStacks^/^maxNumNeutralStacks^/^neutralStackSpread^/^neutralStackScale^/^netralStackScaleForHuman^/^noNeutralsMorale^/
^generateMonstersByFactions^/^allowAlliedFactions^/^moveNeutralsToFactions^/^registerRegularMonsters^/^registerFactionAllies^;
; Подсчитали, сколько поддерживаем таких глобальных переменных
!!SN:M(configRules)/?(numConfigRules:y);
; Для каждого имени переменной
!!re i/0/(numConfigRules)/1/-1:;
!!SN:V(configRules)/i/?(configRuleVarName:z); получили имя переменной
!!VR(key:z):S^mix.global.%(configRuleVarName)^; сформировали ключ для перевода
!!SN:T(key)/?(strValue:z); получили строковое значение из json. Если значения не будет, оно будет установлено в значение запрошенного ключа (key)
; например, %T(a.b.c) вернёт "a.b.c", если такого ключа не найдено
!!SN:C(strValue)/?(intValue:y)/(constExists:y); ищем по строковому значению константу
!!if&(constExists)=(TRUE):; константа была найдена, перезаписываем глобальную переменную
!!VRi^mix_%(configRuleVarName)^:S(intValue);
!!el&(key)<>(strValue):; константа не была найдена, но значение отличается от ключа, значит оно в json имеется
!!VR(intValue):V(strValue); конвертируем строку в целое числи
!!VRi^mix_%(configRuleVarName)^:S(intValue); перезапишем глобальную переменную
!!en;
!!en:;
!#FU(mix_LoadGlobalConfig):P; незамедлительно загружаем json-конфиг ещё до события OnAfterErmInstructions

SergOz · 25.10.2020 12:24

Berserker, спасибо за код скрипта с палатками. Разобрался полностью.

(24.10.2020 04:14)Berserker Wrote: Задача: сделать возможным переопределять глобальные переменные мода из json-конфига с поддержкой констант.

Если можно, то небольшой пример, пожалуйста, в каких целях это можно применить

Berserker · 25.10.2020 16:08

SergOz, я выпускаю мод на смешанные нейтралы с json-файлом настроек в Lang. Ты выпускаешь свой мини-мод настроек смешанных нейтралов по каждому типу монстров и заодно меняешь глобальные настрйки так:

Code:

{

  "mix": {

    "global": {

      "minNumNeutralStacks":        "2",                // Minimum number of mixed neutral stacks in battle.

      "maxNumNeutralStacks":        "4",                // Maximum Number of mixed neutral stacks in battle.

      "neutralStackSpread":         "MIX_SPREAD_SPACE_BETWEEN", // Default spread strategy for neutral stacks.

                                                        // Possible values:"sp_no", "sp_random", "sp_top_down", "sp_near_center", "sp_away_form_center", "sp_space_between".

      "neutralStackScale":          "125",              // Multiplier for original neutrals quantity on adventure map in percents.

      "netralStackScaleForHuman":   "200",              // Additional multiplier of neutrals power only for humans in percents.

      "noNeutralsMorale":           "1",                // If 1, neutrals will have no morale at all.

      "generateMonstersByFactions": "1",                // If 1, additional generated monsters will belong to the same faction.

      "allowAlliedFactions":        "1",                // If 1, allied faction monsters will also be generated.

      "moveNeutralsToFactions":     "1",                // If 1, all WoG neutral monsters will be assigned a faction / town.

      "registerRegularMonsters":    "1",                // If 1, all regular WoG creatures are registered and will become accessible for generation.

      "registerFactionAllies":      "1",                // If 1, configurates each faction allies and their association level.

    },

    "mon173": {

      "custom": "1",

      "slot0": {

        "type": "MIX_MON_TYPE_ALLIED_FACTION",

      }

    }

  }

}

Мой мод отображает глобальные настройки из json на глобальные именованные переменные. А ты, как пользователь-настройщик, в ЕРМ файлы не лезешь, но можешь использовать константы в виде значений. Скажем, тебе нужно в слоте сгенерировать монстра той же фракции или союзной фракции.
Ты пишешь: "type": "MIX_MON_TYPE_ALLIED_FACTION" вместо -3, например.

Bes · 25.10.2020 19:01

Berserker, как я понимаю, последовательность !?FU и !#VA не принципиальна, и можно
в обратном порядке вызывать?

!#VA:(name:y);
!?FU(OnAnyEvent);
...
; (-name) можно же удалять глобальные локальные переменные как локальные?

SergOz · 25.10.2020 19:15

Berserker, в коментах научных каналов часто можно видеть такое:
"Ничего не понятно, но афигенно интересно".
Здесь примерно то же самое, но суть я уловил. Перечитывая, раза с N-ного дойдёт.

Спасибо!

Berserker · 25.10.2020 21:43

Bes, нельзя.
Глобальные переменные — это i^..^, s^...^. а (такиеПеременные) — сугубо локальные от !?XX до следующего !?XX.

Bes · 25.10.2020 21:54

а чего тогда ты сделал объявление локальной через синтаксис !# ? (сразу провокация на выход из твоих примеров использования 148

)

Berserker · 25.10.2020 22:33

Чтобы выделить данную конструкцию визуально. Она работает только на этапе прекомпиляции как команда-пустышка, но все объявленные в ней переменные остаются.
Иными словами нет разницы между:

!!VR(spisok[3]:y):C100/200/300;

и

!#VA(spisok[3]:y); будет удалено, но переменная spisok[3] останется объявленной
!!VR(spisok):C100/200/300;

Threaded Mode \| Linear Mode Школа ERM 2 » ERM 2.0 для ERA III
Author	Message