Threaded Mode | Linear Mode

Bes · 23.10.2020 20:50

SergOz, меня уже Berserker осадил этим:

Quote:внутри %I() нельзя использовать проценты.

SergOz · 23.10.2020 21:01

(23.10.2020 20:17)Berserker Wrote: внутри %I() нельзя использовать проценты.

И нельзя принудительно задавать ID ни в i^...^, ни в (...:y).
Только автоматическое выделение.

Berserker · 23.10.2020 21:54

SergOz, но работает синтаксис ^%y(somePtr)^ или y(somePtr). Если я верно понял часть вопроса.

Bes · 23.10.2020 22:25

Quote:И нельзя принудительно задавать ID ни в i^...^

хм, точно нельзя?
Ведь если в SN:W^^ можно
а

!!VRy1:S10;
!!SN:W^var%Y1^/55; = !!VRi^var10^:S55;

то почему i^var%y1^ не поддерживается?

SergOz · 23.10.2020 22:39

Bes, как я понял в i^var%y1^ значение y1 будет восприниматься как имя, а не как ID. Само имя и будет ID, но, хз какое оно (автовыделение) и где его искать.
Berserker, а нужно ли перед первым чтением из, например,

!!SN:W^%(colPlayer)_%(colTent)^/?i^visit%(colPlayer)%(colTent)^;

писать

!!VRi^visit%(colPlayer)%(colTent)^:S0;

?

Berserker · 23.10.2020 22:51

Внутри i^...^ идёт обычная интерполяция, как и внутри ^...^. Там можно что угодно использовать. Например, значения локальных переменных:

i^battle_hero_%(stackSide)^.
или, упаси боже,
i^battle_hero_%v9950^.

Даже в простом варианте можно сослаться на другую глобальную переменную:

!!VRi^battle_side^:S(BATTLE_LEFT);
...
i^battle_hero_%I(battle_side)^

Bes · 24.10.2020 00:13

но при всём при этом нельзя такую солянку в диалоге отобразить? странно
Dry

!!VRi^battle_hero_%v9950^:S?(var_copy:y); ### ERA3 не поддерживает такой GET-syntax ###
!!IF:M^%(var_copy)^; correct
!!IF:M^%I(battle_hero_%v9950)^; not correct

SergOz · 24.10.2020 00:20

Bes, !!IF:M^%i(battle_hero_%v9950)^;
нижний регистр i

Berserker · 24.10.2020 00:26

S больше не поддерживает GET-syntax.

!!IF:M^%I(battle_hero_%v9950)^; not correct
Так нельзя, поскольку это вложенный % в %I(). Интерполяция внутри интерполяции не поддерживается.

Bes · 24.10.2020 00:42

(24.10.2020 00:26)Berserker Wrote: S больше не поддерживает GET-syntax.

начиная с какой версии, не напомнишь? надеюсь с ERA3 Rolleyes

SergOz, я до сих пор оперирую справочными данными от ERA2, а там нижний регистр в ^^ диалога не поддерживался

Berserker · 24.10.2020 00:53

Bes, да, с третьей, где VR полностью переписан.

Berserker · 24.10.2020 01:30

Задача: по клавише "H" войти в оборону всеми отрядами до хода следующего стека противника.
Применение: возможность массово пропускать ходы при ослеплённом противнике.
Требования: Эра 3.1.3+

; После любого боя, как сетевого, как и локального сбросим флаг спец. действия «Защита всем»,
; чтобы в новом бою по умолчанию он был не активен. А так как любая глобальная переменная имеет значение
; 0 по умолчанию, то заранее инициализировать флаг не нужно.
!?FU(OnAfterBattleUniversal);
!!VRi^nig_isAllDefendAction^:S(FALSE); Установили глобальный флаг спец. действия «Защита всем» в ложь (FALSE)
; Константы (TRUE) - истина и (FALSE) - ложь заменяют 1 и 0 для логических значений
!!VRi^nig_allDefendSide^:S0; Удаляем переменные, которые использовали в бою. Нули не записываются в сохранения
!!VRi^nig_allDefendRound^:S0;
; События нажатия клавиши в бою. Первый аргумент (x1) код клавиши. Второй — предотвратить ли реакцию по умолчанию
; Список кодов клавиш встроен в ЕРМ редактор и отдельно есть в Mods\Era Erm Framework\9999 key codes.erm
!?FU(OnKeyPressed_Battle)&x1=(KEY_H);
!#VA(key:x) (preventDefault:x);
!!BG:N?(stackId:y); Получили ID текущего стека
!!VR(stackSide:y):S(stackId) :(BATTLE_STACKS_PER_SIDE); Получили активную сторону, поделив ID на макс числов стеков для одной стороны
!!FU&i^battle_localHuman_%(stackSide)^<>(TRUE):E; Вышли, если текущая сторона — не человек, сидящий за данным компьютером
; Глобальные переменные battle_localHuman_0 и battle_localHuman_1 устанавливаются
; в библиотеке ЭРЫ в событиях «до боя»
; Так как (stackSide) хранит 0 или 1, то вся строка будет раскрыта в battle_localHuman_0
; или battle_localHuman_1, то есть вернёт значение для текущей стороны
!!VR(preventDefault):S(TRUE); Запрещаем реакцию на клавишу по умолчанию
!!VRi^nig_isAllDefendAction^:S(TRUE); Устанавливаем флаг действия «Защита всем» в ИСТИНУ
!!VRi^nig_allDefendSide^:S(stackSide); Запоминаем сторону, отряды которой должны войти в оборону
!!VRi^nig_allDefendRound^:Si^battle_round^; Запоминаем текущий раунд
!!BG:A(BATTLE_ACTION_DEFEND); Входим в оборону текущим отрядом
; После очередного действия в бою, если активен флаг «Защита всем»
!?FU(OnAfterBattleAction)&i^nig_isAllDefendAction^=(TRUE);
!!BG:N?(stackId:y); Получили ID текущего стека. В событии "OnAfterBattleAction" текущий стек уже не тот,
; что был в событии "OnBeforeBattleAction", а тот, который получит управление
!!VR(stackSide:y):S(stackId) :(BATTLE_STACKS_PER_SIDE); Получили активную сторону, поделив ID на макс числов стеков для одной стороны
!!if&(stackSide)=i^nig_allDefendSide^:; Если текущая сторона — та, что активировала «Защита всем»
!!BG:A(BATTLE_ACTION_DEFEND); Выбираем действие «Защита»
!!el:;
!!VRi^nig_isAllDefendAction^:S(FALSE); Иначе отключаем флаг «Защита всем», давая противнику сделать ход, а человеку потом среагировать на него
!!en:;
; Если новый раунд наступил при активном действии «Защита всем», то сбросить флаг действия «Защита всем»
!?FU(OnBattleRound)&i^nig_isAllDefendAction^=(TRUE)/i^battle_round^<>i^nig_allDefendRound^;
!!VRi^nig_isAllDefendAction^:S(FALSE);

Berserker · 24.10.2020 02:03

(23.10.2020 06:23)SergOz Wrote:
Мне нужно контролировать Палатки Ключников, потому приведу этот пример: (Click to View)

!?OB10;
!!HE-1:O?(colPlayer:y); узнаю цвет игрока
!!OB998:U?(colTent:y); узнаю подтип палатки (цвет)
; для показа посещений палатки всеми игроками при клике на ней
!!SN:W^%(colPlayer)_%(colTent)^/?i^visit%(colPlayer)%(colTent)^;
!!VRi^visit%(colPlayer)%(colTent)^:+1;
!!SN:W^%(colPlayer)_%(colTent)^/i^visit%(colPlayer)%(colTent)^;
!?CM5; кликаем
!!VRv1:C0/0/0;
!!CM:F?(clickFlag:y); какой флаг клика
!!FU&(clickFlag)<>4:E; если не Cntrl+ЛКМ - выход
!!CM:P?v1/?v2/?v3; координаты клика
!!OB1:T?(objType:y); тип объекта
; если кликнул на палатку
!!FU(Tent)&(objType)=10:P21;
!?FU(Tent);
!!OB1:U?(colTent:y); узнаю подтип палатки (цвет)
!!re i/0/7: ;
!!SN:W^%i_%(colTent)^/?yx1;
!!VRx1:+1;
!!en: ;
; в сообщении просто цветом чисел выделяем игроков
!!IF:M^ {~Salmon}СКОЛЬКО РАЗ ИГРОКИ ПОСЕТИЛИ ПАЛАТКУ{~}
{-----------------------------------------------------------------------------------------}
{~OrangeRed}%Y21{~} {~DodgerBlue}%Y22{~} {~Peru}%Y23{~} {~Green}%Y24{~} {~Orange}%Y25{~} {~BlueViolet}%Y26{~} {~SkyBlue}%Y27{~} {~HotPink}%Y28{~}^;
Вопрос: как можно оптимизировать этот скрипт?

SergOz, сформулируй тезисно, что должен делать скрипт.

Для палатки с определённым цветом вывести по ПКМ число раз, сколько заходили в объект?

SergOz · 24.10.2020 02:24

Berserker, да, по ЛКМ+Ctrl. Чтобы на каждой палатке количество посещений каждого игрока.
У меня там заморочка с этими палатками и этот скрипт нужен только для контроля поведения ИИ на фазе тестирования.
Мой скрипт работает и мне этого достаточно. Просто, в процессе написания, возникли вопросы почему глючит !!OBi^...^ и как именованную y уподобить синтаксису !!SN:W^..^/Syx1;
Ну и узнать про другие возможные упрощения/улучшения в скрипте, в качестве повышения уровня понимания ERM2.

Berserker · 24.10.2020 02:37

Пожалуйста, используйте уникальный префикс для своих глобальных переменных вроде "serg_". Иначе не оберётесь проблем с совместимостью и багами.

!?OB10;
!!HE-1:O?(colPlayer:y); узнаю цвет игрока
!!OB998:U?(colTent:y); узнаю подтип палатки (цвет)
; для показа посещений палатки всеми игроками при клике на ней
!!SN:W^%(colPlayer)_%(colTent)^/?i^visit%(colPlayer)%(colTent)^;
!!VRi^visit%(colPlayer)%(colTent)^:+1;
!!SN:W^%(colPlayer)_%(colTent)^/i^visit%(colPlayer)%(colTent)^;

меняем на:

!?OB(OBJ_KEYMASTERS_TENT);
!!HE-1:O?(player:y);
!!OB998:U?(tentColor:y);
!!VRi^serg_tent_visits_%(tentColor)_%(player)^:+1;

Threaded Mode \| Linear Mode Школа ERM 2 » ERM 2.0 для ERA III
Author	Message