Threaded Mode | Linear Mode

SergOz · 10.10.2020 00:51

Правильно ли я понял, что именных переменных (name:y) должно быть не более 100, аналогично y1...y100?

Berserker · 10.10.2020 02:51

SergOz, да, но только в рамках одного триггера от !?XX до следующего !?YY.
Потому ограничения, считай, нет. Для каждого триггера одни и те же y1..y100 переменные ииспользуются для разных целей под разными именами.

Bes · 10.10.2020 04:35

Berserker, прости, не сильно вчитывался в новые возможности ERM2
Вот когда-то в SCVS можно было куски кода в константы всовывать

Code:

(errors off) = '!!UN:P904/1 P905/0;'; выключить показ ошибок

Тут такого нет (не планируется)?

Berserker · 10.10.2020 14:50

Bes, нет, макросов, которые раскрывались бы в любую под строку, тут нет. Константы, что есть, — это строгие целые числа.
Для остального пишем функции.

Из библиотеки Эры:

; ============== ERROR HANDLING ==============
!?FU(DisableErrors);
!!UN:P(WOG_OPT_MUTE_ERRORS)/(TRUE) P(WOG_OPT_LAST_ERROR)/(FALSE);
!?FU(EnableErrors);
; Returns last error flag
!#VA(result:x);
!!UN:P(WOG_OPT_MUTE_ERRORS)/(TRUE) P(WOG_OPT_LAST_ERROR)/?(result);
; ============ END ERROR HANDLING ============

Bes · 10.10.2020 18:50

понял.
кстати, опять я в своём стиле... если сделать получение в двух разных строках в одну и ту же именованную локальную переменную, они потом откомпилируются в разные по номеру переменные, или в одну и ту же? Unsure

!!UN:P(WOG_OPT_LAST_ERROR)/?(result:y);
!!UN:P(WOG_OPT_MUTE_ERRORS)/?(result:y);

igrik · 10.10.2020 21:17

(10.10.2020 18:50)Bes Wrote: понял.
кстати, опять я в своём стиле... если сделать получение в двух разных строках в одну и ту же именованную локальную переменную, они потом откомпилируются в разные по номеру переменные, или в одну и ту же?

!!UN:P(WOG_OPT_LAST_ERROR)/?(result:y);
!!UN:P(WOG_OPT_MUTE_ERRORS)/?(result:y);

Bes, ну ты чо)))) Тестами проверяй))) Bers тебе уже не один раз говорит:

(10.10.2020 04:03)Berserker Wrote: Bes, только тестами, Бес. По-другому не скажешь.

Bes · 10.10.2020 21:27

не, не, это вопросы из разряда "справочная инфа", тут точно Berserker знает что будет.
Я не ради любопытства спрашиваю, исключительно готовлю материал для кое-чего

блин, чтобы тесты такие делать, нужна ERA3, а у меня нет и не хочется седьмую папку с героями заводить, я в имеющихся и то путаю где у меня что (SoD, WoG? ERA1.9, 2.46 (две или три с разными ФМ-релизами), 2,9,14)

Berserker · 10.10.2020 23:13

Bes, в одну и ту же, конечно. В чём иначе смысл имени переменной, если она не на одну и ту же память указывает?
!!UN:P(WOG_OPT_LAST_ERROR)/?(result:y);
!!UN:P(WOG_OPT_MUTE_ERRORS)/?(result); второй раз можно тип не указывать, но можно и указать. Тогда он должен совпадать с ранее объявленным.

(result) заменится на y3, скажем.

Bes · 10.10.2020 23:42

понял, спасибо

Berserker · 13.10.2020 05:05

Просто большая функция на ЕРМ 2.0 (Click to View)

!?FU(mix_ReadTileNeutrals);
; Calculates neutrals types and current final quantitites, writing them to user-specified array.
; The result contains virtual slots, which may be empty and non-sequential.
!#VA(x:x) (y:x) (z:x);
!#VA(neutrals:x); T Neutrals. SN:M array ID to write finally calculated data to.
!#VA(success:x); Boolean. Optional, OUT. True, if data exists and was successfully read.
!#VA(leftFightValue:x); Float. Optional, OUT. Not used Fight Value, that should be preserved after battle.
!!VR(success):S(FALSE);
; Get config, exit if none
!!FU(mix_GetTileNeutralsConfig):P(x)/(y)/(z)/?(config:y);
!!FU&(config)=(FALSE):E;
; Get total number of original creatures
!!FU(mix_GetAdvMapMonInfo):P(x)/(y)/(z)/?(origMonType:y)/?(totalMons:y);
!!FU|(origMonType)=(NO_MON)/(totalMons)<=0:E;
; Calculate total fight value as float
!!MA:F(origMonType)/?(origMonFightValue:y);
!!VR(totalFightValue:e):S(totalMons) *(origMonFightValue);
!!FU&(totalFightValue)<=0:E;
; Initialize result to empty slots
!!SN:V(neutrals)/0/-1/0/-1/0/-1/0/-1/0/-1/0/-1/0/-1/0;
; Copy spread mask to result
!!SN:V(config)/(MIX_NEUTRALS_CONFIG_SPREAD_MASK_IND)/?(spreadMask:y);
!!SN:V(neutrals)/(MIX_NEUTRALS_STRUCT_SPREAD_MASK_IND)/(spreadMask);
; Unpack spread mask
!#VA(spreads[7]:y);
!!VR(spreads):C(FALSE)/(FALSE)/(FALSE)/(FALSE)/(FALSE)/(FALSE)/(FALSE);
!!re i/(@spreads[0])/(@spreads[-1]):;
!!VR(spreadInd:y):Si -(@spreads);
!!VR(testBit:y):S1 Sd<<(spreadInd) &(spreadMask);
!!VRyi&(testBit)<>0:S(TRUE);
!!en:;
; Calculate each stack size in floats
!!VR(numStacksToSpread:y):S0;
!!VR(numStacks:y):S0;
!!re i/0/(MIX_MAX_NEUTRAL_STACKS)/1/-1:;
; Skip free slot
!!VR(pairInd:y):Si *2;
!!SN:V(config)/(pairInd)/?(monType:y)/?(monRelQuantity:e);
!!co&(monType)<=(NO_MON):;
; Skip slot with zero fight value or quantity
!!MA:F(monType)/?(monFightValue:y);
!!VR(monQuantityFloat:e):S(totalFightValue) *(monRelQuantity) :(monFightValue);
!!co&(monQuantityFloat)<=0:;
; Force integer cap for number of creatures
!!VR(monQuantityFloat)&(monQuantityFloat)>=(INT_MAX):S(INT_MAX);
; Adjust number of stacks to spread
!!VR(spread:y):S(@spreads) +i Sy(spread);
!!VR(numStacksToSpread)&(spread)=(TRUE):+1;
; Save monster in the result list
!!SN:V(neutrals)/(pairInd)/(monType)/(monQuantityFloat);
!!VR(numStacks):+1;
!!en:;
; Exit if config does not containt any monsters
!!FU&(numStacks)=0:E;
; Determine free slot indexes and count
!#VA(freeSlots[7]:y);
!!VR(freeSlotPtr:y):S(@freeSlots);
!!re i/0/(MIX_MAX_NEUTRAL_STACKS)/1/-1:;
!!VR(pairInd:y):Si *2;
!!SN:V(neutrals)/(pairInd)/?(monType:y);
!!if&(monType)=(NO_MON):;
!!VRy(freeSlotPtr):Si;
!!VR(freeSlotPtr):+1;
!!en;
!!en:;
!!VR(numFreeSlots:y):S(freeSlotPtr) -(@freeSlots);
!!VR(freeSlotPtr:y):S(@freeSlots);
; Apply spreading
!!if&(numFreeSlots)>0/(numStacksToSpread)>0:;
!!VR(slotsPerSpreadedStack:y):S(numFreeSlots) :(numStacksToSpread);
!!VR(freeSlotsReserve:y):S(numFreeSlots) %(numStacksToSpread);
!!re i/0/(MIX_MAX_NEUTRAL_STACKS)/1/-1:;
; Continue if slot is free
!!VR(pairInd:y):Si *2;
!!SN:V(neutrals)/(pairInd)/?(monType:y)/?(monQuantityFloat:e);
!!co&(monType)=(NO_MON):;
; Continue if slot must not be spreaded
!!VR(spread:y):S(@spreads) +i Sy(spread);
!!co&(spread)<>(TRUE):;
; Determine, how many free slots will be used for current stack
!!VR(numOccupiedSlots:y):S(slotsPerSpreadedStack);
!!if&(freeSlotsReserve)>0:;
!!VR(freeSlotsReserve):-1;
!!VR(numOccupiedSlots):+1;
!!en;
!!co&(numOccupiedSlots)<=0:;
; Calculate float quantity for each slot to occupy
!!VR(numStackSlots:y):S(numOccupiedSlots) +1;
!!VR(spreadedMonQuantityFloat:e):S(monQuantityFloat) :(numStackSlots);
; Update float monster quantity in main stack slot
!!SN:V(neutrals)/(pairInd)/?t/(spreadedMonQuantityFloat);
; Occupy new slots
!!re j/0/(numOccupiedSlots)/1/-1:;
!!VR(freeSlot:y):Sy(freeSlotPtr);
!!VR(freeSlotPtr):+1;
!!VR(pairInd:y):S(freeSlot) *2;
!!SN:V(neutrals)/(pairInd)/(monType)/(spreadedMonQuantityFloat);
!!en:; re
!!en:; re
!!en; if
; Apply merging in order to obtain integer non-zero quantities for each slot and unused fight value sum
!#VA(monReserve[14]:y); array 7 of (monType: int, monQuantity: float)
!!VR(monReserveSize:y):S0;
!!VR(numRealSlots:y):S0;
!!VRi:S(MIX_MAX_NEUTRAL_STACKS) -1;
; Process each stack from right to left
!!re i/i/0/-1:;
; Continue if slot is free
!!VR(pairInd:y):Si *2;
!!SN:V(neutrals)/(pairInd)/?(monType:y)/?(monQuantityFloat:e) V(neutrals)/(pairInd)/(NO_MON)/0;
!!co&(monType)=(NO_MON):;
; Search for the same monster type in reserve
!!re (monReserveInd:y)/0/(monReserveSize)/1/-1:;
!!VR(monReservePtr:y):S(monReserveInd) *2 +(@monReserve);
!!VRy(monReservePtr):C?(reserveMonType:y)/?(reserveMonQuantity:e);
!!br&(reserveMonType)=(monType):;
!!en:;
; Add monster from reserve to current stack, if any
; Create new reserve if current monster type is absent
!!if&(monReserveInd)<(monReserveSize):;
!!VR(monQuantityFloat):+(reserveMonQuantity);
!!el:;
!!VR(monReservePtr):S(monReserveSize) *2 +(@monReserve);
!!VR(monReserveSize):+1;
!!en;
; Convert current stack quantity to integer
!!VR(monQuantity:y):S(monQuantityFloat);
!!VR(monQuantity)&(monQuantity)<0:S(INT_MAX);
; Calculate rest monster quantity for reserve
!!VR(reserveMonQuantity:e):S(monQuantityFloat) -(monQuantity);
; Update reserve
!!VRy(monReservePtr):C(monType)/(reserveMonQuantity);
; Update result stack
!!VR(monType)&(monQuantity)=0:S(NO_MON);
!!SN:V(neutrals)/(pairInd)/(monType)/(monQuantity);
!!VR(numRealSlots)&(monQuantity)>0:+1;
!!en:; re
!!VR(leftFightValue):S0;
; Apply minimal 1 monster requirement if all slots seem to be empty
!!if&(numRealSlots)=0:;
!!VR(minFightValueMonType:y):S(NO_MON);
!!VR(minFightValue:y):S(INT_MAX);
!!VR(minFightValuePairInd:y):S-1;
!!re i/0/(MIX_MAX_NEUTRAL_STACKS)/1/-1:;
; Continue if slot is free
!!VR(pairInd:y):Si *2;
!!SN:V(config)/(pairInd)/?(monType:y);
!!co&(monType)<=(NO_MON):;
; Remember monster, if it's fight value is less, than current minimum
!!MA:F(monType)/?(monFightValue:y);
!!if&(monFightValue)<(minFightValue):;
!!VR(minFightValue):S(monFightValue);
!!VR(minFightValueMonType):S(monType);
!!VR(minFightValuePairInd):S(pairInd);
!!en;
!!en:;
; Set 1 monster to slot and update total fight value
!!SN:V(neutrals)/(minFightValuePairInd)/(minFightValueMonType)/1;
!!el:;
; Calculate leftFightValue, based on left reserve after merging
!!VR(leftFightValueFloat:e):S0;
!!re (monReserveInd:y)/0/(monReserveSize)/1/-1:;
!!VR(monReservePtr:y):S(monReserveInd) *2 +(@monReserve);
!!VRy(monReservePtr):C?(reserveMonType:y)/?(reserveMonQuantity:e);
!!MA:F(reserveMonType)/?(reserveMonFightValue:y);
!!VR(reserveStackFightValue:e):S(reserveMonQuantity) *(reserveMonFightValue);
!!VR(leftFightValueFloat):+(reserveStackFightValue);
!!en:;
!!VR(leftFightValue):C(leftFightValueFloat);
!!en; el
!!VR(success):S(TRUE);

wessonsm · 13.10.2020 19:41

Скрипт ведь учебный по большому счёту.
Просто действительно мало примеров рабочих скриптов на ZVSE2.
Чем больше их будет - тем лучше.
Я именно так ERM осваивал - сначала только правил стандартные скрипты, потом уже потихоньку начал свои писать.

SergOz · 23.10.2020 06:23

Ещё один скрипт на тему контроля посещения объектов игроками.

Мне нужно контролировать Палатки Ключников, потому приведу этот пример: (Click to View)

При определении координат клика не использовал i^...^, потому что у меня на ERA3.04 ругается на !!OBi^..^/i^..^/i^..^:T?(objType:y);, а значит не мог протестировать.

Вопрос: как можно оптимизировать этот скрипт?
P.S. Поясню что меня больше всего интересует. Есть цикл

!!re i/0/7: ;
!!SN:W^%i_%(colTent)^/?yx1;
!!VRx1:+1;
!!en: ;

в котором есть ?yx1. Как здесь можно применить именованную (another:y), чтобы потом её можно было показать в сообщении?

Bes · 23.10.2020 19:54

SergOz, если честно, вообще не понимаю что ты тут замутил с

...
!!FU(Tent)&(objType)=10:P21;
...
!!...;
!!SN:W^%i_%(colTent)^/?yx1;
!!VRx1:+1;
!!en: ;

точнее понимаю, но не понимаю почему таким способом?
почему сразу нельзя было

!!IF:M^ {~Salmon}СКОЛЬКО РАЗ ИГРОКИ ПОСЕТИЛИ ПАЛАТКУ{~}
{-----------------------------------------------------------------------------------------}
{~OrangeRed}%I(0_%(colTent)){~} {~DodgerBlue}%I(1_%(colTent)){~} {~Peru}%I(2_%(colTent)){~} {~Green}%I(3_(%colTent)){~} {~Orange}%I(4_%(colTent)){~} {~BlueViolet}%I(5_%(colTent)){~} {~SkyBlue}%I(6_%(colTent)){~} {~HotPink}%I(7_%(colTent)){~}^;

Berserker · 23.10.2020 20:17

SergOz, сегодня попробую дать полный ответ.

Bes, внутри %I() нельзя использовать проценты.

SergOz · 23.10.2020 20:44

Quote:точнее понимаю, но не понимаю почему таким способом?
почему сразу нельзя было...

Bes, а ты попробуй сразу и на разных палатках - тогда станет понятно.
И, к тому же, у меня в том !?CM5; ещё отсылки на другие функции.

Threaded Mode \| Linear Mode Школа ERM 2 » ERM 2.0 для ERA III
Author	Message