Pages: 1 2 3 4 5 6 7 8 9 10 11 12 13 14
How do we let system options icon working with left click and trigger function on right click without having the post original pop up?! CM:R0 is screwed here.
!?CM4; RONON****
!!BG:N?v39; v39=stack # (used in Sheppard's functions)
!!BMv39:T?y-1; creature type (35 for Ronon)
!!CM:I?y-2; **here tried F=512, F=0 (left click) but seems not working
!!FU&y-2<>2003:E; exit if not click on Combat options
!!FU&y-1<>35:E; exit if not C35's turn
!!FU7000:P; Ronon's battle menu
** battle wrap-up
Later in function
!?FU7000;
[......]
!!IF:E100/70; The choice will be stored in v100
!!CM&v100<0:R0; <----?!
!!FU&v100<0:E;
When I click right on system options, I get function 7000 and after that it shows combat options screen. I flagged it as 512/0 but did not work. I still get both screens, one after the other.
!!CM:R0 works fine.
!!CM&v100<0:R0; <----?!
!!FU&v100<0:E;
What is this? Give the full code.
It is simply the "4 pics" dialog, with selected result stored in v100
Code:
!?CM4; RONON****
!!BG:N?v39; v39=stack # (used in Sheppard's functions)
!!BMv39:T?y-1; creature type (35 for Ronon)
!!CM:I?y-2;
!!FU&y-2<>2003:E; exit if not click on Combat options
**CM&y-2=2003:R0; disable std button action if Combat clicked
!!FU&y-1<>35:E; exit if not C35's turn
!!FU7000:P; Ronon's battle menu
** battle wrap-up
!?FU7000; Ronon battle menu_
** set up radio-button (G1) dialog box: radio/use v1 for results/initial state
** /z# has header/z# has 1st item description/etc.
!!VRz20:S^Ronon battle menu^;
!!VRz21:S^^;
!!VRz22:S^Pick one^;
!!VRz23:S^%Z199\Bless.gif^;
!!VRz24:S^%Z199\Precis.gif^;
!!VRz25:S^%Z199\Dispel.gif^;
!!VRz26:S^%Z199\Shield.gif^;
!!VRz27:S^Create wide-area energy discharge^;
!!VRz28:S^Create ranged damage^;
!!VRz29:S^Remove unfriendly energy fields^;
!!VRz35:S^Create Augmenting field^;
!!VRz27:S^Block energy^;
!!VRz28:S^Create ranged damage^;
!!VRz29:S^Remove unfriendly energy fields^;
!!VRz35:S^Block energy^;
!!VRz31:S^Bless^;
!!VRz32:S^Precision^;
!!VRz33:S^Dispel^;
!!VRz34:S^Shield^;
!!IF:D70/z20/0/z22/z23/z24/z25/z26/z27/z28/z29/z35/z27/z28/z29/z35;
!!IF:F70/z31/z32/z33/z34/1; Give hints and disable cancel button
!!IF:E100/70; The choice will be stored in v100
!!CM&v100<0:R0; (if player clicks on cancel)
!!FU&v100<0:E;
!!FU7001&v100=1:P;
!!FU7001&v100=2:P;
!!FU7001&v100=3:P;
!!FU7001&v100=4:P;
!?FU7001;
!!IF:M^Designate the coordinates (right-click hex).^;
!!IF:V300/1; enables another mouse click trigger
!?CM4&300; trigger for hex designation by Ronon
!!CM:R0; no other clicks allowed until battle option completed
!!CM:D?y-1; hex number
!!FU|y-1<1/y-1>185:E; Exit if invalid hex
!!IF:V300/0;
!!UN:R6/2000;
!!FU7002&v100=1:Py-1;
!!FU7003&v100=2:Py-1;
!!FU7004&v100=3:Py-1;
!!FU7005&v100=4:Py-1;
!?FU7002; x1=hex cast bless expert
!!BU:Ex1/?y2; get stack # at hex x1 (-1 if none)
!!VRz1:S^SGA\C302.wav^;
!!IF:V1/0;
!!IF&y2=-1:V1/1; no stack @ hex N.G.
!!IF&v53<21/y2>20:V1/1; opp. side N.G.
!!IF&v53>20/y2<21:V1/1; opp. side N.G.
!!SN&1:Pz1;
!!IF&1:V300/1; try again
!!FU&1:E;
!!BMv39:C41/x1/3/3/1; cast bless
!!BG:A3; end turn with Defend action
!?FU7003; x1=hex cast precision advanced
!!BU:Ex1/?y2; get stack # at hex x1 (-1 if none)
!!VRz1:S^SGA\C302.wav^;
!!IF:V1/0;
!!IF&y2=-1:V1/1; no stack @ hex N.G.
!!IF&v53<21/y2>20:V1/1; opp. side N.G.
!!IF&v53>20/y2<21:V1/1; opp. side N.G.
!!SN&1:Pz1;
!!IF&1:V300/1; try again
!!FU&1:E;
!!BMv39:C44/x1/2/3/1; cast precision
!!BG:A3; end turn with Defend action
!?FU7004; x1=hex cast Dispel expert
!!BU:Ex1/?y2; get stack # at hex x1 (-1 if none)
!!VRz1:S^SGA\C302.wav^;
!!IF:V1/0;
!!IF&y2=-1:V1/1; no stack @ hex N.G.
!!IF&v53<21/y2>20:V1/1; opp. side N.G.
!!IF&v53>20/y2<21:V1/1; opp. side N.G.
!!SN&1:Pz1;
!!IF&1:V300/1; try again
!!FU&1:E;
!!BMv39:C35/x1/3/3/1; cast dispel
!!BG:A3; end turn with Defend action
!?FU7005; x1=hex cast Shield advanced
!!BU:Ex1/?y2; get stack # at hex x1 (-1 if none)
!!VRz1:S^SGA\C302.wav^;
!!IF:V1/0;
!!IF&y2=-1:V1/1; no stack @ hex N.G.
!!IF&v53<21/y2>20:V1/1; opp. side N.G.
!!IF&v53>20/y2<21:V1/1; opp. side N.G.
!!SN&1:Pz1;
!!IF&1:V300/1; try again
!!FU&1:E;
!!BMv39:C27/x1/2/3/1; cast shield
!!BG:A3; end turn with Defend action
Basically my wish is:
1)On left click open system menu
2) On right click open the above menu, without getting system menu
CM4 is said to work with right click, but when I click left I get same thing.
Check CM:F for 512.
Check CM:S for 14.
If not - exit;
Thanks it worked
(I used the conditions to start the function as well)
Code:
!?CM4; RONON****
!!BG:N?v39; v39=stack # (used in Sheppard's functions)
!!BMv39:T?y-1; creature type (35 for Ronon)
!!CM:I?y-2 F?y-3 S?y-4;
!!FU&y-2<>2003/y-3<>512/y-4<>14:E; exit if not click on Combat options
!!FU&y-1<>35:E; exit if not C35's turn
!!FU7000&y-2=2003/y-3=512/y-4=14:P; Ronon's battle menu
Strange thing: if an hero is blind cursed, you can't control his steps
!#HE106:Y1/0/999/1; (can't explore around)
!?HM-1 will not work for this hero...
Does anyone know where is located Heroes internal clicks memory? I noticed that after a certain number of right clicks, the game can't store anymore and shows errors when clicking. What would be great would be to have a command which deletes the overloaded memory...
Such memory does not exist. To be correct, it's Windows internal implementation of windows' messages lists.
I am sure there is something related to right clicks memory. I have already experienced this in one of my maps (The Empire) where after a few months the game could not display anymore hints on right click. Now I get a message "Out of memory" after a while. I will post here the screen, when I save it. With the new combats mechanics, there are some 25-30 right clicks /battle and multiplied by 400 battles, it just exploded the game memory.
Quiting the game and restarting solves the problem.
Maybe you've used too many hints for objects...
And if it is true, where are they stored in memory and how to empty the thing without reloading game? Is there a way?
Soon, very soon
(actually hunting last bugs, man I exploded the game memory, I have to use dialogs 1 to 99 because in end game they are completely overlapping if used with low z variables :D)
Some pics from fights:
Economic crisis? inflation? at 9 month?
Not really. Considering that you have to play for about 12 months with only a gog, a magog, an archimage and an orc, I had to diversify at maximum their individual customization, from improving stats to immunities and abilities. The prices start low, but more you pick, more is expensive. So when Ronon (archimage) for example got his first +1 attack, the price was 5000 gold. Now he is at 70 attack (more than a supreme archangel) and it is costly. All creatures on map have dynamic boosts with time and the team has to follow, otherwise they die
Income from trade routes is growing each week by %50. If the planet is attacked by wraiths (random) the income is cut.
Pages: 1 2 3 4 5 6 7 8 9 10 11 12 13 14
