Threaded Mode | Linear Mode

Bes · 22.06.2012 00:00

Berserker, я конечно понимаю, что ERA уже вошла в нашу жизнь как само собой разумеещееся... но всё-же лучше уточнять что такой-то код ТОЛЬКО для ERA-платформы (а то потом объясняй людям откуда у них в WoG3.58f пошли вылеты и ошибки) 166

M.A.K.C. · 04.07.2012 22:27

Здраствуйте, для карты нужен скрипт, чтобы каждый 4-й день курганы на карте с 50% вероятностью преобразовывались в случайные отряды нежити.

Скрипт для размещения курганов сделал, а для замены(преобразования) никак... нужна помощь

Berserker · 04.07.2012 22:54

Так а что там сложного? UN:O удаляет объект, UN:I создаёт, !!OB тип и подтип назначит 54/х, !!MO настроит монстров на карте.

M.A.K.C. · 04.07.2012 23:27

Нужен пример, не получается

Ivor · 05.07.2012 01:41

(04.07.2012 22:27)M.A.K.C. Wrote: Здраствуйте, для карты нужен скрипт, чтобы каждый 4-й день курганы на карте с 50% вероятностью преобразовывались в случайные отряды нежити.

В нежить будут преобразованы на 4ый - 50%, 8ой - 75%, 12ый - 87,5% курганов. За 2 недели почти все курганы превратятся в нежить. Так и задумано?

M.A.K.C. · 05.07.2012 07:31

(05.07.2012 01:41)Ivor Wrote:
(04.07.2012 22:27)M.A.K.C. Wrote: Здраствуйте, для карты нужен скрипт, чтобы каждый 4-й день курганы на карте с 50% вероятностью преобразовывались в случайные отряды нежити.
В нежить будут преобразованы на 4ый - 50%, 8ой - 75%, 12ый - 87,5% курганов. За 2 недели почти все курганы превратятся в нежить. Так и задумано?

можно и так, а можно проще. с 50% вероятностью курган или преобразуется, или нет.

Berserker · 05.07.2012 17:47

M.A.K.C., а какой код уже имеется?

M.A.K.C. · 05.07.2012 19:14

Вот это

Spoiler (Click to View)

!#TM41:S1/999/4/255;
!?TM41;
!!FU28444:P?y-1/?y-2/?y-3;Вызываем функцию генерации координат случайной свободной клетки.
!!UN:Iy-1/y-2/y-3/133/0;Ставим курган на клетку.
;Функции генерации случайной свободной клетки карты.
!?FU28444;Функция генерации случайной свободной клетки карты.
!!UN:X?y1/?y2;Считываем размеры карты.
!!VRy2:+1;Вычисляем количество уровней на карте.
!!VRy3:Sy1*y1*y2;Вычисляем количество клеток карты.
!!VRy3:-1;Вычисляем номер последней клетки карты.
!!VRy4:Sv2;Сохраняем значение глобальной переменной.
!!VRv2:S0;Обнуляем переменную счёта свободных клеток.
!!DO28445/0/y3/1:Py1/y2;Запускаем цикл, проходящийся по всем клеткам карты и считающий число свободных клеток на ней.
!!FU&v2<=0:E;Если свободных клеток нет, завершаем функцию.
!!VRy5:Sv2-1;Вычисляем условный номер последней свободной клетки.
!!VRv2:S0 Ry5;Генерируем случайный условный номер свободной клетки.
!!DO28446/0/y3/1:Py1/y2;Запускаем цикл, проходящийся по клеткам карты и вычисляющий реальный номер клетки.
!!VRx1:Sv2%y1;Вычисляем и возвращаем x-координату клетки.
!!VRx2:Sv2:y1%y1;Вычисляем и возвращаем y-координату клетки.
!!VRx3:Sv2:y1:y1%y2;Вычисляем и возвращаем z-координату клетки.
!!VRv2:Sy4;Восстанавливаем значение глобальной переменной.
!?FU28445;Функция проверки свободности клетки.
!!VRy1:Sx16%x1;Вычисляем x-координату клетки.
!!VRy2:Sx16:x1%x1;Вычисляем y-координату клетки.
!!VRy3:Sx16:x1:x1%x2;Вычисляем z-координату клетки.
!!TRy1/y2/y3:E?y4;Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5;Считываем посещаемость клетки.
!!TRy1/y2/y3:T?y6/d/d/d/d/d/d/d;Считываем тип территории клетки.
!!FU&y4=0|y5=0/y6=8/y6=9:E;Если клетка недоступна, завершаем тфункцию.
!!OBy1/y2/y3:T?y7;Считываем тип объекта на клетке.
!!VRv2&y7<>34:+1;Если на клетке стоит не герой, добавляем 1 в переменную свободных клеток.
!?FU28446;Функция проверки свободности клетки.
!!VRy1:Sx16%x1;Вычисляем x-координату клетки.
!!VRy2:Sx16:x1%x1;Вычисляем y-координату клетки.
!!VRy3:Sx16:x1:x1%x2;Вычисляем z-координату клетки.
!!TRy1/y2/y3:E?y4;Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5;Считываем посещаемость клетки.
!!TRy1/y2/y3:T?y6/d/d/d/d/d/d/d;Считываем тип территории клетки.
!!OBy1/y2/y3&y4=1/y5=1/y6<>8/y6<>9:T?y7;Если клетка свободна, считываем тип объекта на клетке.
!!VRv2&y4=0|y5=0/y6=8/y6=9/y7=34:+1;Если клетка несвободна или на ней есть герой, добавляем 1 в переменную реального номера клетки.
!!VRx16&x16=v2:Sx1*x1*x2;Если реальный номер клетки вычислен, завершаем цикл.

надо, чтобы с 50% вероятностью все курганы на карте преобразовывались
Скелеты 80%
Призраки 60%
Вампиры - Вампиры Лорды 45%
Личи - 35%
Рыцари смерти 15%
Костяные драконы 5%
Можно и другая процентовка, главное суть.

Berserker · 05.07.2012 20:22

Quote:с 50% вероятностью курган или преобразуется, или нет.

В первый же день? А половина курганов вечно курганами остаётся?

M.A.K.C. · 05.07.2012 20:32

Просто разный таймер, курганы будут появляться в два раза реже, чем преобразовываться

Berserker · 05.07.2012 21:17

Тогда вся карта будет ими захламляться )

M.A.K.C. · 05.07.2012 21:59

Это все решаемо через таймер, Главное скрипт!

Algor · 06.07.2012 05:13

M.A.K.C., держи:

скрин (Click to View)

erm (Click to View)

!#TM41:S1/999/1/255;
!?TM41;
!!FU28444:P?y-1/?y-2/?y-3;Вызываем функцию генерации координат случайной свободной клетки.
!!UN:Iy-1/y-2/y-3/91/0/91/0/0/1;Ставим знак на клетку (их можно считать в UN:U).
!!SGy-1/y-2/y-3:M^Скоро отсюда попрет мертвечинка...^;Унифицируем надпись на знаке
!!UN:Iy-1/y-2/y-3/133/0/133/0/0/1;Ставим курган на клетку.
;Функции генерации случайной свободной клетки карты.
!?FU28444;Функция генерации случайной свободной клетки карты.
!!UN:X?y1/?y2;Считываем размеры карты.
!!VRy2:+1;Вычисляем количество уровней на карте.
!!VRy3:Sy1*y1*y2;Вычисляем количество клеток карты.
!!VRy3:-1;Вычисляем номер последней клетки карты.
!!VRy4:Sv2;Сохраняем значение глобальной переменной.
!!VRv2:S0;Обнуляем переменную счёта свободных клеток.
!!DO28445/0/y3/1:Py1/y2;Запускаем цикл, проходящийся по всем клеткам карты и считающий число свободных клеток на ней.
!!FU&v2<=0:E;Если свободных клеток нет, завершаем функцию.
!!VRy5:Sv2-1;Вычисляем условный номер последней свободной клетки.
!!VRv2:S0 Ry5;Генерируем случайный условный номер свободной клетки.
!!DO28446/0/y3/1:Py1/y2;Запускаем цикл, проходящийся по клеткам карты и вычисляющий реальный номер клетки.
!!VRx1:Sv2%y1;Вычисляем и возвращаем x-координату клетки.
!!VRx2:Sv2:y1%y1;Вычисляем и возвращаем y-координату клетки.
!!VRx3:Sv2:y1:y1%y2;Вычисляем и возвращаем z-координату клетки.
!!VRv2:Sy4;Восстанавливаем значение глобальной переменной.
!?FU28445;Функция проверки свободности клетки.
!!VRy1:Sx16%x1;Вычисляем x-координату клетки.
!!VRy2:Sx16:x1%x1;Вычисляем y-координату клетки.
!!VRy3:Sx16:x1:x1%x2;Вычисляем z-координату клетки.
!!TRy1/y2/y3:E?y4;Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5;Считываем посещаемость клетки.
!!TRy1/y2/y3:T?y6/d/d/d/d/d/d/d;Считываем тип территории клетки.
!!FU&y4=0|y5=0/y6=8/y6=9:E;Если клетка недоступна, завершаем тфункцию.
!!OBy1/y2/y3:T?y7;Считываем тип объекта на клетке.
!!VRv2&y7<>34:+1;Если на клетке стоит не герой, добавляем 1 в переменную свободных клеток.
!?FU28446;Функция проверки свободности клетки.
!!VRy1:Sx16%x1;Вычисляем x-координату клетки.
!!VRy2:Sx16:x1%x1;Вычисляем y-координату клетки.
!!VRy3:Sx16:x1:x1%x2;Вычисляем z-координату клетки.
!!TRy1/y2/y3:E?y4;Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5;Считываем посещаемость клетки.
!!TRy1/y2/y3:T?y6/d/d/d/d/d/d/d;Считываем тип территории клетки.
!!OBy1/y2/y3&y4=1/y5=1/y6<>8/y6<>9:T?y7;Если клетка свободна, считываем тип объекта на клетке.
!!VRv2&y4=0|y5=0/y6=8/y6=9/y7=34:+1;Если клетка несвободна или на ней есть герой, добавляем 1 в переменную реального номера клетки.
!!VRx16&x16=v2:Sx1*x1*x2;Если реальный номер клетки вычислен, завершаем цикл. **
****
!?TM41;
!!UN:U91/-1/?y1;Количество курганов в y1
!!VRv1:S-1;инициализация v1 для быстрого поиска
!!DO28447/1/y1/1:P;Преобразуем курганы в нежить
!?FU28447;Функция преобразования кургана в нежить
!!UN:U91/-1/-1/1;v1..v3 - координаты кургана
!!VRy1:S0 R99;y1-случайное число (0..99)
!!FU&y1>=20:E;Преобразовываем 20% курганов
!!UN:Ov1/v2/v3/1;Удаляем знак
!!UN:Ov1/v2/v3/1;Удаляем курган
!!VRy1:S0 R99;y1-случайное число (0..99)
!!VRy2&y1>=0/y1<5:S69; 5% Драконы призраки
!!VRy3&y1>=0/y1<5:S5; в количестве 5 шт
!!VRy2&y1>=5/y1<10:S68; 5% Костяные драконы
!!VRy3&y1>=5/y1<10:S6; в количестве 6 шт
!!VRy2&y1>=10/y1<17:S67; 7% Рыцари смерти
!!VRy3&y1>=10/y1<17:S6; в количестве 7 шт
!!VRy2&y1>=17/y1<24:S66; 7% Черные рыцари
!!VRy3&y1>=17/y1<24:S8; в количестве 8 шт
!!VRy2&y1>=24/y1<33:S65; 9% Могущественные Личи
!!VRy3&y1>=24/y1<33:S10; в количестве 10 шт
!!VRy2&y1>=33/y1<42:S64; 9% Личи
!!VRy3&y1>=33/y1<42:S15; в количестве 15 шт
!!VRy2&y1>=42/y1<53:S63; 11% Лорды Вампиры
!!VRy3&y1>=42/y1<53:S20; в количестве 20 шт
!!VRy2&y1>=53/y1<64:S62; 11% Вампиры
!!VRy3&y1>=53/y1<64:S30; в количестве 30 шт
!!VRy2&y1>=64/y1<77:S61; 13% Приведения
!!VRy3&y1>=64/y1<77:S50; в количестве 50 шт
!!VRy2&y1>=77/y1<90:S60; 13% Стражи
!!VRy3&y1>=77/y1<90:S70; в количестве 70 шт
!!VRy2&y1>=90/y1<100:S196; 9% Драколич
!!VRy3&y1>=90/y1<100:S1; в гордом одиночестве
!!MW:Pv1/v2/v3/y2/?y4;Генерим бродячего монстра (обычного без очень хитрых извратов не получится)
!!MWy4:A3/d/d/d/d/1/d/0;Монстр не двигается
!!MOv1/v2/v3:Gy3 R10/1 O0 U1;Монстры в нужном количестве, злые как собаки, плодятся и не отступают

M.A.K.C. · 07.07.2012 18:14

Глючит скрипт, может кто знает в чем причина?

Algor · 08.07.2012 00:06

(06.07.2012 07:30)M.A.K.C. Wrote: Скрипт не работает, при нападении на преобразованного монстра битвы не происходит.

Да ну? Только что перепроверил, все работает нормально. Попробуй отключить все остальное, может конфликтует с чем...

Threaded Mode \| Linear Mode Заготовки скриптов
Author	Message