Threaded Mode | Linear Mode

Raistlin · 11.04.2021 18:06

Данная тема является справочником, содержащем примеры готовых скриптов. Скрипты, выкладываемые здесь, должны быть хорошо прокомментированы, хорошо структурированы, а также не быть банальными. Использование команд UN:C, SN:E и SN:К приветствуется.

В качестве примера возьму скрипт, найденный на просторах этого форума, и доработанный мной. Суть скрипта - поиск наиболее короткого маршрута от одного гекса до другого в бою, суть моей поправки - раньше скрипт всегда считал замковые ворота препятствием, но теперь это не так. Решение проблемы заключалось в отказе от BU:О и использовании вместо этой команды SN:E4625904[...].

Узнать расстояние между двумя гексами на поле боя:

** Автор: Algor, обновил: Raistlin
** получение пройденного расстояния между двумя гексами
** по алгоритму, который привел в FizMiG'е AlexSpl
** FU8888-FU8891
!?FU8888; [получение пройденного расстояния между двумя гексами]
; x1 - исходный гекс (1..185)
; x2 - целевой гекс (1..185)
; x3 - ширина существа (1..2)
; x4 - расстояние или -1(гекс не доступен) или -2 (гекс занят/за полем)
!!BU:Ex1/?y1; [номер отряда в исходной позиции]
!!VRy2:Sx1; [для одногексового отряда 2й исходный гекс совпадает с первым]
!!VRy2&y1>=0/y1<21/x3=2:+1; [y2 - 2й исходный гекс для атакующего двугексового существа]
!!VRy2&y1>20/x3=2:-1; [y2 - 2й исходный гекс для защищающегося двугексового существа]
!!DO8889/0/186/1:Px3; [инициализация сетки значениями -1(не определено) и -2 (не доступно)]
!!SN:W^alg%X1^/0 W^alg%Y2^/0; [инициализация исходных гексов (расстояние 0)]
!!DO8890/1/30/1:Px2; [расчет значений сетки (30 итераций)]
!!SN:W^alg%X2^/?x4; [возврат в x4 значения целевого гекса]
!?FU8889; [установка значения -1(не определено) или -2 (не доступно) для гекса x16]
!!BU:Ex16/?y1; [y1/y2 - отряд/препятствие в гексе]
!!UN:C6919200/4/?y50; [менеджер Битвы]
!!SN:E4625904/2/y50/x16; [вызов функции IsHexNotFree]
!!VRy2:Sv1 *2; [y2=2, если на позиции препятствие]
!!VRy3:Sx16 %17; [y3 = 0 или 16 если гекс за пределами поля]
!!VRy5:S0;
!!VRy5|y1>=0/y2=2/y3=0/y3=16:S2; [y5=2 для недоступного гекса]
!!if&x1=2/y5<2:; [для двугексовых существ определяем доступность еще и по соседним гексам]
!!VRy4:Sx16 -1; [y4 - номер левого гекса]
!!BU:Ey4/?y1; [y1/y2 - отряд/препятствие в гексе]
!!SN:E4625904/2/y50/y4; [вызов функции IsHexNotFree]
!!VRy2:Sv1 *2; [y2=2, если на позиции препятствие]
!!VRy3:Sy4 %17; [y3 = 0 или 16 если гекс за пределами поля]
!!VRy5|y1>=0/y2=2/y3=0/y3=16:+1; [y5++, если левый гекс не доступен]
!!VRy4:Sx16 +1; [y4 - номер правого гекса]
!!BU:Ey4/?y1; [y1/y2 - отряд/препятствие в гексе]
!!SN:E4625904/2/y50/y4; [вызов функции IsHexNotFree]
!!VRy2:Sv1 *2; [y2=2, если на позиции препятствие]
!!VRy3:Sy4 %17; [y3 = 0 или 16 если гекс за пределами поля]
!!VRy5|y1>=0/y2=2/y3=0/y3=16:+1; [y5++, если левый гекс не доступен]
!!en:;
!!SN&y5<2:W^alg%X16^/-1; [значение гекса "не определено"]
!!SN&y5>=2/x16<>96:W^alg%X16^/-2; [значение гекса "не доступно"]
!!SN&x16=96/v1=1:W^alg%X16^/-2; [значение гекса "не доступно" для ворот]
!?FU8890; [расчет значений сетки]
!!SN:W^alg%X1^/?y1; [текущее значение целевого гекса]
!!FU&y1>=0:E; [выход, если расстояние до текущего гекса уже определилось]
!!DO8891/1/185/1:P; [для каждого гекса определяем расстояния от исходного по соседним значениям]
!?FU8891; [расчет значения гекса x16]
!!SN:W^alg%X16^/?y1; [y1 - текущее значение гекса]
!!FU&y1<>-1:E; [выход, если значение уже определено]
!!VRy1:Sx16 :17 %2; [y1 - четность ряда проверяемого гекса]
!!VRy10:S100; [y10 - инициализация значения большим числом]
!!VRy2:Sx16 -1; [y2 - левый гекс]
!!SN:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy2:Sx16 +1; [y2 - правый гекс]
!!SN:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy2:Sx16 -17 -y1; [y2 - левый верхний гекс]
!!SN&y2>=0:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y2>=0/y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy2:Sx16 -16 -y1; [y2 - правый верхний гекс]
!!SN&y2>=0:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y2>=0/y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy2:Sx16 +17 -y1; [y2 - левый нижний гекс]
!!SN&y2<187:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y2<187/y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy2:Sx16 +18 -y1; [y2 - правый нижний гекс]
!!SN&y2<187:W^alg%Y2^/?y9; [y9 - значение гекса]
!!VRy10&y2<187/y9<y10/y9>=0:Sy9; [y10 - минимальное значение соседнего гекса]
!!VRy10&y10<100:+1; [если значение гекса определилось...]
!!SN&y10<100:W^alg%X16^/y10; [...устанавливаем его]
!?CM4; [ДЕМОНСТРАЦИЯ: при ПКМ на гексе выводит пешее расстояние до него от текущего отряда]
!!BG:N?y1; [y1 - текущий отряд]
!!BMy1:P?y4 F?y5; [y4 - исходный гекс, y5 - флаги отряда]
!!VRy5:&1 +1; [y5 - размер отряда (1..2)]
!!CM:D?y3 S?y2; [y3/y2 - место/тип клика]
!!FU&y2<>14:E; [выход, если не ПКМ]
!!FU8888:Py4/y3/y5/?y6; [y6 - пройденное расстояние]
!!IF:M^Расстояние: %Y6 (%Y4 -> %Y3, %Y5-hex)^; [вывод сообщения]

Также приведу пример из моего собственного кода.
Реализация абилки Астральных Элементалей из WoG UE:

Что за абилка (Click to View)

!?BR&v997>0; При каждом раунде, начиная со второго
!!re v10/0/41:; Проходимся по стекам
!!BMv10:T?y1; Тип монстра в текущем стеке
!!if&y1=251:; Если Астральный Элементаль
!!BMv10:F?y2; Получаем флаги
!!VRy2:&8388608; Клон?
!!co&y2<>0:; Пропускаем клонов
!!BMv10:N?y3; Количество оставшихся монстров
!!co&y3=0:; Пропускаем мертвые стеки
!!BMv10:P?y4; Позиция текущего стека
!!UN:C6919200/4/?y5; Менеджер битвы
!!VRy6&v10<21:S21692; Корректируем смещение
!!VRy6&v10>20:S21696;
!!UN:Cy5/y6/4/?y7; Узнаем количество стеков у текущей стороны
!!SN&y7<20:E5926784/2/y5/y4/50; Если не 20, вызываем клон
!!en:;
!!en:;

Berserker · 18.04.2021 07:15

Получение названий/описаний заклинаний:

!#DC(EDU_WOG_SPELLS_TABLE_ADDR) = 8114880;
!#DC(EDU_SIZEOF_SPELL_STRUCT) = 136;
!#DC(EDU_STRUCT_SPELL_NAME) = 16;
!#DC(EDU_STRUCT_SPELL_SHORT_NAME) = 20;
!#DC(EDU_STRUCT_SPELL_DESCR) = 120;
!#DC(EDU_STRUCT_SPELL_DESCR_BASIC) = 124;
!#DC(EDU_STRUCT_SPELL_DESCR_ADVANCED) = 128;
!#DC(EDU_STRUCT_SPELL_DESCR_EXPERT) = 132;
!#DC(EDU_SPELL_TEXT_NAME) = 1;
!#DC(EDU_SPELL_TEXT_SHORT_NAME) = 2;
!#DC(EDU_SPELL_TEXT_DESCR) = 3;
!#DC(EDU_SPELL_TEXT_DESCR_BASIC) = 4;
!#DC(EDU_SPELL_TEXT_DESCR_ADVANCED) = 5;
!#DC(EDU_SPELL_TEXT_DESCR_EXPERT) = 6;
!?FU(edu_GetSpellText);
!#VA(spellId:x); Spell ID.
!#VA(textType:x); One of EDU_SPELL_TEXT_XXX constants.
!#VA(result:x); Result string.
!!if&(textType)=(EDU_SPELL_TEXT_NAME);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_NAME);
!!el&(textType)=(EDU_SPELL_TEXT_SHORT_NAME);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_SHORT_NAME);
!!el&(textType)=(EDU_SPELL_TEXT_DESCR);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_DESCR);
!!el&(textType)=(EDU_SPELL_TEXT_DESCR_BASIC);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_DESCR_BASIC);
!!el&(textType)=(EDU_SPELL_TEXT_DESCR_ADVANCED);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_DESCR_ADVANCED);
!!el&(textType)=(EDU_SPELL_TEXT_DESCR_EXPERT);
!!VR(fieldOffset:y):S(EDU_STRUCT_SPELL_DESCR_EXPERT);
!!el;
!!SN:F^ShowErmError^/^edu_GetSpellText: invalid spell text type: %(textType)^;
!!VR(result):S(@empty:z);
!!FU:E;
!!en;
!!VR(offset:y):S(spellId) *(EDU_SIZEOF_SPELL_STRUCT) +(fieldOffset);
!!UN:C(EDU_WOG_SPELLS_TABLE_ADDR)/(offset)/(UNC_UINT32)/?(textAddr:y);
!!SN:B(textAddr)/0/?s^temp^;
!!VR(result):Zs^temp^;
!!VRs^temp^:S^^;
!?PI;
!!FU(edu_GetSpellText):P(SPELL_EARTHQUAKE)/(EDU_SPELL_TEXT_DESCR_EXPERT)/?(spellText:z);
!!IF:M^%(spellText)^;

Berserker · 29.04.2021 01:12

Как, имея арт "Сердце Дракона", влиять на тип драконов, появляющихся на поле боя, при помощи ERM?:

!?FU(OnGameEnter);
; убираем зависимость: случайно или от типа почвы.
; ставим: всегда случайно
!!UN:C7763959/2/37008;
; выпиливаем случайный выбор дракона:
; всегда берём первого монстра из массива
; AnyDragon2Summon[Random(0,14)]
!!UN:C7763962/1/0; правим "14" в "0"
!?FU(OnBeforeBattleUniversal);
; подменяем первого монстра в массиве AnyDragon2Summon
!!UN:C8002264/4/132; указываем номер монстра для вызова

Как поменять название строения Грааля в Инферно?:

!?FU(OnGameEnter);
!!VRz250:S^Название строения^;
!!VRz251:S^Описание строения^;
; Важно. Нельзя трогать переменные z250 и z251
!!VRy1:S250*512 +9597416;
!!VRy2:S251*512 +9597416;
!!UN:C6968548/4/y1; [правим ссылку названия здания Грааля Инферно]
!!UN:C6977820/4/y2; [правим ссылку описания здания Грааля Инферно]

Raistlin · 05.05.2021 00:11

Добавление нового события для существующего объекта:

*Выдержка из WoG UE
*Новое событие в Костре
!?OB12;
!!SN:W^WoGUE.Campfire%V998%V999%V1000.Setup^/?y1; Статус настройки костра
!!if&y1=0:; Если не настроен
!!VRy1:S1; Берем случайное число
!!VRy1:R8;
!!SN:W^WoGUE.Campfire%V998%V999%V1000.Setup^/y1; Сохраняем результат
!!FU&y1>6:E; Если не повезло - выход
[:Campfire.Handle]
!!if&1000:;
!!IF:Q1/z163519; Если что-то есть, спрашиваем игрока о том, хочет ли он приблизиться
!!OBv998/v999/v1000&-1:T125; Заменяем тип объекта (125 - водоросль)
!!FU&-1:E; Выход, если не хочет
!!en:;
!!if&y1=6:; Дарим Ос
!!FU(WoGUE.Campfire.GiveTroops):P163509/126;
!!FU:E;
!!en:;
!!if&y1=5:; Дарим Пауков
!!FU(WoGUE.Campfire.GiveTroops):P163508/124;
!!FU:E;
!!en:;
!!FU&-1000:E; На ИИ не нападаем
!!if&y1<3:;
!!FU(WoGUE.Campfire.Battle):P163506/124; Бой с Пауками (Значения 1 и 2)
!!FU:E;
!!en:;
!!FU(WoGUE.Campfire.Battle):P163507/126; Бой с Осами (Значения 3 и 4)
!!el:;
!!SN:G[Campfire.Handle]; Прыгаем к обработчику, если костер уже настроен
!!en:;
!$OB12;
!!SN:W^WoGUE.Campfire%V998%V999%V1000.Setup^/?y1; Статус настройки костра
!!OBv998/v999/v1000&y1<7:T12; Если настроен, восстанавливаем тип объекта
!?FU(WoGUE.Campfire.GiveTroops);
!!VRy1:S5;
!!VRy1:R10; Сколько присоеденится
!!if&1000:;
!!IF:M1/zx1;
!!HE-1:C2/x2/y1/1; Если человек, спрашиваем
!!el:;
!!HE-1:C2/x2/y1/0; ИИ даем сразу
!!en:;
!!SN:W^WoGUE.Campfire%V998%V999%V1000.Setup^/10; Отмечаем, что костер зачистили
!?FU(WoGUE.Campfire.Battle);
!!VRy1:S20;
!!VRy1:R25; Число нападающих
!!HE-1:P?y50/?y51/?y52;
!!IF:M1/zx1;
!!HE-1:Ty50/y51/y52/x2/y1; Бой
!!HE-1:O?y2; Проверяем, победил герой или нет
!!SN&y2<>-1:W^WoGUE.Campfire%V998%V999%V1000.Setup^/10; Если победил (остался у владельца), отмечаем, что костер зачистили

Способность Воплощений Сехмет - существ 4 уровня в новом городе Бастионе:

; Кража магии
!?BG0;
!!BG:A?y1; Тип действия
!!FU&y1<>7:E; Выход, если не выстрел
!!BG:N?y2;
!!BMy2:T?y3;
!!if&y3=204:; Если ходит Воплощение Сехмет
!!BG:E?y4; Выясняем, на какой стек направлена атака
!!SN:W^WoG359.PriestessShoots^/1; Отмечаем, что был совершен выстрел
!!SN:W^WoG359.PriestessShoots.Attacker^/y2; Сохраняем индексы стеков
!!SN:W^WoG359.PriestessShoots.Target^/y4;
!!en:;
!?BG1;
!!SN:W^WoG359.PriestessShoots^/?y1;
!!FU&y1=0:E;
!!SN:W^WoG359.PriestessShoots^/0;
!!SN:W^WoG359.PriestessShoots.Attacker^/?y2;
!!SN:W^WoG359.PriestessShoots.Target^/?y3;
!!BA:Q?y50; Статус быстрой битвы
!!IF&y50=0:V1/0; Статус проигрывания звука воровства
!!IF&y50=1:V1/1; Звуки не проигрываются, если быстрая битва
; Вызываем функцию ApplySteal для всех полезных заклинаний
!!re i/27/58:;
!!SSi:F?y4; Флаги заклинания
!!VRy4:&2048; Проверка на "дружественность"
!!co&y4=0:; Переходим к следующей итерации, если флага нет
!!FU(ApplySteal):Pi/y2/y3;
!!en:;
!?FU(ApplySteal);
!!BMx3:Gx1/?v1/?n;
!!FU&v1=0:E; Выход, если полезное заклинание не наложено
!!SSx1:L?y1; Уровень заклинания
!!VRy2:S5 -y1 *20; Вероятность выпадения
!!VRy3:S0 R100; Генерируем случайное число
!!FU&y3>y2:E; Выход, если не повезло
!!BMx2:Mx1/v1/1; Наклaдываем магию на Воплощений (всегда базовый уровень)
!!BMx3:Z?y4; Получаем структуру атакуемого стека
!!SN:E4473392/2/y4/x1; Снимаем заклинание
!!if&-1:;
!!VRz1:S^VISIONS^;
!!SN:Pz1; Проигрываем звук
!!IF:V1/1; Сохраняем статус проигрывания, чтобы не было лишнего шума :)
!!BMx3:P?y5; Получаем позицию атакующего стека
!!VRz2:S^SpellSteal.def^;
!!FU(PlayCustomAnimation):P0/2/y5/100/0/0/1; Проигрывание анимации воровства заклинания
!!en:;
!!BMx3:T?y6;
!!UN:N1/z2/x1; Узнаем название существа и заклинания
!!UN:N3/z3/y6/1;
!!VRz4:S^Воплощения Сехмет забирают заклинание %Z2 у отряда %Z3.^;
!!BU:Mz4; Показываем сообщение в лог

Одна из пособностей Надсмотрщиков - существ 2 уровня в новом городе Бастионе:
Описание: "Каждый Надсмотрщик, находящийся не в армии героя (то есть, в каком-либо гарнизоне), повышает общий доход на 5 единиц золота. Если в гарнизоне шахты находится не менее 50 Надсмотрщиков (суммируются все стеки), то ровно один раз в каждые 3 дня эта шахта приносит двойной доход."

; В данном примере показано, как повышается доход из городских гарнизонов. Остальной код тоже давно написан, но пока что опубликован не будет.
!?FU(OnCalculateTownIncome);
!#VA(townId:x) (income:x);
!!VR(overseers:y):S0;
!!re (iterator:y)/0/6:;
!!CA0/(townId):M2/(iterator)/?(creatureType:y)/?(count:y);
!!VR(overseers)&(count)>0/(creatureType)=199:+(count);
!!en:;
!!VR(money:y):S(overseers) *5;
!!VR(income):+(money); К доходу города добавляется количество Надсмотрщиков*5

Я принял решение выложить немного кода, относящегося к Бастиону, по двум причинам: во первых, чтобы продемонстрировать его работоспособность, и во вторых, чтобы справочник развивался, а также, чтобы у людей всегда были под рукой примеры того, как можно реализовывать различные нестандартные игровые бонусы.
Да, кстати, если у кого будут время и настроение, можете попробовать свои силы в реализации парочки неготовых способностей. Просто напишите мне, я буду рад любой помощи.

Оформление кода, желательно, делать таким же, как у меня.

Berserker · 12.07.2021 05:28

!?CM0;
!!CM:R0;
!!FU(edu_GetHeroClassName):P(HERO_EDRIC)/?(className:z);
!!IF:M^%(className)^;
!?FU(edu_GetHeroClassName);
!#VA(heroId:x);
!#VA(result:x); string
!!VR(savedV1:y):Sv1;
!!HE(heroId):Z?(heroStruct:y);
!!SN:E5083616/(CALLCONV_THISCALL)/(heroStruct);
!!SN:Bv1/d/?s^temp^;
!!VRv1:S(savedV1);
!!VR(result):Zs^temp^;
!!VRs^temp^:S^^;

daemon_n · 09.11.2021 07:26

Получение координат курсора при движении мыши в любых диалогах
+ Бонус получение id Элемента при наведении на него: © daemon_n & Hawaiing

Необходимо поставить хук на движение мыши в диалогах:
Второй хук для тех, кто хочет Красиво)
!!SN:L^EraPlugins\erm_hooker.era^/?y1;
!!if&y1<>0;
!!SN:Ay1/^SetHook^/?(hooker:y);
!!SN:E(hooker)/1/6290592/(Dlg_OnMouseMove); [005FFCA0 6290592 Dlg_OnMouseMove __this]
!!SN:E(hooker)/1/6287088/(DlgItem_ShowHint); [005FEEF0 6287088 DlgItem_ShowHint_callParentVMT4 __fastcall]
!!en;
ERM 1 Вариант:
!!SN:X?y1;
!!VRy4:Sy1+12;
!!UN:Cy4/4/?y14; ESP
!!VRy15:Sy14+8;
!!VRy16:Sy14+12;
!!UN:Cy15/4/?y25;[xabs]
!!UN:Cy16/4/?y26;[yabs]
ERM 2 Вариант:
!#VA(dlg:x);
!!UN:C(dlg)/40/4/?(x:y); получили точную х- координату мыши В игре ! Аналог CM:A?(x:y)/d;
!!UN:C(dlg)/44/4/?(y:y); получили точную y- координату мыши В игре ! Аналог CM:Ad/?(y:y);
Идём дальше - получаем ID Элемента на позиции
!!FU(H3Dlg_GetCurrentDlg):P?(currentDlg:y);
!!SN:E6289824/2/(currentDlg)/(x)/(y); Получаем структуру элемента в v1 [005FF9A0 6289824 Dlg_ItemAtPos __this]
!!UN&v1>0:Cv1/16/2/?(itemId:y); Используя мои хаки со смещением, получаем Id элемента)) Аналог !!CM:I?(itemId:y);
Если мы умнички и хотим получить Id элемента только при наведении на него, сохраняем значения в Глобальные переменные и идём дальше;
!!VRi^Dlg_mouseX^:S(x);
!!VRi^Dlg_mouseY^:S(y);
Нужен наш второй хук DlgItem_ShowHint
!?FU(DlgItem_ShowHint);
и повторяем действие, но уже с имеющимися координатами
!!FU(H3Dlg_GetCurrentDlg):P?(currentDlg:y);
!!SN:E6289824/2/(currentDlg)/i^Dlg_mouseX^/i^Dlg_mouseY^; Получаем структуру элемента в v1 [005FF9A0 6289824 Dlg_ItemAtPos __this]
!!UN&v1>0:Cv1/16/2/?(itemId:y); Используя мои хаки со смещением, получаем Id элемента)) Аналог !!CM:I?(itemId:y);

SergOz · 14.08.2022 08:09

!?FU(OnBattleScreenMouseClick)|i^mouse_battleHex^=252/i^mouse_battleHex^=253;
!!if&i^mouse_action^=(MOUSE_LMB_PRESSED)/i^mouse_item^=0;
!!OW:Cd/?(meID:y);
!!if&i^battle_owner_0^=(meID);
!!VR(hostileSide:y):S(BATTLE_RIGHT);
!!el;
!!VR(hostileSide:y):S(BATTLE_LEFT);
!!en;
!!VR(clickSide:y):Si^mouse_battleHex^ -252;
!!if&(clickSide)=(hostileSide);
!!UN:C(COMBAT_MANAGER)/4/?(cmbMgr:y) C(cmbMgr)/78528/4/?(storeActiveSide:y) C(cmbMgr)/78528/4/(hostileSide);
!!UN:C(cmbMgr)/81268/1/?(storeNoCastLimit:y) C(cmbMgr)/81268/1/(TRUE);
!!SN:E5893136/(CALLCONV_THISCALL)/(cmbMgr);
!!UN:C(cmbMgr)/78528/4/(storeActiveSide) C(cmbMgr)/81268/1/(storeNoCastLimit:y);
!!en;
!!en;

Строку !!OW:Cd/?(meID:y), если версия ERA ещё не поддерживает эту команду, можно заменить на:

!!UN:C(GAME_MANAGER)/(UNC_UINT32)/?(gm:y);
!!SN:E5039840/2/(gm);
!!VR(meId:y):Sv1;

Threaded Mode \| Linear Mode Сложные скрипты (справочник) » Готовые решения
Author	Message