Threaded Mode | Linear Mode

Archer30 · 10.03.2021 10:26

Hi! I have a question about arrays in ERM 2.
Is it possible to make a variable in a variable with array?

!?FU(OnEveryDay);
!#VA(firstLevelMon[9]:y);
!!VR(value:y):S1;
!!VR(firstLevelMon):C(MON_PIKEMAN)/(MON_DWARF)/(MON_GREMLIN)/(MON_IMP)/(MON_SKELETON)/(MON_TROGLODYTE)/(MON_GOBLIN)/(MON_GNOLL)/(MON_PIXIE);
!!IF:M^%(firstLevelMon[%(value)])^;

Looks like %(firstLevelMon[%(value)]) is wrong 102

Berserker · 10.03.2021 14:00

Archer30, nope, ERM is too low level. We have to define pointer to array item and access it indirectly.

In Lua it would be firstLevelMons[value], but in ERM 2:

!?FU(OnEveryDay);
!#VA(firstLevelMons[9]:y);
!!VR(firstLevelMonPtr:y):S(@firstLevelMons) +1; Ptr = pointer = y-index of array first item (like 50 for y50) + logical offset/index
!!VR(firstLevelMons):C(MON_PIKEMAN)/(MON_DWARF)/(MON_GREMLIN)/(MON_IMP)/(MON_SKELETON)/(MON_TROGLODYTE)/(MON_GOBLIN)/(MON_GNOLL)/(MON_PIXIE);
!!VR(mon:y):Sy(firstLevelMonPtr); get the value using yy3-like syntax if y3 holds 51, it's the same as y51
!!IF:M^%(mon)^;

Archer30 · 10.03.2021 14:40

Hmmm, in this particular case, the name variable is worse than v-variable. I can simplify the code by:

!?FU(OnEveryDay);
!#VA(firstLevelMon[9]:y);
!!VR(value:y):S3;
!!VRv2:C(MON_PIKEMAN)/(MON_DWARF)/(MON_GREMLIN)/(MON_IMP)/(MON_SKELETON)/(MON_TROGLODYTE)/(MON_GOBLIN)/(MON_GNOLL)/(MON_PIXIE);
!!IF:M^%v(value)^;

Berserker · 10.03.2021 17:06

It's awful code. Do not use global variables for almost the same purpose but with invalid logics. You th code I gave above, press F11 and see, what it's compiled too.
Even better try this code for testing:

!?FU(OnEveryDay);
!#VA(dummy[66]:y);
!#VA(firstLevelMons[9]:y);
!!VR(firstLevelMonPtr:y):S(@firstLevelMons) +1; Ptr = pointer = y-index of array first item (like 50 for y50) + logical offset/index
!!VR(firstLevelMons):C(MON_PIKEMAN)/(MON_DWARF)/(MON_GREMLIN)/(MON_IMP)/(MON_SKELETON)/(MON_TROGLODYTE)/(MON_GOBLIN)/(MON_GNOLL)/(MON_PIXIE);
!!VR(mon:y):Sy(firstLevelMonPtr); get the value using yy3-like syntax if y3 holds 51, it's the same as y51
!!IF:M^%(mon)^;

You'll see something like

!!VRy80:S66 +1; y80 points to y67 - second array item
!!VRy81:Syy80; y80 now holds value from y67
!!IF:M^%y81^;

Archer30 · 10.03.2021 17:50

Berserker, I understand you are not a fan of mixing variable type. I myself never want to mess up with that, but it's sometimes necessary to use v. Check this:

!?FU(WOG_EndOfTurn); [requires WoG Scripts to work, check every hero on turn end]
!!OW:H-1/2/0;
!!re i/1/v2;
!!VR(heroIndex:y):Si +2;
!!OW:H-1/(heroIndex)/i;
!!FU(HeroMustHaveArmy):Pv(heroIndex);
!!en;

The command uses v index. What should I do to get rid of v-variable in this case? 102

Berserker · 10.03.2021 19:15

Array access code via pointers does not need v-vars at all. The code above can be converted to safe:

!!OW:C?(player:y);
!!re i/(HERO_FIRST)/(HERO_LAST_WOG);
!!HEi:O?(heroOwner:y);
!!FU(HeroMustHaveArmy)&(heroOwner)=(player):Pi;
!!en;

Archer30 · 10.03.2021 20:06

Hmmm, maybe I was wrong about coding. I thought your code would require much more calculation (as you loop through all heroes) and may extend the time of passing the day a little bit.

Berserker · 10.03.2021 21:12

Try it, it won't. 255 iterations, 2 commands and one condition evaluation. ERM speed is about 400 000 lightweight receivers/sec.

Berserker · 11.03.2021 18:03

In response to igrik and Archer30 array indexing request, ERA Team presents v3.3.7:

!#VA(firstLevelMons[9]:y);
!!VR(firstLevelMons):C(MON_PIKEMAN)/(MON_DWARF)/(MON_GREMLIN)/(MON_IMP)/(MON_SKELETON)/(MON_TROGLODYTE)/(MON_GOBLIN)/(MON_GNOLL)/(MON_PIXIE);
!!re i/0/(firstLevelMons[SIZE])/1/-1;
!!IF:M^%(firstLevelMons[i])^;
!!en;

daemon_n · 11.03.2021 20:39

Berserker, ~~что за -1?~~ прочитал в теме обновления.
Божечки, скоро ERM превратится в c++ 96-copy

P.S: вместо гномов кентавры Yes

Berserker · 11.03.2021 21:47

daemon_n, 5-й параметр был введён сто лет назад. Конечное значение счётчика всегда ограниченно суммой пятого и третьего параметра.
Большинство цикло идут от 0 до КОЛВО_ЧЕГО-ТО - 1. Иногда нужно пропустить последний элемент вообще. Тогда будет -2.

igrik · 11.03.2021 21:52

(11.03.2021 18:03)Berserker Wrote:
!!re i/0/(firstLevelMons[SIZE])/1/-1;
!!IF:M^%(firstLevelMons[i])^;
!!en;

Аллилуйя!

Bes · 11.03.2021 22:33

igrik, ты теперь часть ERA Team, как я понимаю, а потому все твои взывания к неким нужностям будут так или иначе воплощаться в ERA3 Spiteful

Пора засчехлять мешок с отложенными хотелками Spiteful

igrik · 11.03.2021 23:31

Bes, не поверишь, но хотелок у меня больше нет.
Раньше были 3: расширенное UN:C, получение структуры героя и стека. Теперь они есть.

В ERM2 сложно работать с массивами в циклах. Решение тут крайне необходимо. Надеюсь оно в скором времени появится в реальности.
Итого - мой мешок с хотелками пуст ))

Вот WoG Scripts 2 допилю (через год, два) и вообще на пенсию уйду.

Berserker · 12.03.2021 01:14

igrik Wrote:Надеюсь оно в скором времени появится в реальности.

Так уже же: https://mods.hmm35.ru/Era%20Update.exe

Threaded Mode \| Linear Mode Школа ERM 2 » ERM 2.0 для ERA III
Author	Message