Threaded Mode | Linear Mode

SergOz · 09.10.2020 06:30

Night, это была проверка функциональности "старины" ВоГ'а: ведь раньше я не смог решить эту задачку.
Без SN:O, тоже можно обойтись, но о-о-очень громоздкий будет скрипт.
Эра рулит! Laie_43

Bes · 09.10.2020 13:54

SergOz, красиво, 132

один недостаток - в WoG v100 занята, но есть временные v101-v111, надо было чуть сместить
и v200 используется в постоянке (а вот v201 свободна). Правда зачем тебе там вообще v200, взял бы v1 Yes

А то мало ли, зайдёт кто-то и скопирует для себя в игру этот готовый вариант, а потом будут баги от конфликтов с базовыми скриптами WoG

Berserker · 09.10.2020 14:56

(09.10.2020 06:13)SergOz Wrote: Стало интересно написать скрипт, отслеживающий посещение объектов для каждого игрока, без команд Эры.
Взял для примера Университет (раз был о нём разговор). Получилось следующее...

SergOz, отлично.

Не тестировал, могут быть опечатки:

ZVSE2
!$OB(OBJ_UNIVERSITY); After visiting university, obvious comment for old ERM students
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_SetUniverVisited):Pv998/v999/v1000/(currentPlayer)/(TRUE); Update visited flag
!?FU(OnAdvMapTileHint); On mouse over adventure map tile
!#VA(x:x) (y:x) (z:x) (objType:x) (objSubtype:x);
!!FU&(objType)<>(OBJ_UNIVERSITY):E; Exit if not university
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_IsUniverVisited):P(x)/(y)/(z)/(currentPlayer)/?(visited:y); Check if visited
!!if&(visited)<>(FALSE):;
!!MM:M^Visited^;
!!el:;
!!MM:M^Not visited^;
!!en;
!?FU(OnAdventureMapRightMouseClick);
!!CM:P?(x:y)/?(y:y)/?(z:y); Get click coordinates
!!OB(x)/(y)/(z):T?(objType:y); Get object under cursor
!!FU&(objType)<>(OBJ_UNIVERSITY):E; Exit if not university
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_IsUniverVisited):P(x)/(y)/(z)/(currentPlayer)/?(visited:y); Check if visited
!!if&(visited)<>(FALSE):;
!!IF:M1/4/^Visited^;
!!el:;
!!IF:M1/4/^Not visited^;
!!en;
!?FU(serg_IsUniverVisited);
; Returns TRUE if university with given coordinates is visited by specified player
; Example FU(serg_IsUniverVisited):P(x)/(y)/(z)/(PLAYER_BLUE)/?(isVisited:y)
!#VA(x:x) (y:x) (z:x); University coordinates (x1..x3 for old ERM students)
!#VA(player:x); Player color. (x4 for old ERM students)
!#VA(result:x); Boolean. Function result is either (TRUE) or (FALSE).
; It means x5 will be either 1 or 0 for old ERM students.
!!SN:O?(x)/?(y)/?(z); Get coordinates of object entrance
!!VR(bitMask:y):Si^serg_univer_%x_%y_%z^; Get this university bit mask
!!VR(testBit:y):S1 Sd<<(player); Test bit is 1 shifted left by PlayerColor number of positions
!!VR(bitMask):&(testBit); Check necessary bit
!!VR(result):S(FALSE); Update result
!!VR(result)&(bitMask)<>0:S(TRUE);
!?FU(serg_SetUniverVisited);
; Updates 'visited' flag for particular university and player.
; Example FU(serg_SetUniverVisited):P(x)/(y)/(z)/(currentPlayer)/(TRUE);
!#VA(x:x) (y:x) (z:x); University coordinates (x1..x3 for old ERM students)
!#VA(player:x); Player color. (x4 for old ERM students)
!#VA(visited:x); Boolean. (TRUE) or (FALSE). (x5 is 1 or 0 for old ERM students)
!!SN:O?(x)/?(y)/?(z); Get coordinates of object entrance
!!VR(bitMask:y):Si^serg_univer_%x_%y_%z^; Get this university bit mask
!!VR(bit:y):S1 Sd<<(player); Necessary bit is 1 shifted left by PlayerColor number of positions
!!if&(visited)<>(FALSE):;
!!VR(bitMask):|(testBit); Either set bit
!!el:;
!!VR(bitMask):Sd~(testBit); Or unset bit using d~ syntax
!!en;
!!VRi^serg_univer_%x_%y_%z^:S(bitMask);

Archer30 · 11.10.2020 21:45

A request from Canary. He's a bit nervous asking a question here so I help him out.

Is there a good way to allow moving/attacking after casting a spell with a creature (e.g. Farie Dragon cast a magic arrow, then move to another hex within a single turn)?
Currently what Canary does is to give extra move with morale after casting.
This could work but it's a bit weird if the caster is undead (as undead creatures are never affected by morale).

Thanks in advanced!

SergOz · 11.10.2020 22:06

Archer30, Вы написали в теме готовых скриптов. Для написания такого скрипта не хватает данных.
В какой ситуации должно происходить дополнительное действие боевого отряда?
Если же Вам нужна просто подсказка, то я когда-то воспользовался подсказкой от igrik:

; сделать стек активным
!!UN:C6919200/4/?y10;
!!SN:E4607760/2/y10/[сторона (0...1)]/[номер стека у этой стороны (0...20)];

и у меня всё отлично получилось.

Archer30 · 11.10.2020 22:28

Thanks SergOz, it seems my limited knowledge about scripts did not allow me to ask a question properly. Rolleyes

Please allow me rephrase:

"Is there a way to make all creatures with single target casting ability (ie. Farie Dragon, Santa Gremlin and not Enchanter nor Magog) to move/attack after casting a spell in a single turn?"

I will forward the hint to Canary and see if his problem is sovled.

Berserker · 11.10.2020 22:36

The answer is probably activate the stack again after casting in !?BG1 using function

!?FU(cnr_ActivateStack);
; x1 -stack ID (0..41)
!!VRy1:Sx1 :21;
!!VRy2:Sx1 %21;
!!UN:C6919200/4/?y10;
!!SN:E4607760/2/y10/y1/y2;

Archer30 · 12.10.2020 07:17

Thanks Berserker, that should work. Even I can understand it now. 132

manlenya · 27.10.2020 17:45

Подскажите скрипт для пустого артефакта на каст заклинания в начале боя на свои войска, как в альянсе ангелов или аотд.
на форуме https://forum.df2.ru/index.php?showtopic=2457 видел такой, но почему-то не срабатывает.
!?BA0;
!!BA:H0/?v30;
!!BA:H1/?v31;
!!HEv30&v30<>-2:A2/168/d/?v32;
!!HEv31&v31<>-2:A2/168/d/?v33;
!!VRv25&v30<>-2/v32=1:S0;
!!DO23/0/20/1&v30<>-2/v32=1:P;
!!VRv25&v31<>-2/v33=1:S21;
!!DO23/0/20/1&v31<>-2/v33=1:P;
!?FU23;
!!BMv25:M33/99/3;
!!VRv25:Sd1;

Berserker · 27.10.2020 17:51

Там проверялся артефакт номер 168. Пробовали давать его герою?

SergOz · 27.10.2020 19:35

manlenya, если тебе нужен разовый каст закла в начале боя (как в Альянсе Ангелов), то можно так.

;
!?BA0;
!!VRv99:S0;
; Когда одевается кираса
!?AE1&v998=167; здесь 167 это номер пустого арта - кирассы. Меняй номер, если другой арт.
!!IF:W-1; обращаемся к текущему герою (-1)
!!VRw1:S1; фиксируем в его личной переменной (w1) признак "надетости" кирасы(1).
; Когда снимается кираса
!?AE0&v998=167;
!!IF:W-1; обращаемся к текущему герою (-1)
!!VRw1:S0; фиксируем в его личной переменной (w1) признак "снятости" кирасы (0).
; Перед каждым действием любого стека в бою:
!?BG0&v99=0; разовое действие в начале боя.
!!BG:H?y1 N?y2; в y1 читаем номер героя-владельца стека, в y2 - номер этого стека на поле боя (0..41)
!!FU&y1=-1:E; если стек не принадлежит никакому герою - выходим
!!IF:Wy1; выбираем героя, к которому будем обращаться
!!FU&w1=0:E; если у этого героя не надета кираса - выходим
!!BG:Q?y3; наш герой атакующий или защищающийся?
!!BHy3:C36/0/3/0; колдуем волшебное зеркало (№36) на все свои войска
!!BHy3:M0; позволяем ещё раз воспользоваться книгой заклинаний
!!VRv99:S10; чтобы скрипт больше не срабатывал

Не забудь дать название арту и описание.
Это, наверное, не лучший вариант, но я его написал ещё лет 5 назад

P.S. Ах, да - такой скрипт будет уменьшать манну героя на стоимость кастуемого закла, но ты можешь сразу пополнить её.

U.P.D. Проверил только что - скрипт не стабильно работает.

V_Maiko · 14.11.2020 01:50

Does anyone have or can make a script for certain range unit (Archer for example) to return the shot when they are attacked from a distance? (what I'm asking for is something called "Range Retaliation").

Berserker · 14.11.2020 03:50

V_Maiko, I thought there was such a ERM function in UN:C theme to trigger distant attack.

V_Maiko · 14.11.2020 04:29

Berserker, And do you think I can do it by myself? Not even PerryR knew how to use UN:C when I asked him for help with a script to change the sounds to the creatures. Unsure

Berserker · 14.11.2020 05:32

ZVSE2
!?FU(edu_BattleStack_Shoot);
; Forces one stack to shoot at another one.
!#VA(attackerStackId:x) (defenderStackId:x);
!!BM(attackerStackId):Z?(attackerStackStruct:y);
!!BM(defenderStackId):Z?(defenderStackStruct:y);
!!SN:E4453920/(CALLCONV_THISCALL)/(attackerStackStruct)/(defenderStackStruct);
!?FU(OnBattleScreenMouseClick);
!!CM:S?(clickType:y);
!!FU&(clickType)<>(MOUSE_RMB_PRESSED):E;
!!CM:D?(clickPos:y);
!!BU:E(clickPos)/?(defenderStack:y);
!!FU&(defenderStack)=(NO_MON):E;
!!CM:R(FALSE);
!!BG:N?(stack:y);
!!FU(BattleStack_Shoot):P(stack)/(defenderStack);

Press RMB over enemy creature in battle to make current stack to shoot at destination stack. Anyway, this is not full "Distant retaliation" implementation.
It's not full distant retaliation script. The full variant will lack AI, will need to check for Ammo to retaliate, some creature attack with magic, so they should retaliate magically, etc.

Threaded Mode \| Linear Mode Если просто нужен скрипт
Author	Message