Threaded Mode | Linear Mode

Bes · 06.09.2020 02:58

(06.09.2020 02:47)Berserker Wrote:
!!CM:P?(x:y)/?(y:y)/?(z:y);
!!IF:L^You clicked on %(x) %(y) %(z)^;

Вот такое реально удобнее, бесспорно, не надо парить голову в середине триггера с сотней строк в теле какую же там щас могу взять y-переменную Mail1

а вот с остальным пока реально сложно переучить беглое чтение кода, да... Bad

Berserker · 06.09.2020 03:04

Bes, кроме этого константы вида (OBJ_MONSTER) вместо "54" и именованные функции. Всё.

Bes · 06.09.2020 03:11

Berserker, сложно читать из-за увеличения длин строк, это я имел ввиду. И да, за многолетний период привычные типы на карте 98, 54 быстро воспринимаешь, чем (OBJ_TOWN),(OBJ_MONSTR) и т.д.
На всё это опять нужно время, потому ветеранам будет проще писать код смешанный (где-то новые команды, а где-то привычные старые нечитаемые для других числа)

Berserker · 07.09.2020 21:06

Bes, читать сложно до первого написанного сложного триггера. Мозг — штука пластичная.

Пример:

(12.09.2020 00:32) Wrote:
ZVSE2
!#DC(SERG_BA_HERO_CAST) = 1;
!#DC(SERG_BATTLE_STACKS_PER_SIDE) = 21;
!?FU(OnMagicBasicResistance);
!!BG:A(action:y) N?(stack:y);
!!if&(action)=(SERG_BA_HERO_CAST):;
!!VR(side:y):(stack) :(SERG_BATTLE_STACKS_PER_SIDE);
!!BH(side):N?(casterHero:y);
!!HE(casterHero):S(SKILL_SORCERY)/?(sorcerySkill:y);
!!en;

Berserker · 08.09.2020 03:13

Era 3.0.5+. ERM 2.0
Возвращает логическую принадлежность монстра конкретному городу/фракции. Изменения в настройках городов не влияют на работу функции.

!?FU(fun_GetMonsterFraction);
!#VA(monType:x) (result:x);
!!VR(result):S(NO_TOWN);
!!if&(monType)<=(MON_CHAOS_HYDRA):;
!!VR(result):S(monType) :14;
!!el&(monType)>=(MON_AIR_ELEMENTAL)/(monType)<=(MON_WATER_ELEMENTAL):;
!!VR(result):S(TOWN_CONFLUX);
!!el&(monType)>=(MON_PIXIE)/(monType)<=(MON_MAGIC_ELEMENTAL):;
!!VR(result):S(TOWN_CONFLUX);
!!el|(monType)=(MON_ICE_ELEMENTAL)/(monType)=(MON_MAGMA_ELEMENTAL)/(monType)=(MON_STORM_ELEMENTAL):;
!!VR(result):S(TOWN_CONFLUX);
!!el&(monType)>=(MON_ENERGY_ELEMENTAL)/(monType)<=(MON_PHOENIX):;
!!VR(result):S(TOWN_CONFLUX);
!!el&(monType)>=(MON_SUPREME_ARCHANGEL)/(monType)<=(MON_SACRED_PHOENIX):;
!!VR(result):S(monType) -(MON_SUPREME_ARCHANGEL) +(TOWN_CASTLE);
!!el|(monType)=(MON_NIGHTMARE)/(monType)=(MON_DRACOLICH):;
!!VR(result):S(TOWN_NECROPOLIS);
!!el&(monType)=(MON_HELL_STEED):;
!!VR(result):S(TOWN_INFERNO);
!!el&(monType)=(MON_SYLVAN_CENTAUR):;
!!VR(result):S(TOWN_RAMPART);
!!el&(monType)=(MON_WAR_ZEALOT):;
!!VR(result):S(TOWN_CASTLE);
!!en;

Berserker · 09.10.2020 15:00

Пример скрипта на информацию о посещении университетов (Click to View)

ZVSE2
!$OB(OBJ_UNIVERSITY); After visiting university, obvious comment for old ERM students
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_SetUniverVisited):Pv998/v999/v1000/(currentPlayer)/(TRUE); Update visited flag
!?FU(OnAdvMapTileHint); On mouse over adventure map tile
!#VA(x:x) (y:x) (z:x) (objType:x) (objSubtype:x);
!!FU&(objType)<>(OBJ_UNIVERSITY):E; Exit if not university
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_IsUniverVisited):P(x)/(y)/(z)/(currentPlayer)/?(visited:y); Check if visited
!!if&(visited)<>(FALSE):;
!!MM:M^Visited^;
!!el:;
!!MM:M^Not visited^;
!!en;
!?FU(OnAdventureMapRightMouseClick);
!!CM:P?(x:y)/?(y:y)/?(z:y); Get click coordinates
!!OB(x)/(y)/(z):T?(objType:y); Get object under cursor
!!FU&(objType)<>(OBJ_UNIVERSITY):E; Exit if not university
!!OW:C?(currentPlayer:y); Get current player
!!FU(serg_IsUniverVisited):P(x)/(y)/(z)/(currentPlayer)/?(visited:y); Check if visited
!!if&(visited)<>(FALSE):;
!!IF:M1/4/^Visited^;
!!el:;
!!IF:M1/4/^Not visited^;
!!en;
!?FU(serg_IsUniverVisited);
; Returns TRUE if university with given coordinates is visited by specified player
; Example FU(serg_IsUniverVisited):P(x)/(y)/(z)/(PLAYER_BLUE)/?(isVisited:y)
!#VA(x:x) (y:x) (z:x); University coordinates (x1..x3 for old ERM students)
!#VA(player:x); Player color. (x4 for old ERM students)
!#VA(result:x); Boolean. Function result is either (TRUE) or (FALSE).
; It means x5 will be either 1 or 0 for old ERM students.
!!SN:O?(x)/?(y)/?(z); Get coordinates of object entrance
!!VR(bitMask:y):Si^serg_univer_%x_%y_%z^; Get this university bit mask
!!VR(testBit:y):S1 Sd<<(player); Test bit is 1 shifted left by PlayerColor number of positions
!!VR(bitMask):&(testBit); Check necessary bit
!!VR(result):S(FALSE); Update result
!!VR(result)&(bitMask)<>0:S(TRUE);
!?FU(serg_SetUniverVisited);
; Updates 'visited' flag for particular university and player.
; Example FU(serg_SetUniverVisited):P(x)/(y)/(z)/(currentPlayer)/(TRUE);
!#VA(x:x) (y:x) (z:x); University coordinates (x1..x3 for old ERM students)
!#VA(player:x); Player color. (x4 for old ERM students)
!#VA(visited:x); Boolean. (TRUE) or (FALSE). (x5 is 1 or 0 for old ERM students)
!!SN:O?(x)/?(y)/?(z); Get coordinates of object entrance
!!VR(bitMask:y):Si^serg_univer_%x_%y_%z^; Get this university bit mask
!!VR(testBit:y):S1 Sd<<(player); Necessary bit is 1 shifted left by PlayerColor number of positions
!!if&(visited)<>(FALSE):;
!!VR(bitMask):|(testBit); Either set bit
!!el:;
!!VR(bitMask):Sd~(testBit); Or unset bit using d~ syntax
!!en;
!!VRi^serg_univer_%x_%y_%z^:S(bitMask);

igrik · 09.10.2020 15:08

Обучающие примеры скриптов на ERM 2.0
Парочка переписанных WoG скриптов (комментарии тут нужны только в редких случаях)
А код сам по себе уже вполне читаем.

ERM 2: выбор класса командира (Click to View)

ERM 2: быстрая настройка знамён полководца (Click to View)

ERM 2: Новые поля битв (Click to View)

Berserker · 09.10.2020 15:13

Code:

!!SN:T^wog_186.title^/?z2;

!!SN:T^wog_186.standart^/?z3;

!!SN:T^wog_186.cancel^/?z4;

!!SN:T^wog_186.noHired^/?z5;

Можно прямо в !!IF:G(ERM_RADIO)/2/1024/^%T(wog_186.title)^/...
Все 4 переменные.

igrik · 09.10.2020 15:17

(09.10.2020 15:13)Berserker Wrote:

Code:

!!SN:T^wog_186.title^/?z2; !!SN:T^wog_186.standart^/?z3; !!SN:T^wog_186.cancel^/?z4; !!SN:T^wog_186.noHired^/?z5;
Можно прямо в !!IF:G(ERM_RADIO)/2/1024/^%T(wog_186.title)^/...
Все 4 переменные.

Агонь

Буду учитывать в дальнейшем!

Berserker · 09.10.2020 15:19

!!FU(IntLog2):P(bits)/?(type:y); вместо ручного определения соотношения бита и номера пункта меню

Berserker · 09.10.2020 15:26

Code:

!!UN:N3/(paladin:z)/(MON_PALADIN_A)/0;

!!UN:N3/(hierophant:z)/(MON_HIEROPHANT_A)/0;

!!UN:N3/(temple:z)/(MON_TEMPLE_GUARDIAN_A)/0;

!!UN:N3/(succubus:z)/(MON_SUCCUBUS_A)/0;

!!UN:N3/(soul:z)/(MON_SOUL_EATER_A)/0;

!!UN:N3/(brute:z)/(MON_BRUTE_A)/0;

!!UN:N3/(ogre:z)/(MON_OGRE_LEADER_A)/0;

!!UN:N3/(shaman:z)/(MON_SHAMAN_A)/0;

!!UN:N3/(astral:z)/(MON_ASTRAL_SPIRIT_A)/0;

=>

!#VA(commanderNames[9]:z); Массив из 9-и строк для имён командиров
!!re i/(TOWN_FIRST)/(TOWN_LAST_WOG):; Прошлись по всем городам
!!VR(commanderNamePtr:y):S(@commanderNames) +i; Номер y-переменной с очередным именем командира
!!VR(monType:y):S(MON_PALADIN_A) +i; Вычисляем тип очередного командира
!!SN:H^monname^/(monType)/0/?y(commanderNamePtr); Получаем имя очередного командира
!!en:;

Night · 09.10.2020 17:47

Хм, что-то у меня каждый второй скрипт на ЕРМ2 с ошибками выдаёт.

Spoiler (Click to View)

Сделал copy/paste в sublime, сохранил, запустил игру. EraErmFlamework даже поставил, но что с ним, что без, везде ошибки. Пока без них только ERM 2: Новые поля битв запустил.

Что я делаю не так?

Berserker · 09.10.2020 18:00

igrik определил у себя часть (аргх) безпрефиксных констант, которые в примере кода не указаны. Определи их сам.
Открой IF:Q, посмотри, какой ИД у артефакта, например 6, и напиши:
1000 night - consts.erm

ZVSE2
!#DC(MSG_TYPE_ART) = 6; определили новую константу в файле с приоритетом 1000, который загрузится раньше скриптов с кодом

Night · 09.10.2020 18:13

Berserker, а как этот пример использовать?

!?FU(night_GetSecondarySkillsLimit);
!#VA(result:x);
!!UN:C4881872/(UNC_UINT8)/?(result);

Я сделал такой скрипт для проверки:

ZVSE2
!?CM0;
!!OW:A-1/?y1;
!!CM:F?y11 I?y12; [тип клика, место клика]
!!FU|y11<>512/y12<>1:E;
!!FU(night_GetSecondarySkillsLimit):P;
!?FU(night_GetSecondarySkillsLimit);
!#VA(result:x);
!!UN:C4881872/(UNC_UINT8)/?(result);
!!IF:L^%Y1^;

Но он мне также выдаёт ошибку

Spoiler (Click to View)

Или нужно вместо (UNC_UINT8) задавать значение смещения в байтах? 1,2 или 4?

!?FU(night_GetSecondarySkillsLimit);
!#VA(result:x);
!!UN:C4881872/1/?(result);

Такого вида работает, а вот (UNC_UINT8) - нет. Хм.

Berserker · 09.10.2020 23:32

Night, вот самый свежий исполняемый файл Эры:
https://dropmefiles.com/H5AQP

Там всё исправлено. UINT8 - Unsigned integer 8. Читаем беззнаковое целое число из 8-и бит, то есть байт. Это -1.

Threaded Mode \| Linear Mode Школа ERM 2 » ERM 2.0 для ERA III
Author	Message