ZVSE

** Раз в неделюгерой может использовать Подзорную трубу и
** увидеть участок карты радиусом в 3-7 клетки на границе обзора

!?FU7700;
!!SN:W^Spyglass^/-1; [сброс флага]

!?CM2;
!!CM:I?y1 F?y2 S?y3;
!!FU&y2<>0:E; Only left click
!!FU&y3<>12:E; Only on left push
!!if|y1=11/y1=12/y1=13/y1=14/y1=20:; for all 5 misc slots
!!VRy1:-2; This is the trick
!!HE-1:A1/?y2/y1;
!!FU|y2<>53:E;
!!VRy60:S$day$ -1;
!!VRy60::7 +1;
!!OW:A-1/?y30;
!!SN:W^SpyglassDay_H%Y30^/?y61;
!!FU&y60=y61:E;
!!IF:Q1^Использовать подзорную трубу^;
!!FU&-1:E;
!!SN:W^SpyglassDay_H%Y30^/y60;
!!SN:W^Spyglass^/y30;
!!CM:R0;
!!en:;

!?CM0;
!!SN:W^Spyglass^/?y1; [y1 - номер героя актив. трубу]
!!FU&y1<0:E; [выход если труба не активирована]
!!OW:A-1/?y2; [y2 - активный герой]
!!FU&y1<>y2:E; [выход если активный герой не тот что активировал трубу]
**
!!CM:I?y1; [y1 - позиция курсора]
!!FU&y1<>37:E; [выход если не карта приключений]
!!CM:P?y1/?y2/?y3; [y1/y2/y3 - координаты курсора]
!!HE-1:P?y11/?y12/?y13; [y11/y12/y13 - координаты героя]
!!FU&y3<>y13:E; [выход если разные уровни]
**
!!HE-1:S3/?y30; [y30 - уровень разведки]
!!UN&y30=0:C6547928/4/?y40; [y40 - радиус обзора Без навыка]
!!UN&y30=1:C6547932/4/?y40; [y40 - радиус обзора Базовый]
!!UN&y30=2:C6547936/4/?y40; [y40 - радиус обзора Продвинутый]
!!UN&y30=3:C6547940/4/?y40; [y40 - радиус обзора Эксперт]
**
!!HE-1:A2/53/d/?y53; [y53 - число надетых подзорных труб]
!!VRy40&y53>0:+1;
!!HE-1:A2/52/d/?y52; [y52 - число надетых подзорных телескопов]
!!VRy40&y52>0:+1;
**
!!VRy31:Sy40; [y31\y32 - расстояние на котором можно проводить разведку]
!!VRy32:S0 -y40; [= радиус обзора]
!!VRy21:Sy1 -y11;
!!FU|y21<y32/y21>y31:E;
!!VRy22:Sy2 -y12;
!!FU|y22<y32/y22>y31:E;
**
!!IF:Q1^Посмотреть через трубу на этот участок?^;
!!FU&-1:E;
!!OW:C?y4;
!!UN:Sy1/y2/y3/y4/y40; [show area X Y L player radius]
!!CM:R0;
!!SN:W^Spyglass^/-1;

**end