Threaded Mode | Linear Mode

Berserker · 08.09.2019 01:36

Эра 2.9.0. Пример реализация мода на альтернативные существа. В Цитадели можно нанимать вместо орков троллей в соотношении 3.333 орка к троллю.
Все значения обновляются в реальном времени. 8 орков можно нанять как 2 тролля + 1 орк или 1 тролль и 4 орка, например.
Image: atm.png

; Alternative Trolls Mod
; Mod allows to hire trolls instead of orcs using 3:10 rate (1 troll = 3.333 orcs)
!?FU(atm.UpdateSlots);
!!SN:F^recruit_dlg^/0/?y99/?y1/?y99/0; y1 - original number of orcs
!!SN:F^recruit_dlg.mem^/^rate_x^/?y2; y2 - number of trolls for
!!SN:F^recruit_dlg.mem^/^rate_y^/?y3; y3 - appropriate number of orcs
!!SN:F^recruit_dlg.mem^/^percentage_left^/?e1; e1 - amount of monsters available in percents
!!VRe9:S1:1000; e9 - epsilon (possible rounding error)
!!VRe2:Sy1 *y2 :y3 *e1 +e9; e2 - number of trolls left
!!VRy4:Se2; y4 - number of trolls left
!!SN:F^recruit_dlg^/2/?y99/y4; update trolls quantity
!!VRe3:Sy1 *e1 +e9; e3 - number of orcs left
!!VRy5:Se3; y5 - number of orcs left
!!SN:F^recruit_dlg^/0/?y99/y5; update orcs quantity
!?FU(OnOpenRecruitDlg);
!!SN:F^recruit_dlg.info^/?y1/?y2/?y3;
; y1 - dialog ID
; y2 - town ID
; y3 - dwelling ID
!!FU|y2=-1/y3=-1:E; exit if not town dwelling
!!FU&y3<>2/y3<>9:E; exit if not 3-d level dwelling (upgraded or not)
!!CA0/y2:T?y4; y4 - town type
!!FU&y4<>6:E; exit if not stronghold
!!SN:X?y99/0; don't close dialog on buy
!!SN:F^recruit_dlg.mem^/^is_unequal_alt^/1; mark dialog as ours
!!VRe1:S1; e1 - number alternative creatures available (1 = 100%)
!!SN:F^recruit_dlg.mem^/^percentage_left^/e1; save number of available monsters in percents
; remember orcs/trolls rate
!!SN:F^recruit_dlg.mem^/^rate_x^/3; 3 trolls
!!SN:F^recruit_dlg.mem^/^rate_y^/10; vs 10 orcs
!!SN:F^recruit_dlg^/2/144/0/10000; setup trolls slot
!!FU(atm.UpdateSlots):P;
!?FU(OnRecruitDlgAction);
!!SN:F^recruit_dlg.mem^/^is_unequal_alt^/?y1; y1 - 1 if it's atm dialog
!!FU&y1<>1:E;
!!SN:X?y2; y2 - number of recruited monsters
!!SN:F^recruit_dlg.info^/?y99/?y99/?y99/?y3; y3 - active slot
!!SN:F^recruit_dlg.mem^/^rate_x^/?y4; y4/y5 = trolls/orcs rate
!!SN:F^recruit_dlg.mem^/^rate_y^/?y5;
!!SN:F^recruit_dlg^/0/?y99/?y6/?y99/0; y6 - original number of orcs
!!SN:F^recruit_dlg.mem^/^percentage_left^/?e1; e1 - amount of monsters available in percents
!!if&y3=2:;
!!VRe2:Sy2 *y5 :y4 :y6; e2 - recruited percentage
!!el:;
!!VRe2:Sy2 :y6; e2 - recruited percentage
!!en:;
!!VRe1:-e2;
!!SN:F^recruit_dlg.mem^/^percentage_left^/e1; update percentage left
!!FU(atm.UpdateSlots):P;

Reinc · 08.09.2019 20:07

А разница в уровнях существ не слишком большая, чтобы позволять нанимать троллей из здания для орков?

Berserker · 08.09.2019 21:04

Reinc, так ведь найм идёт по принципу либо малое число одних, либо большое других.

wessonsm · 09.09.2019 20:28

Berserker,
!?FU(OnRecruitDlgAction) и !?FU(OnOpenRecruitDlg) - новые события?
И !!SN:F - новая команда?

Berserker · 09.09.2019 21:30

wessonsm, да, уже убрал !!SN:F, теперь новаый ресивер !!RD (Recruiting Dialog).

; Alternative Trolls Mod
!?FU(atm.UpdateSlots);
!!RD:C0/?y99/?y1/?y99/0; y1 - original number of orcs
!!RD:M^rate_x^/?y2; y2 - number of trolls for
!!RD:M^rate_y^/?y3; y3 - appropriate number of orcs
!!RD:M^percentage_left^/?e1; e1 - amount of monsters available in percents
!!VRe9:S1:100; e9 - epsilon (possible rounding error)
!!VRe2:Sy1 *y2 :y3 *e1 +e9; e2 - number of trolls left
!!VRy4:Se2; y4 - number of trolls left
!!RD:C2/?y99/y4; update trolls quantity
!!VRe3:Sy1 *e1 +e9; e3 - number of orcs left
!!VRy5:Se3; y5 - number of orcs left
!!RD:C0/?y99/y5; update orcs quantity
!?FU(OnOpenRecruitDlg);
!!RD:I?y1/?y2/?y3;
; y1 - dialog ID
; y2 - town ID
; y3 - dwelling ID
!!FU|y2=-1/y3=-1:E; exit if not town dwelling
!!FU&y3<>2/y3<>9:E; exit if not 3-d level dwelling (upgraded or not)
!!CA0/y2:T?y4; y4 - town type
!!FU&y4<>6:E; exit if not stronghold
!!SN:X?y99/0; don't close dialog on buy
!!RD:M^is_unequal_alt^/1; mark dialog as ours
!!VRe1:S1; e1 - number alternative creatures available (1 = 100%)
!!RD:M^percentage_left^/e1; save number of available monsters in percents
; remember orcs/trolls rate
!!RD:M^rate_x^/3; 3 trolls
!!RD:M^rate_y^/10; vs 10 orcs
!!RD:C2/144/0/10000; setup trolls slot
!!FU(atm.UpdateSlots):P;
!?FU(OnRecruitDlgAction);
!!RD:M^is_unequal_alt^/?y1; y1 - 1 if it's atm dialog
!!FU&y1<>1:E;
!!SN:X?y2; y2 - number of recruited monsters
!!RD:I?y99/?y99/?y99/?y3; y3 - active slot
!!RD:M^rate_x^/?y4; y4/y5 = trolls/orcs rate
!!RD:M^rate_y^/?y5;
!!RD:C0/?y99/?y6/?y99/0; y6 - original number of orcs
!!RD:M^percentage_left^/?e1; e1 - amount of monsters available in percents
!!if&y3=2:;
!!VRe2:Sy2 *y5 :y4 :y6; e2 - recruited percentage
!!el:;
!!VRe2:Sy2 :y6; e2 - recruited percentage
!!en:;
!!VRe1:-e2;
!!RD:M^percentage_left^/e1; update percentage left
!!FU(atm.UpdateSlots):P;

ElfbI · 09.09.2019 23:19

Berserker, при использовании положительной у-переменной функции внутри триггера она не портит ли соответствующую положительную у-переменную триггера? Я когда у вас спрашивал про переход с отриц. на положит., стал менять несколько своих скриптов - полезли баги, связанные с этим, так что я быстренько вернул все как было...

Berserker · 10.09.2019 00:43

ElfbI, в вопрос явно закралась ошибка. Отвечу просто: y1..y100 всегда локальны (относятся к местной копии) тому триггеру, в котором используются.

Эра 2.9 в активной разработке. Интерполяция произвольных строк по запросу (дано "%Z3 has %Y5 shooters", получаем "Orrin has 700 shooters"), масштабное АПИ для управления диалогом найма существ, оптимизация скорости исполнения ЕРМ и др.

Grossmaster · 10.09.2019 16:32

А в будущих патчах Эры будет редактор карт Unleashed с поддержкой модов?

Berserker · 10.09.2019 19:32

Grossmaster, а что за редактор? Пока никаких изменений в этой области не планируется.

daemon_n · 10.09.2019 20:05

Berserker, я так понимаю, он имел ввиду Этот (ссылка на Heroes Community)

Berserker · 10.09.2019 22:09

daemon_n, спасибо!

Berserker · 11.09.2019 00:05

!!RD:O0/8/1/0/0;

Открыть диалог существ. Источник — улучшенное строение 2-го уровня города №0. Назначение — армия героя №0 (Оррин). Не закрывать диалог по нажатию кнопки покупки.
Результат — нанимаем существ из своего города в армию чужого героя

daemon_n · 11.09.2019 00:14

Berserker, ура - вот как можно бесконечно растить опыт за деньги!

Berserker · 11.09.2019 00:49

daemon_n, можно )

Berserker · 14.09.2019 01:23

Надоело загружать библиотеки, получать адреса функций, вызывать функции с нужным соглашением о вызове?
Скажем, нужно сделать резервную копию файла настроек игры. Пишем:

!!SN:L^kernel32.dll^/?y1 Ay1/^CopyFileA^/?y2 Ey2/1/^heroes3.ini^/^heroes3.ini.bak^/0;

Но так долго писать и не очень быстро выполнять. А если так?

!!SN:F^CopyFileA^/^heroes3.ini^/^heroes3.ini.bak^/0;

Совсем другое дело! Эра сама поймёт, откуда функция, из era.dll или kernel32.dll, закэширует её адрес по имени и будет всегда использовать stdcall-соглашение о вызове.

Что делать, если не загружен плагин era_hooker, а он нужен? Предупредить!

!!SN:F^PluginExists^/^era_hooker^;
!!IF&v1=0:M^Отсутствует важный плагин. FUN.erm не будет работать^;

Threaded Mode \| Linear Mode ERA II » WoG Era 2: Русская и Английская версии
Author	Message