Threaded Mode | Linear Mode

ElfbI · 20.08.2019 00:01

Berserker, нет еще, я пока на эре v2.7.7

Времени нет пока, да и тот скрипт я отладить не успел еще. Работа(

ElfbI · 20.08.2019 01:02

Berserker, вот кстати скрипт для генерации сокровищ на воде, который в итоге вышел (осторожно, здесь были индусы 96-copy

)

Spoiler (Click to View)

ZVSE
!#SN:W^counter_seagenerator^/-1;
!#UN:X?y1/?y2; !#SN:W^map_size_XY_libr^/y1; map size
!#VRy2:Sy2 +1; !#SN:W^map_level_1_2_libr^/y2; map level instead of 0/1 get 1/2
!#VRy3:Sy1 *y1 *y2; !#VRy3:-1; !#SN:W^map_squares_qty_libr^/y3; map number of squares
!?TM2;
***подготовка массива для клеток воды***
!!SN:W^counter_seagenerator^/?y1; !!VRy2:S$day$; !!VRy3:S$weekday$;
!!FU28465&y1=-1/y2=1:P;
!!SN:W^counter_seagenerator^/1;
***здесь мы работаем с полученным массивом
!!if|y3=2/y3=4/y3=6:; 3 раза в неделю, одно сокровище за каждого игрока.
***
!!SN:W^seagenerator_cell_number^/?y92; получаем количесво ячеек массива с клетками воды, не занятыми препятствиями
!!SN:W^map_squares_water_28463^/?y93; получаем кол-во клеток с водой карте
!!if&y92>=1/y93>=1:;
!!FU28467:P; находим подходящую клетку с координатами 28463_x 28463_y 28463_z
!!SN:W^seagenerator_generation_success^/?y94; проверяем, был ли поиск успешен (на клетке может появиться объект или герой) успешен = 1
!!if&y94=1:;
!!SN:W^28463_x^/?y21;
!!SN:W^28463_y^/?y22;
!!SN:W^28463_z^/?y23;
!!VRy20:S0 R2; random numb 0-2
!!if&y20=0:;
!!UN:Iy21/y22/y23/29/0/29/0/8/1; place object
!!VRy24:S0 R3;
!!OBy21/y22/y23:Cy24; set control number
!!en:;
!!if&y20=1:;
!!UN:Iy21/y22/y23/82/0/82/0/8/1;
!!VRy24:S0 R2;
!!if&y24=2:;
!!FU28470:P; get art numb
!!SN:W^Sea_gen_art_28466^/?y24;
!!VRy24:*8 -8190; calculate control number for ob:C
!!OBy21/y22/y23:Cy24;
!!el:;
!!OBy21/y22/y23:Cy24;
!!en:;
!!en:;
!!if&y20=2:;
!!UN:Iy21/y22/y23/86/0/86/0/8/1;
!!FU28470:P;
!!SN:W^Sea_gen_art_28466^/?y24;
!!OBy21/y22/y23:Cy24;
!!en:;
!!en:;
!!en:;
***
!!en:;
********************************************************************************в первый день 1 раз
!?FU28465; Функция генерации массива с клетками воды.
!!SN:W^map_size_XY_libr^/?y1; получаем размер карты
!!SN:W^map_level_1_2_libr^/?y2; получаем кол-во уровней
!!SN:W^map_squares_qty_libr^/?y3; получаем кол-во клеток
***
!!VRy45:Sv3;!!VRv3:S0; Сохраняем значение глобальной переменной. Обнуляем переменную счёта клеток.
!!DO28466/0/y3/1:Py1/y2/0; Запускаем цикл, проходящийся по всем клеткам карты и считающий число клеток c водой на ней.
!!FU&v3<=0:E; Если клеток нет, завершаем функцию.
***
!!SN:W^map_squares_water_28463^/v3; записываем кол-во клеток с водой v3
!!VRy46:Sv1; !!VRv1:S0; !!SN:M-1/v3/0/1; Cоздаем слот памяти с размером массива v3 (число свободных клеток на ней.) и получаем индекс в v1
!!SN:W^seagenerator_slot_index^/v1; записываем индекс слота памяти
***
!!VRv3:S0; Обнуляем переменную счёта клеток.
!!DO28466/0/y3/1:Py1/y2/1; Запускаем цикл, проходящийся по всем клеткам карты и настраиваем массив. Теперь v3=количество ячеек массива.
!!SN:W^seagenerator_cell_number^/v3;записываем количество ячеек в слоте памяти
!!VRv1:Sy46; !!VRv3:Sy45; Восстанавливаем значение глобальной переменной.
!?FU28466; Функция подсчета клеток воды, настройки массива и упаковки координат
;x3 - режим
;х3=0 подсчет
;х3=1 подсчет и запись
!!VRy1:Sx16%x1; Вычисляем x-координату клетки.
!!VRy2:Sx16:x1%x1; Вычисляем y-координату клетки.
!!VRy3:Sx16:x1:x1%x2; Вычисляем l-координату клетки.
!!TRy1/y2/y3:T?y6/d/d/d/d/d/d/d;Считываем тип территории клетки.
!!if&y6=8:; Если вода
!!TRy1/y2/y3:E?y4; Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5; Считываем посещаемость клетки.
!!if&y4=1/y5=1:; Если в режиме подсчета и клетка проходима считаем в v3 кол-во нужных клеток
!!if&x3=0:;
!!VRv3:+1; Если свободная клетка с водой добавляем в v3
!!el:; Если в режиме подсчетa и упаковки координат
!!SN:W^seagenerator_slot_index^/?y99; получаем индекс слота
!!VRy7:Sy1; [x] подготавливаем координаты для упаковки
!!VRy8:Sy2*256; [y] подготавливаем координаты для упаковки
!!VRy9:Sy3*65536;[z] подготавливаем координаты для упаковки
!!VRy11:Sy9 +y8 +y7; [a+b+c] пакуем координаты клетки в y11
!!SN:My99/v3/y11; записываем в слот с индексом y99 в ячейку номер v3 упакованные координаты y11
!!VRv3:+1; нумерция ячейки идет с 0, поэтому увеличиваем значение после записи координат
!!en:;
!!en:;
!!en:;
********************************************************************************в любой нужный момент по таймеру
!?FU28467; Функция генерации случайной свободной клетки из диапазона массива.
!!VRy45:Sv3; !!VRv3:S0; Сохраняем значение глобальной переменной. Обнуляем переменную счёта клеток.
!!SN:W^seagenerator_cell_number^/?v3; получаем количество ячеек в слоте памяти
!!VRy3:Sv3 -1; вносим поправку, чтобы получить значение генератора в нужной области
!!VRy4:S1 Ry3; вычисляем условный случайный номер ячейки в массиве (УНЯ). (нумерация ячеек выглядит так [0]...[v3-1], поэтому при посчете реального номера нужно выычесть 1)
; работаем с ячейками массива в диапазоне от [УНЯ]=[y4] до [последней ячейки массива]=[v3]
!!DO28468/y4/v3/1:Py4/v3; Запускаем цикл, проходящийся по ячейкам массива и вычисляющий реальный номер случайной ячейки.
!!VRv3:Sy45; Восстанавливаем значение глобальной переменной.
!?FU28468; Функция генерации реального номера случайной ячейки массива
;x1=УНЯ
!!VRx16&x16=1:Sx1; на первом цикле устанавливаем номер цикла = УНЯ
!!FU28469:Px16; здесь мы распаковываем координаты УНЯ в SNW переменные
!!SN:W^28463_x^/?y1; получаем x-координату клетки.
!!SN:W^28463_y^/?y2; получаем y-координату клетки.
!!SN:W^28463_z^/?y3; получаем z-координату клетки.
!!TRy1/y2/y3:E?y4; Считываем проходимость клетки.
!!TRy1/y2/y3:P?y5; Считываем посещаемость клетки.
!!if&y4=1/y5=1:; если проходима
!!OBy1/y2/y3:T?y7; проверяем нет ли героя
!!if&y7<>34:; если нет героя - реальный номер клетки вычислен, можно использовать координаты 28463_x 28463_y 28463_z
*!IF:M^ПЫЩ^;
!!SN:W^seagenerator_generation_success^/1;
!!VRx16:Sx2;
!!FU:E; завершаем цикл
!!en:;
!!el:;
!!SN&x16=x2:W^seagenerator_generation_success^/-1; если подходящей ячейки в диапазоне нет
!!en:;*
* x y z y99
* Пример 1+ 2*256+ 1*65536 = 66049
!?FU28469; |a|+| b |+ | c | Функция распаковки координат
;x1=x16(28468)=
!!VRy93:Sx1 -1; получаем реальный номер ячейки из УНЯ
!!SN:W^seagenerator_slot_index^/?y11;
!!SN:My11/y93/?y99; получили упакованные координаты водной клетки из ячейки х1-1
!!VRy23:Sy99 :65536; !!VRy33:Sy23 *65536; получаем округленный результат деления, а затем произведение координаты c=z*65536 Пример y23=66049/65536=1.007->округл->1 z=1 y33=1*65536=65536
!!VRy99:-y33; вычитаем произведение координаты, чтобы узнать оставшиеся две Пример y99=66049-65536=513
!!VRy22:Sy99 :256; !!VRy32:Sy22 *256; получаем округленный результат деления, а затем произведение координаты b=y*256 Пример y22=513/256=2.004->округл->2 y=2 y32=2*256=512
!!VRy21:Sy99 -y32; вычитаем произведение координаты, чтобы узнать оставшуюся a=x Пример y21=513-512=1 x=1
!!SN:W^28463_x^/y21; Записываем x-координату клетки.
!!SN:W^28463_y^/y22; Записываем y-координату клетки.
!!SN:W^28463_z^/y23; Записываем z-координату клетки.
****
!?FU28470;
!!VRy24:S7 R114; random number for art generation
!!VRy24&y24>=72:+1; skip some of them and generate artifact (exclusining -124 -86 -87 -88 -89 -90 -72)
!!VRy24&y24>=86:+5;
!!VRy24&y24>=124:+1;
!!VRy24&y24>=128:S159 R1; may generate 159/160
!!UN:Ay24/?y25; check if banned
!!if&y25=1:;
!!UN:J6/14/?y24; if banned generate one of not banned treasure/minor/major
!!en:;
!!SN:W^Sea_gen_art_28466^/y24;

Осталось настроить, сколько сокровищ будет появляться и артефакты в сундуке / у мужика на бревне, может, убавить.
Возможно, пригодится кому мой г****код, я пока баги ловил, достаточно подробно комментарии писал. Вроде работает, как часы. Проверял: если нет воды, если клетки воды заняты, если на все клетки сокровища поставлены, если вода в подземелье, если на воде герой. Надо бы с ним поиграть, но когда смогу еще...

Berserker · 20.08.2019 02:38

ElfbI, хорошо задокументировано и оформлено. Писать на ЕРМ просто и лаконично в любом случае невозможно, не хватает высокоуровневых конструкций.

igrik · 21.08.2019 21:06

Чтобы не потерять:
Код на определение расстояния между двумя гексами на ERM (© Berserker)

!?FU(GetShootDistance);
; x1 - id начального гекса
; x2 - id целевого гекса
; x3 - результат функции: возвращает расстояние, или -1 при неверных или недопустимых параметрах
!!VRx3|x2<0/x2>186:S-1; !!FU|x2<0/x2>186:E;
!!VRy2:Sx2 %17;
!!VRx3|y2=0/y2=16:S-1; !!FU|y2=0/y2=16:E;
!!VRy1:Sx1 %17 *2; !!VRy3:Sx1 :17;
!!VRy2:Sx2 %17 *2; !!VRy4:Sx2 :17;
!!VRy7:Sy3 %2; !!VRy1&y7=1:-1;
!!VRy8:Sy4 %2; !!VRy2&y8=1:-1;
!!VRy6:Sy4 -y3; !!VRy6&y6<0:*-1;
!!VRy5:Sy2 -y1; !!VRy5&y5<0:*-1;
!!VRy5:-y6; !!VRy5&y5<0:S0;
!!VRx3:Sy6 *2 +y5 :2;
; *** end

UPD: а вот геройская функция 0x469250 int __fastcall BattleMgr_GetStepsTaken(gex_start, gex_finish) ((return distance))

!!SN:E4624976/3/<gex_start>/<gex_finish>;

Berserker · 21.08.2019 23:09

igrik, не вижу особенного смысла запрещать позиции за гранью поля боя %17 = 0 или 16. Они вполне корректные для больших существ и никак не влияют на математику.

igrik · 22.08.2019 09:50

Berserker, эти поля же недопустимы для существ. Двухгексовые монстры также на них не становятся. Я не вижу смысла в них для данной функции.

Berserker · 22.08.2019 13:48

igrik, а баллиста на них не залазит? Может ли до них достать площадное заклинание?

igrik · 22.08.2019 16:33

Площадное заклинание до этих полей не достаёт.
Баллиста и палатка вторым (задним) гексом на них стоит. Но на этих гексах даже информацию о них посмотреть нельзя. Повода же стоит на нормальном (рабочем) гексе.
К тому же, я не раз в коде встречал, что эти гексы не используются в проверках на рабочий гекс.
Вот например выдрежка из кода функции получения кадра дефа на поле боя при движении мыши.

Image: image.jpg

Igor · 22.08.2019 22:27

Berserker, igrik, спасибо.

slater777 · 22.08.2019 22:34

Возникла идея написать скрипт, при котором все хранилища дракономух заменялись бы камнями опыта. Сам скрипт замены найден и работает. Но проблема в том, что герой, посещая данный новый камень, посещает и все остальные. Т.е. у всех новых камней номер одинаковый. По крайней мере, по другому я это объяснить не могу. Не подскажете, через какую команду можно все м таким объектам присвоить новые номера?

Berserker · 22.08.2019 23:28

!!OB:C?

wessonsm · 22.08.2019 23:41

В ERM-справке написано:
!!ST#1/#2/#3:XXXX; - камень знаний в X Y L.
N$ - Номер камня знаний

XEPOMAHT · 23.08.2019 16:00

(22.08.2019 22:34)slater777 Wrote: Не подскажете, через какую команду можно все м таким объектам присвоить новые номера?

В MapItem.контрольное_слово хранится этот номер.

Т.е. скрипт примерно такой (без проверок на безопасность):

UN:IX/Y/Z/100/0/1; - поставить Камень Знаний в координатах XYZ.
UN:U100/0/?y1; - получить количество камней
OBX/Y/Z:Cy1; - последний номер пускай и будет номером камня (вроде б можно, т.к. и там и там двойное слово, можно ещё применить и dec y1, чтобы не было пропуска в порядке номеров камней)

slater777 · 23.08.2019 22:22

XEPOMAHT, спасибо, дописал в скрипте вогификации к функции непосредственной замены объекта вот такие строки:

** Setup for Experience Stones **
!!UN:U100/0/?y20; [y20 - количество камней опыта на карте]
!!UN:U100/1/?y21; [y21 - количество заснежных камней опыта на карте]
!!VRy22:S0 +y20 +y21 +1;
!!OBy3/y4/v954&vv955=100/vv956=0:Cy22; [установление номера генерируемого камня]

Сработало, только образовался разрыв в номерах. Создал карту с 3 заснежными камнями, 3 обычными, и 2 камня сгенерировалось.
В итоге:
0,1,2 - номера обычных камней
3,4,5 - номера заснежных камней
И 8,9 - номера сгенерируемых.
Если подскажете способ отобрать из выборки максимальное число, буду благодарен!

Berserker · 23.08.2019 22:58

Макс = -1
Для каждого из объектов
Если контрольное слово > Макс, то Макс = контрольное слово

По окончании цикла получишь Макс.

Threaded Mode \| Linear Mode Ваши вопросы по ERM-скриптам
Author	Message