ZVSE
** При наличии 2 навыков: Первая помощь и Мистицизм палатка может воскрешать
** до 3 существ в зависимости от развития навыка Мистицизм.

!?BG0; перед действием
!!BG:N?y1 E?y2 A?y3; [y1- номер активного отряда(0…41), y2- номер отряда цели (0…41), y3- действие (11- лечение палатки)]
!!BMy1:T?y4 I?y5; [y4- тип отряда (147 - палатка), y5- принадлежность герою 0-левый\1-правый]
!!BA:Hy5/?y6; [(0-левый\1-правый) y6 - номер героя]
!!FU&y4<>147:E; [выход, если не лечение палатки или нет героя]
!!FU&y3<>11:E; [выход, если не лечение палатки или нет героя]
!!FU&y6<1:E; [выход, если не лечение палатки или нет героя]
!!FU&y2=-1:E; [выход, если не лечение палатки или нет героя]
** параметры героя
!!HEy6:S27/?y27 S8/?y8; [y27 - уровень навыка Мистицизм, y8 - первая помощь]
!!FU&y27=0/y8=0:E; [выход, если нет первой помощи или мистицизма]
** параметры отряда цели лечения
!!BMy2:H?y11 L?y12; [y11- МЗ максимальное здоровье, y12- ПЗ потерянное здоровье]
!!BMy2:N?y13 B?y14; [y13- ТК текущее количество, y14- НК начальное количество]
** количество очков лечения
!!VRy100:S25 *y8 +25; [задаем количество очков лечения ЛЗ]
** воскрешаем если навык мистицизма 3
!!if&y11<y100/y13<y14/y27>2:; [если МЗ<ЛЗ и ТК<НК и мистицизм > 2]
!!VRy13:+1; [ТК = ТК + 1 ]
!!VRy100:-y11; [ЛЗ = ЛЗ - МЗ ]
!!en:;
** воскрешаем если навык мистицизма 2 или 3
!!if&y11<y100/y13<y14/y27>1:; [если МЗ<ЛЗ и ТК<НК и мистицизм > 1]
!!VRy13:+1; [ТК = ТК + 1 ]
!!VRy100:-y11; [ЛЗ = ЛЗ - МЗ ]
!!en:;
** воскрешаем если навык мистицизма 1 или 2 или 3
!!VRy15:+y100 -y12; [y15- СЛ сверхлечение - Если остаток лечения больш урона - оживить еще одного]
!!if&y15>0/y13<y14/y27>0:; [если СЛ>0 и ТК<НК и мистицизм есть]
!!VRy13:+1; [ТК = ТК + 1 ]
!!VRy100:-y12; [ЛЗ = ЛЗ - урон ]
!!en:;
!!BMy2:Ny13; [устанавливаем количество существ после воскрешения]
** лечим тем что осталось после оживления
!!if&y15>0/y13=y14:; [если СЛ>0 и ТК=НК]
!!BMy2:L0; [восполнение здоровья до максимума]
!!en:;
!!if&y15<0:; [если СЛ нет]
!!VRy12:-y100;
!!BMy2:Ly12; [восполнение здоровья]
!!en:;
!!BG:A12; [отмена стандартного лечения]
** end

ZVSE

**Герой получает или дает опыт 50 * разницу в уровнях * уровень навыка обучение

!?FU77010; Перед взаимодействием героев
!!SN:X?y1/?y2; Узнать номера героев

!!HEy1:O?y5; Игрок хозяин 1 героя
!!HEy2:O?y6; Игрок хозяин 2 героя
!!FU&y5<>y6:E; Выход если герои от разных игроков

!!VRy60:S$day$;
!!SN:W^H3_Scholar_H1%Y1_H2%Y2_%Y60^/?y10;
!!FU&y10=1:E; Exit if they have already met today
!!SN:W^H3_Scholar_H1%Y2_H2%Y1_%Y60^/?y10;
!!FU&y10=1:E; Exit if they have already met today

!!HEy1:S21/?y5; Проверка наличия навыка обучение
!!HEy2:S21/?y6; Проверка наличия навыка обучение
!!FU&y5=0/y6=0:E; Выход если у героев нет обучения

!!VRy5&y6>y5:Sy6; Узнаем наивысший уровень навыка обучение

!!HEy1:Ed/?y11; Проверка уровня героя 1
!!HEy2:Ed/?y12; Проверка уровня героя 2
!!FU&y11=y12:E; Выход если уровни равны

!!VRy3&y11>y12:Sy1;
!!VRy4&y11>y12:Sy2;
!!VRy3&y11<y12:Sy2;
!!VRy4&y11<y12:Sy1;

!!HEy3:Ed/?y11; Проверка уровня героя с большим уровнем
!!HEy4:Ed/?y12; Проверка уровня героя с меньшим уровнем

!!VRy7:Sy11 -y12 *5 *y5; опыт 50 * разницу в уровнях * уровень навыка обучение

!!HEy4:Edy7; добавить герою опыт

!!SN:W^H3_Scholar_H1%Y1_H2%Y2_%Y60^/1; [Set Flag so it can only happen once per day]
!!SN:W^H3_Scholar_H1%Y2_H2%Y1_%Y60^/1;

ZVSE

; Скрипт: Заклинания огня наносят вампирам двойной урон
; Плащ Короля Нежити и мантия Вампира убирают уязвимость к огню

!?BG0; [перед действием в бою]
!!BG:A?y1; !!FU&y1<>1:E; [y1 - тип действия, выход, если не колдовство героя]
!!BG:S?y1; !!FU&y1<>21/y1<22/y1<11/y1<13/y1<29:E; [выход, если не огненное закл.]
!!BG:N?y1; !!BMy1:T?y2; !!FU&y2<>63/y2<>62:E; [номер стека, тип существа, выход если не вампиры]

!!BG:H?y1;
!!HEy1:A2/130/d/?y2; !!FU&y2>0:E; [130 Плащ Короля Нежити выход если надеты]
!!HEy1:A2/55/d/?y2; !!FU&y2>0:E; [55 Мантия Вампира выход если надеты]

!!SN:W^vampfire^/1; [выставление флага урон огнем по вампирам]

!?BG1; [при передаче хода]
!!SN:W^vampfire^/0; [сброс флага урон огнем по вампирам]

!?MR1;
!!SN:W^vampfire^/?y1; [выход, если не урон огнем по вампирам]
!!MR&y1>0:F?y4 Fdy4; [удвоение базового урона]

** end