Threaded Mode | Linear Mode

Valery · 03.05.2015 22:15

What I found so far, please add anything that could simplify scripters life and is not in erm help actually.

;If OB:T = 34 (hero). #get object under hero / erm snippet

!!UN:C6919480/4/?y20;
!!VRy20:+136736;
!!VRy21:S[hero number]*1170+y20;
!!VRy22:Sy21+12; y22 points to object type
; +16; y[NN] would point to object subtype
!!VRy23:Sy21+20; y23 points to object control word (real OB:C)
!!UN:Cy23/4/?y24; get object type under hero...

;Fix day of, all erm help is wrong about:

Day (1..n): !!VRv1:Sc;
Day (0..n): !!VRv1:Sc -1;
Day of the month (0..27): !!VRv1:Sc -1 %28;
Week of the month (0..3): !!VRv1:Sc -1 %28 :7;
Week of the month (1..4): !!VRv1:Sc -1 %28 :7 +1;

; redraw town screen

!!UN:C6919500/4/?y1; // TownManager
!!SN:E6117392/2/y1; // RedrawTownScreen

;change battlefield during battle

; one way: call WoG function
!!BA:B^file.pcx^;
!!SN:E7740298/1; call 0x761B8A (result is v1)
!!UN:C6919200/4/?y1; get [0x699420]
!!VRy1:+78948; +0x13464
!!UN:Cy1/4/v1; // set result
; another way: allocate Era string
; make new temporary array of 1 string, set its 0th element to our string and get its address to y2
!!SN:M-1/1/1/0 Mv1/0/^file.pcx^ Mv1/?y2/0;
!!UN:C6919200/4/?y1; get [0x699420]
!!VRy1:+78948; +0x13464
!!UN:Cy1/4/y2; // set string address

;Mop function, find hero portrait for DL

!!FU48750:P[hero_mumber]/1/2;
!!IF:M^Маленький потртет %Z1
Большой портрет %Z2^;
!?FU48750;
x1 - hero number
x2 - small portrait to z[number]
x3 - large portrait to z[number]
!!VRx1:*92+8144112;
!!UN:Cx1/4/?y1;
!!VRx1:+4;
!!UN:Cx1/4/?y2;
!!VRx2:*512+9597416;
!!VRx3:*512+9597416;
!!DO48751/1/512/1:Py1/x2 Py2/x3;
!?FU48751;
!!UN:Cx1/1/?y1 Cx2/1/y1;
!!VRx16&y1=0:S600;
!!VRx1:+1;
!!VRx2:+1;

;safe functions equip/delete artifact

!?FU338354; equip art
; x1 - hero or - 1 for current
; x2 - art type
; x3 - art subtype or -1 (usually for non-scrolls)
; x4 - slot or -1
!!UN:C6919480/4/?y1; [y1 - BASE]
!!VRy2:Sx1*1170+y1+136736; [y2 - pointer to hero structure]
!!VRy5:S3*4+10784128-4; [y5 - pointer to y3]
!!VRy3:Sx2; [artifact type = 5]
!!VRy4:Sx3; [set y4 to subtype]
!!SN:E5123184/2/y2/y5/x4;
!?FU338357; unequip art
; x1 - hero or - 1 for current
; x2 - slot
!!HE-1&x1=-1:N?x1;
!!UN:C6919480/4/?y1; [y1 - BASE]
!!VRy2:Sx1*1170+y1+136736; [y2 - pointer to hero structure]
!!SN:E5123648/2/y2/x2;
!?FU338355; check if artifact can be put in slot possible replacing existing art
; x1 - hero or - 1 for current
; x2 - art
; x3 - slot
; return v1 = 1 (yes) or 0 (no)
!!UN:C6919480/4/?y1; [y1 - BASE]
!!VRy2:Sx1*1170+y1+136736; [y2 - pointer to hero structure]
!!SN:E5122736/2/y2/x2/x3;
!!VRv1:&1;
*******************************************************************************************
!?FU338354; extract hero arts
; x1 - hero
; v1 - SN:M array of art/id pairs
!!VRy1:S0; [y1 - slot]
!!VRy10:S0; [y10 - array index]
!!SN:M-1/28/0/0; [allocate array 14 * 2 of temp integer]
!!VRy2:Sv1; [y2 - reslut]
!!HEx1:A1/?y3/y1; [#4 y3 - art type]
!!VRy4:S-1; [y4 - art subtype]
!!if&y3>=1001:; [correct type/subtype for scrolls]
!!VRy4:Sy3-1001;
!!VRy3:S1;
!!en:;
!!FU338357&y3<>-1:Px1/y1; [unequip art if any]
!!SN:My2/y10/y3; [save art info]
!!VRy10:+1;
!!SN:My2/y10/y4;
!!VRy10:+1;
!!VRy1:+1;
!!VRy1&y1=13:S18;
!!SN&y1<=18:G4;
!!VRv1:Sy2;
!?FU338353; equip hero arts from SN:M array
; x1 - hero
; x2 - SN:M array
!!VRy1:S0; [y1 - slot]
!!VRy2:S0; [y2 - array index]
!!SN:Mx2/y2/?y3; [#2 y3, y4 - art type/subtype]
!!VRy2:+1;
!!SN:Mx2/y2/?y4;
!!VRy2:+1;
!!FU338354:Px1/y3/y4/y1; [equip art]
!!VRy1:+1;
!!VRy1&y1=13:S18;
!!SN&y1<=18:G2;

;set scouting radius

!!UN:C6547928/4/$; $=scouting radius, set to 0 to have next turn in fog. Backside: it affect all heroes so should be dependent of !?HL and default value is 5

;65000 objects allowed (XXL maps)

!#UN:C4892718/1/183;

;pitlords summon horned demons

!#UN:C5928811/1/49;

;DL addition:

Code:

A#1/#2/$/1    Change dialogue item characteristic.

#1 - item ID

#2    type    $

  3    Text    (string): new text of the item

  4    Def     (number): new cadre in Def

  11    Pcx     (string): new picture

 #4  parameter should always be 1 (anyone care to explain why?)

Notes:

May be called in !?DL trigger and so may be used to customize the dialog on a fly.

Berserker · 03.05.2015 22:28

Quote:#4 parameter should always be 1 (anyone care to explain why?)

#4 Redraw dialog (1 or 0, 0 by default).

gamecreator · 03.05.2015 23:01

(03.05.2015 22:15)Valery Wrote: What I found so far, please add anything that could simplify scripters life and is not in erm help actually.

SN:G may corrupt ERM conditions (if/el/en) if used from inside one.
And updated code for correct curse removal:

!?FU1; правильно удаляет проклятье
; x1 = номер проклятья
; x2 = номер героя
!!VRy1:S0; индекс
!!UN:C7688945/4/?y2; получить поле проклятья (обычно 0x27FE810)
!!UN:C7688968/4/?y3; получить поле героя (обычно 0x27FE814)
!!UN:C7688927/4/?y4; получить максимальное количество проклятий
!!FU&y1>=y4:E; проклятья закончились, ничего не найдено -> выход; начало цикла
!!UN:Cy2/4/?y5; получить номер текущего проклятья
!!UN:Cy3/4/?y6; получить номер текущего героя
!!if&x1=y5/x2=y6:; нашли нужное проклятье
!!SN:E7689874/1/x2/x1/y1; cdecl 0x755692(int hero, int curse, int index)
!!HEx2&v1=0:Yx1/0/0/0; если функция сработала, то удалить информацию
!!FU:E; конец функции
!!en:; этот блок выходит из функции, конструкция el не нужна
!!VRy1:+1; перейти к следующему проклятью
!!VRy2:+20; 0x14 - размер структуры
!!VRy3:+20; 0x14 - размер структуры
!!SN:G4; перейти на начало цикла

Valery · 03.05.2015 23:17

(03.05.2015 22:28)Berserker Wrote: #4 Redraw dialog (1 or 0, 0 by default).

We never tested it with 0, and I saw nowhere that. Isn't it safer to say 1 is default?

gamecreator · 03.05.2015 23:21

Wog sources say it's redraw. For example, you want to change several elements. If you redraw only when changing the last one, it would be much faster and smoother.

Valery · 03.05.2015 23:25

Ah I see, thanks.

;find player starting town type

!?FU15020;
;x1 current player
!!UN:C6919480/4/?y1;
!!VRy1:+128688; address of starting-town-type table
!!VRy2:Sx1*4+y1; table has 4 bytes per color, starts at y1
!!UN:Cy2/4/?y3; y3=starting Town type

; show oracle map

!!UN:C6918840/4/?y1; [pAdvManager]
!!SN:E4302672/2/y1; [ShowOracleMap]

;no ghosts will appear in town after demolishing all dwellings

!?CM1;
!!CA-1:U?y1;
!!VRy1:*30+8630976+20;
!!UN:Cy1/4/0;

;create DL dialog on holding mouse button

!?FU9030;
;x1 DL #
!!VRy1:Sv1;
!!SN:E7510739/1/x1; [find HDlg -> v1]
!!VRy2:Sv1; [v2 = HDlg]
!!if&y2<>0:;
!!SN:E5864096/1; [stop animation]
!!UN:Cy2/4/?v1; [v1 = dialog]
!!SN:E6245264/2/v1; [show while holding mouse button]
!!SN:E5864272/1; [continue animation]
!!SN:E7518240/2/y2; [destroy HDlg]
!!en:;
!!VRv1:Sy1;

Berserker · 03.05.2015 23:26

Valery, if you specify nothing, 0 is assumed. gamecreator is right, if you update several elements, use 1 only for the last one.
Meaning is: redraw the whole dialog after changing control state.

Valery · 03.05.2015 23:31

yes I understood, is that the error for missing redraw popped up only in 2.55.

Berserker · 03.05.2015 23:42

Valery, we faced it in Phoenix even when Era had 1.xx versions. It comes from TE (2005). You were just lucky.

Valery · 03.05.2015 23:48

ok boss, all my DL have 4th parameter, I only forgot it once and I payed of my life and blood.

;must fix emerald tower script, right? As it is now, is big error:

!?TM38;
!!UN:P44/?y-1; [Check if script is enabled: y-1]
!!FU&y-1<>1:E; [Exit if script isn't enabled]
!!UN:U63/65/?v1; [Number of Emerald Towers: v1]
!!VRv1:S-1; [Initialize v1 to -1 to work with new faster UN:U syntax]
!!DO10910/1/v1/1&v1>0:P; [Loop through all Emerald Towers]

v1 stores number of towers and is set to -1 next command, then next command the loop is screwed. I fix it by replacing v1 with the usual y-1, ok?

!!UN:U63/65/?y-1; [Number of Emerald Towers: y-1]
!!VRv1:S-1; [Initialize v1 to -1 to work with new faster UN:U syntax]
!!DO10910/1/y-1/1&y-1>0:P; [Loop through all Emerald Towers]

Amazing this error stayed there for 10 years.

Bes · 04.05.2015 00:26

Quote:Function to change building position:

!!VRy1:S0; //city (e.g. Castle)
!!VRy2:S5; //building ID (e.g Tavern)

!!VRy6:S2; //frames num in new def
!!VRy3:S250; //new x
!!VRy4:S200; //new y

!!VRy5:Sy1 *44 +y2 *6 +6859276;

!!UN:Cy5/2/y6;
!!VRy5:+2;
!!UN:Cy5/2/y3;
!!VRy5:+2;
!!UN:Cy5/2/y4;

For more information try to see this post (with translator)
http://forum.df2.ru/index.php?showtopic=...t&p=192935

Valery · 04.05.2015 14:26

Bersy, how to use in Komposer the erm format I see in some of the htm files? Like here in forum.

Berserker · 04.05.2015 15:06

I didn't include highlighting script there. Once solitaire345 did it. He also added SN commands from Era. I understood you correctly?
We could try, if you wish.

Valery · 04.05.2015 15:14

yes, solitaire used it in several receivers htm. Did this mean he had to implement it for only that file?

of course it looks better with, as all other codes examples are pure red. But if too much work, it will be enough as it is.

Berserker · 04.05.2015 17:26

Not too much, but I'm currently feeling graaaay…fog.

Threaded Mode \| Linear Mode Updating the erm help, please contribute
Author	Message