Threaded Mode | Linear Mode

Algor · 04.03.2015 18:01

Для случайных карт это все определяется шаблоном, а балансировать стоимость существ и зданий на основании какой-то выборки стандартных карт как-то неправильно...
Опять же, с т.з. доступности ресурсов надо бы оценивать кол-во зданий, который приносят фиксированный тип ресурсов - банки существ (кроме циклопского), сады лепрекона. Хотя они также определяются автором шаблона или карты.

Есть, кстати, еще неравномерность при использовании "плотности" шахт (наверняка и городов, не проверял). Т.е. если в шаблоне кол-во шахт задано не фиксировано, а плотностью, генератор будет в первую очередь пытаться разместить ртуть и в последнюю - золото (т.е. в порядке следования в rmg-шаблоне). Т.о. если не пытаться погонять вручную плотности под размеры карты и локаций (а этого никто не делает, как я заметил), ртутных рудников попадаться будет больше. Но, опять же справедливости ради, "плотности" в rmg-шаблонах практически не используются.

Дьякон · 04.03.2015 18:32

(04.03.2015 18:01)Algor Wrote: Для случайных карт это все определяется шаблоном, а балансировать стоимость существ и зданий на основании какой-то выборки стандартных карт как-то неправильно...

Любой баланс можно испортить картой. Как бы не балансировалась стоимость монстров и строений можно написать такой шаблон, который будет сводить на нет все попытки баланса (поставить по 10 шахт, например). Баланс карт - это такой же важный элемент игры. Поэтому есть два пути:
1) Балансишь монстров и здания по вкусу, а потом создаешь свои карты под этот баланс (естественно это бредовый вариант)\
2) Берешь готовые шаблоны СоДа и на основании статистики полученных карт (либо анализа шаблонов) - балансишь все остальное и выставляешь требования к новым шаблонам, а может и правка особо выбивающихся старых шаблонов.
Первый вариант - это начало с нуля, второй - это отталкивание от какой-то базы. Я выбираю второй вариант.

На счет банков существ - большой вопрос в том какой % они занимают по сравнению с общими сокровищами. А вот на счет мельниц и садов леприкона - мое упущение, спасибо за подсказку.

Algor · 04.03.2015 19:15

В таком случае первые 2 пункта можно почитать по rmg.txt

Для третьего вот:

!#TM19:S1/1/1/255;
!?TM19;
!!UN:U79/0/?y1 U79/1/?y2 U79/2/?y3 U79/3/?y4 U79/4/?y5 U79/5/?y6 U79/6/?y7;
!!IF:M^На карте:
=================
Дерево: %Y1 куч.
Руда: %Y3 куч.
Ртуть: %Y2 куч.
Сера: %Y4 куч.
Кристаллы: %Y5 куч.
Драг.камни: %Y6 куч.
Золото: %Y7 куч.^;

Пример на карте XL+U, шаблон Ring:
Image: script.jpg

Кол-во ресурсов в кучах считать?

Либо можно с картинками, что-то сразу не допер:

!#TM19:S1/1/1/255;
!?TM19;
!!UN:U79/0/?y1 U79/1/?y2 U79/2/?y3 U79/3/?y4 U79/4/?y5 U79/5/?y6 U79/6/?y7;
!!IF:N1/y2/3/y4/4/y5/5/y6/0/y1/2/y3/6/y7;
!!IF:N^Кучи ресурсов на карте:^;

Дьякон · 04.03.2015 19:26

Да если можно количество ресурсов, если добавить еще мельницы (водяные и простые) и сады леприкона, то вообще отлично.
У1 везде я так понял просто ошибка копипаста ))?

igrik · 04.03.2015 19:50

Да все также: y1 .... и т.д не копипаста, а все остальное да

!!UN:U112/-1/?y10; 112 Ветряная мельница
означает посчитать все объекты (112 Ветряная мельница ) любого подтипа (-1) и занести это число в переменную y10
!!IF:M^%Y10^; отобразить содержимое переменной
; 109 Водяное колесо
; 79 Ресурс [0-7 – таблица ресурсов] ! уже не -1 как выше
; 53 Шахта [0-7 – таблица шахт]

аналогично и с остальными объектами

Algor · 04.03.2015 19:59

Дьякон Wrote:У1 везде я так понял просто ошибка копипаста ))?

Да, было) На работе сижу, отвлекают всякой фигней, вот и не уследил 148

Дьякон · 05.03.2015 00:38

Подсчитать количество ресурсов в куче можно?
Или сколько в среднем попадает в кучу?

gamecreator · 05.03.2015 00:46

Можно, AR:V.
Случайное количество ресурсов в куче, если не ошибаюсь, 5-10 для дерева, руды и золота и 3-6 для остальных.

Algor · 05.03.2015 13:10

Дьякон Wrote:Подсчитать количество ресурсов в куче можно?

Извини, отвлекся вчера:

ZVSE
!#TM19:S1/1/1/255;
!?TM19;
!!UN:U109/-1/?y1 U112/-1/?y2 U55/-1/?y3;
!!IF:M^Объекты на карте:
=================
Водяное колесо: %Y1
Ветряная мельница: %Y2
Сад лепрекона: %Y3^;
!!UN:U53/0/?y1 U53/1/?y2 U53/2/?y3 U53/3/?y4 U53/4/?y5 U53/5/?y6 U53/6/?y7;
!!IF:N1/y2/3/y4/4/y5/5/y6/0/y1/2/y3/6/y7;
!!IF:N^Рудники на карте:^;
!!UN:U79/0/?y1 U79/1/?y2 U79/2/?y3 U79/3/?y4 U79/4/?y5 U79/5/?y6 U79/6/?y7;
!!IF:N1/y2/3/y4/4/y5/5/y6/0/y1/2/y3/6/y7;
!!IF:N^Кучи ресурсов на карте:^;
!!VRv1:C0/0/0/0/0/0/0/-1;
!!UN:U79/-1/?y1;
!!DO9876/1/y1/1:P;
!!IF:N1/v2/3/v4/4/v5/5/v6/0/v1/2/v3/6/v7;
!!IF:N^Кол-во ресурсов в кучах на карте:^;
!?FU9876;
!!UN:U79/-1/-1/8;
!!OB8:U?y1;
!!VRy1:+1;
!!AR8:V?y2;
!!VRy2&y1=7:*100;
!!VRvy1:+y2;

Дьякон · 05.03.2015 13:51

Спасибо!! А я сижу страдаю. 3 часа потратил на чтение справки и написание скрипта ( и то еще не тестил, может и не работает). Как быстро человек все забывает (((

ZVSE
!#TM3:S1/1/1/255;
!?TM3;
!!DO1/0/7/1:P79;
!!UN:U112/-1/?v500 U109/-1/?v501 U55/-1/?v502;
!!IF:M^На карте:
=================
Дерево: %V401
Руда: %V403
Ртуть: %V402
Сера: %V404
Кристаллы: %V405
Драг.камни: %V406
Золото: %V407
Мельниц: %V500
Водяное колесо: %V501
Сад леприкона: %V502^;
!?FU1;
!!UN:Ux1/x16/?y1;
!!VRv700:S0;
!!DO2/1/y1/1:Px1/x16;
!!VRy3:Sx16 +400
!!VRvy3:Sv700;
!?FU2;
!!UN:Ux1/x2/-1/310;
!!ARv310/v311/v312:V?y1;
!!VRv700:+y1;

Кстати, а можно ли играть в СоД через ехе Вога (ну т.е. без скриптов и без новых монстров и т.п.), но с поддержкой ЕРМ?

P.S. Я так понял золото еще нужно на 100 умножать.

Algor · 05.03.2015 14:05

(05.03.2015 13:51)Дьякон Wrote: Кстати, а можно ли играть в СоД через ехе Вога (ну т.е. без скриптов и без новых монстров и т.п.), но с поддержкой ЕРМ?

У Valery есть мод

Safe SoD (Click to View)

(05.03.2015 13:51)Дьякон Wrote: P.S. Я так понял золото еще нужно на 100 умножать.

Да, у меня умножено.

igrik · 06.03.2015 00:39

Valery выкладывал мод [Upgrade all] (button upgrading all creatures in town sceen)
Это то же, только без кнопок и раздельно на каждого героя или город. Клик + Shift на портрете героя или на флаге игрока

Spoiler (Click to View)

ZVSE
; автоматический грейд существ в замке Клик + Shift на любом из портретов героев в городе
!?CM1;
!!CM:F?y6 S?y7 I?y5;
!!FU|y7<>12/y6<>1:E;
!!if|y5=123/y5=125:;
!!CA-1&y5=123:H0/?y1; получить номер героя визитера
!!CA-1&y5=125:H1/?y1; получить номера героя гостя
!!FU&y5=125/y1=-1:E; если клик на месте героя гостя, а его нет, то выход
!!CM:R0;
!!DO33035/0/6/1:Py1;
!!UN:R4; обновить экран города
!!en:;
!?FU33035;
; x1 - номер героя, если -1, то это город
; x16 - номер проверяемого слота
!!if&x1<>-1:; герои
!!HEx1:C0/x16/?y1/?y2; узанть что за монстр
!!FU33036&y1<>-1:Py1/y2/?y4; передать номер и кол-во дегрейда, и получить номер апгрейда
!!HEx1&y4<>-1:C0/x16/y4/y2/0/5; улучшить монстра
!!el:; город
!!CA-1:P?y11/?y12/?y13; получить координаты города
!!CAy11/?y12/?y13:M2/x16/?y14/?y15; узанть что за монстр
!!FU33036&y14<>-1:Py14/y15/?y4; передать номер и кол-во дегрейда, и получить номер апгрейда
!!if&y14<>-1/y4<>-1:;
!!EXy11/y12/y13/x16/2:A?y14/?y15/?y10; [проверили опыт у существа]
!!EXy11/y12/y13/x16/2:R?y90/?y91/?y92/?y93; [наличие Знамени Полководца, и его навык (в слоте города)]
!!CAy11/y12/y13:M2/x16/y4/y15; [установили существо в слот города]
!!VRy9:Sy10 *5 :100;
!!VRy10:-y9; отнять 5% опыта
!!VRy10&y10<0:S0; проверка чтобы опыт не уходи в минус
!!EXy11/y12/y13/x16/2:Ay4/y15/y10; [и сюда же вогнали опыт]
!!EXy11/y12/y13/x16/2:Ry90/y91/y92/y93; [данные о знамени (в город)]
!!en:;
!!en:; конец условия
!?FU33036; работа с монстрами
; x1 - номер монстра
; x2 - кол-во мностров
; x3 - возврат улучшенного номера монстра
; если где-то ниже условие не проходит, то x3 нужно ставить в -1
!!VRx3:S-1; обнуление переменной
!!MA:Ux1/?y90; узнать в кого грейдится
!!FU&y90=-2:E; выход, если не улучшается
!!if&y90=-1:; если стандартное улучшение
!!VRy1:Sx1 %2;
!!VRx3|y1<>0/x1>131:S-1;
!!FU|y1<>0/x1>131:E; если это улучшенный или дальше лазурного по списку - выход
!!if&x1>=112/x1<=115:;
!!VRx3&x1=112:S127; Воздушный Элементаль
!!VRx3&x1=113:S125; Элементаль Земли
!!VRx3&x1=114:S129; Огненный Элементаль
!!VRx3&x1=115:S123; Элементаль Воды
!!el:;
!!VRx3:Sx1 +1; улучшенный
!!en:;
!!el:;
!!VRx3:Sy90; указываем номер существа грейда
!!en:;
;--- работа с типом замка
!!CA-1:T?y2; узнать тип замка 0...8
!!MA:Ox1/?y3; узнать тип замка, которому принадлежит дегрейд
; если разные, то:
!!VRx3&y3<>y2:S-1; обнуление переменной
!!FU&y3<>y2:E; и выход
;--- работа со строениями в замке
!!MA:Lx3/?y2; проверить уровень существа грейда 0...6
!!VRy2:+37; переход к номеру ул.стоений
!!CA-1:B3/y2; узнать постоено ли здание в флаг 1
; если нет, то:
!!VRx3&-1:S-1; обнуление переменной
!!FU&-1:E; и выход
;--- работа с деньгами
!!MA:Cx1/6/?y10; узанть скок стоит монстр дегрейд
!!MA:Cx3/6/?y11; узанть скок стоит монстр апгрейд
!!VRy11:-y10 *x2; узнать общую стоимость улучшения стека
!!OW:R-1/6/?y12; проверить игрока на золото
!!VRy12:-y11; получить разницу
!!VRx3&y12<0:S-1; если денег нехватает то грейд -1
!!FU&y12<0:E; если денег нехватает, выход
;--- работа с ресурсами для апгерйда
!!DO33037/0/6/1:Px1/x3/?y2/?y3; узнать стоимость монстра (ресурсы)
!!if&y3<>0:; если стоит какой-либо ресурс, то
!!OW:R-1/y3/?y4; проверить игрока на ресурс
!!VRy4:-y2; получить разницу
!!VRx3&y4<0:S-1; если денег нехватает то грейд -1
!!FU&y4<0:E; если денег нехватает, выход
!!OW:R-1/y3/y4; забрать у игрока ресурс
!!en:;
!!OW:R-1/6/y12; забрать у игрока золото
!?FU33037; работа с ресурсами для апгерйда
; x1 - номер монстра дегрейда
; x2 - номер монстра апгрейда
; x3 - возврат кол-ва ресурсов
; x4 - возврат типа ресурса
!!MA:Cx1/x16/?y1; проверка на ресурс дегрейда
!!MA:Cx2/x16/?y2; проверка на ресурс апргрейда
!!VRy2:-y1; вычитаем стоимость
!!VRx3&y2<>0:Sy2; передать кол-во ресурсов
!!VRx4&y2<>0:Sx16; передать тип ресурсов
!!VRx16&y2<>0:S7; и выход
*** end [автоматический грейд существ в замке]
*** ------------------------------------------

gamecreator · 22.03.2015 00:13

Теперь Эта тема - своеобразный "стол заказов".
Подробно описываете что желаете увидеть и, если повезёт, кто-нибудь из местных умельцев откликнется и напишет скрипт специально для Вас!

v3r3r · 09.08.2015 13:41

Добрый день. Играю в версию 3.58f, там есть такой эвент (можно выбрать через WoG-меню) "неделя монстров", т.е. когда всю неделю только один тип монстра имеет усиление на основные параметры.

Все бы ничего, но мне предельно хочется, чтобы монстр, получивший усиление на ЕГО неделе - сохранял усиление навсегда! Вплоть до последующих усилений от "недели монстров" - т.е. когда этот монст получит еще большее усиление ...и так до бесконечночи.

До бесконечности конечно вряд ли дойдет, но сам факт, что баланс игры может немного измениться в чью-то пользу - очень интригует.

Пожалуй хочу этот скрипт больше чем какой-либо другой. Ведь тут много зависит от рандома.

Если кто-то готов помочь с таким скриптом - буду очень признателен.
З.Ы. сам я гуманитарий, все замуты с ERM закончились для меня тем, что сильно разболелась голова и взорвался мозг - не мое это, слишком сложно.

Algor · 09.08.2015 20:00

Интересная идея. Отпишитесь потом, как оно в игре.

Исправленный script20.erm (закоментарена 241 строка) положить в Data/s.

Для чертей/бесов при отстроенном в Инферно граале параметры сохраняться не будут.

Threaded Mode \| Linear Mode Если просто нужен скрипт
Author	Message