Threaded Mode | Linear Mode

Algor · 01.06.2013 19:10

(01.06.2013 16:18)Фаталист Wrote: ...в момент загрузки карты (работает нормально) можно ли как-нибудь вставить туда картинку НЕ из стандартных?

ZVSE
!?PI; [перед показом карты]
!!VRz1:S^../data/test.bmp^; [путь относительно каталога maps]
!!IF:B77/1/0 P77; [определение картинки для диалога №77 и показ его]

Такое нужно было? Или с текстом, вводом данных и несколькими картинками?

Фаталист · 02.06.2013 18:23

ZVSE
!?PI;
!!VRz1:S^../Data/Pic/JC.bmp^;
!!IF:B77/1/0 P77;
!!IF:M^{История "героя".}
{Глава первая - Уход из Тимстрина v1.0}
Джейн - красивая девушка, родившаяся в маленькой деревушке Тимстрин. По мере взросления у неё всё сильнее разгоралось желание отправиться в путешествия, научится сражаться, и, даже, попробовать овладеть магическими навыками. И вот время пришло...
{Разработчики карты:}
{Фаталист} - идея, реализация карты, корректирование скриптов.
{Algor} - написание сложных и универсальных скриптов для карты.
Отдельные благодарности - {ИО Bes-а}, {Berserker}, {MOP} за небольшие подсказки, советы и ответы по написанию скриптов для этого сценария.
Карта сделана на базе сайта - {wforum.heroes35.net}^;

Вот так вот вышло. С начало выводится стандартное окошко вогификации, потом выводится картинка и после сообщение. Спасибо за помощь.

В принципе, осталось до конца создания карты всего 2 скрипта (остальные уже производные будут, я их сам спокойно смогу откорректировать). Так вот, начну с первого. Это скрипт повторяющегося нападения (тот который вы написали), так вот я туда добавил пару строчек, которые добавляют/заменяют бойцов в собственной армии.

ZVSE
!?LE22/33/0&999;
!!VRv1222:S1;
!!IF:M^Сообщение №1^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=1;
!!BA:M0/4/137/1;
!!BA:M1/0/84/5 M1/1/84/4 M1/2/85/3 M1/3/140/2 M1/4/85/3 M1/5/84/4 M1/6/84/5;
;...
!?BA53&v1222=1;
!!BA:H0/?y1;
!!HEy1:O?y2;
!!VRv1222&y2=-1:S0;
!!FU&y2=-1:E;
!!VRv1222:S2;
!!IF:M^Сообщение №2^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=2;
!!BA:M0/0/170/1 M0/1/171/1 M0/2/137/1 M0/3/137/1 M0/4/137/1 M0/5/171/1 M0/6/170/1;
!!BA:M1/0/86/2 M1/1/86/2 M1/2/85/4 M1/3/140/2 M1/4/84/4 M1/5/87/1 M1/6/87/1;
!!VRv1222:S0;

Так вот. Три маленьких вопроса. Первый как прописать строчку !!BA:M0, чтобы юнит в первой волне добавлялся не в определённый заданный слот, а в пустующий. Второй, после окончания события армия остаётся такой же как была задана в событии, так вот как вернуть армию, которая была до события? И третий, как правильно прописать третье сообщение после завершения события (если в конце прописать !!IF:M^Сообщение №3^; то перед вторым боем срабатывает третье сообщение)?

Algor · 02.06.2013 21:20

(02.06.2013 18:23)Фаталист Wrote:
{Разработчики карты:}
{Фаталист} - идея, реализация карты, корректирование скриптов.
{Algor} - написание сложных...
Вот так вот вышло. С начало выводится стандартное окошко вогификации, потом выводится картинка и после сообщение.

Если так хочется указать помогавших, лучше засунуть это в штатное описание карты. Выдавать такое при запуске, имхо, ущерб атмосферности. И слово "сложных" убери, оно совсем не так.
И, кстати, если текстовый ввод решил делать в формате "Глава первая", то намного круче будет это будет смотреться как картинка, на которой изображен свиток/страничка книги/обрывок пергамента с текстом "начала главы". Ну это конечно если с графикой дружишь.

(02.06.2013 18:23)Фаталист Wrote: Три маленьких вопроса. Первый как прописать строчку !!BA:M0, чтобы юнит в первой волне добавлялся не в определённый заданный слот, а в пустующий.

Можно использовать "призыв":

!!BU:S9/1/3/0/-1/1; [призыв 1го фанатика(9) в 3ю позицию поля боя на сторону нападающего, исчезает после боя]

(02.06.2013 18:23)Фаталист Wrote: Второй, после окончания события армия остаётся такой же как была задана в событии, так вот как вернуть армию, которая была до события?

Проще всего перед боем (триггер BA52) сохранить армию во временные переменные, а после боя (триггер BA53) восстановить ее:

!?BA52;
!!HE-1:N?v1360;[v1360 - номер героя]
!!HE-1:C0/0/?v1361/?v1371 C0/1/?v1362/?v1372 C0/2/?v1363/?v1373 C0/3/?v1364/?v1374 C0/4/?v1365/?v1375 C0/5/?v1366/?v1376 C0/6/?v1367/?v1377; [v1361-1367/v1371-1377 - типы/количества существ в отрядах]
!?BA53;
!!HEv1360:O?y1; [y1 - хозяин героя]
!!FU&y1<0:E; [выход, если герой проиграл бой]
!!HEм1360:C0/0/v1361/v1371 C0/1/v1362/v1372 C0/2/v1363/v1373 C0/3/v1364/v1374 C0/4/v1365/v1375 C0/5/v1366/v1376 C0/6/v1367/v1377; [восстанавливаем сохраненную армию]

(02.06.2013 18:23)Фаталист Wrote: И третий, как правильно прописать третье сообщение после завершения события (если в конце прописать !!IF:M^Сообщение №3^; то перед вторым боем срабатывает третье сообщение)?

Сообщение нужно писать в триггере BA53 после 3го боя. И там же (а не в BA52) сбросить счетчик боев.

!?BA53&v1222=2;
!!IF:M^Сообщение №3^;
!!VRv1222:S0; [сброс счетчика боев]

Фаталист · 02.06.2013 21:42

Algor,

Quote:Если так хочется указать помогавших, лучше засунуть это в штатное описание карты. Выдавать такое при запуске, имхо, ущерб атмосферности. И слово "сложных" убери, оно совсем не так. И, кстати, если текстовый ввод решил делать в формате "Глава первая", то намного круче будет это будет смотреться как картинка, на которой изображен свиток/страничка книги/обрывок пергамента с текстом "начала главы". Ну это конечно если с графикой дружишь.

Ок, сделаю. Я помимо того что сам немного разбираюсь в фотошопе, так ещё пара друзей есть, только я тогда уже думаю смастерю "одну" картинку, которая будет содержать изображение JC.pcx и описание в красивом оформлении пергамента (прикольно то, что у меня на винчестере до сих пор лежат граф. ресурсы с пергаментами). Разработчиков, нас, впишу тогда в реадми файл.

По поводу скрипта, второе и третье - это именно то что я хотел. Вот только первое, а если в этой клетке уже будут юниты (ситуация: герой с 2 отрядами (по умолчанию 0 и 1 ячейки, а вот если игрок переставит одного из них в 4 ячейку...) заходит в событие и если совпадает ячейка, то юнит заменяется (если б я точно знал с какими войнами игрок подойдёт в эту точку, я бы их просто дополнительно прописал, а так может случится замена и бой будет проигран из-за отсутствия одного война)).

Algor · 02.06.2013 22:26

(02.06.2013 21:42)Фаталист Wrote: Вот только первое, а если в этой клетке уже будут юниты (ситуация: герой с 2 отрядами (по умолчанию 0 и 1 ячейки, а вот если игрок переставит одного из них в 4 ячейку...) заходит в событие и если совпадает ячейка, то юнит заменяется (если б я точно знал с какими войнами игрок подойдёт в эту точку, я бы их просто дополнительно прописал, а так может случится замена и бой будет проигран из-за отсутствия одного война)).

В указанном примере "ячейка" это гекс на поле боя а не слот в армии героя, так что пересечения не будет. Единственная накладка может случиться если на гексе будет препятствие (хотя в 3м гексе препятствий не бывает, насколько я помню), но это можно обойти удалив например все препятствия (и тогда уже призывать помощников в любой гекс без опаски):

!?BF&v1222=2; [подготовка поля боя ко второй битве]
!!BF:C; [удалить все препятствия с поля боя]

Фаталист · 02.06.2013 23:48

Algor, Ааа... тогда всё правильно будет происходить. Спасибо

Фаталист · 03.06.2013 14:06

Algor, Можешь сказать между какими строчками нужно вставлять скрочку вызова фанатика, чтобы он появился? Вставлял между 7-10 строчками, ошибок синтаксических не было, но и он в бою не появлялся (гекс пустой, проверял), если раньше 7 строчки вставлял - синтаксическая ошибка.

ZVSE
!?LE22/33/0&999;
!!VRv1222:S1;
!!IF:M^Сообщение №1^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=1;
!!HE-1:N?v1360;
!!HE-1:C0/0/?v1361/?v1371 C0/1/?v1362/?v1372 C0/2/?v1363/?v1373 C0/3/?v1364/?v1374 C0/4/?v1365/?v1375 C0/5/?v1366/?v1376 C0/6/?v1367/?v1377;
!!BA:M1/0/84/5 M1/1/84/4 M1/2/85/3 M1/3/140/2 M1/4/85/3 M1/5/84/4 M1/6/84/5;
;...
!?BA53&v1222=1;
!!BA:H0/?y1;
!!HEy1:O?y2;
!!VRv1222&y2=-1:S0;
!!FU&y2=-1:E;
!!VRv1222:S2;
!!IF:M^Сообщение №2^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=2;
!!BA:M0/0/170/1 M0/1/171/1 M0/2/137/1 M0/3/137/1 M0/4/137/1 M0/5/171/1 M0/6/170/1;
!!BA:M1/0/86/2 M1/1/86/2 M1/2/85/4 M1/3/140/2 M1/4/84/4 M1/5/87/1 M1/6/87/1;
;...
!?BA53&v1222=2;
!!HEv1360:O?y1;
!!FU&y1<0:E;
!!HEv1360:C0/0/v1361/v1371 C0/1/v1362/v1372 C0/2/v1363/v1373 C0/3/v1364/v1374 C0/4/v1365/v1375 C0/5/v1366/v1376 C0/6/v1367/v1377;
!!IF:M^Сообщение №3^;
!!VRv1222:S0;

Algor · 03.06.2013 15:29

(03.06.2013 14:06)Фаталист Wrote: Algor, Можешь сказать между какими строчками нужно вставлять скрочку вызова фанатика, чтобы он появился?

В триггере BR вставлять надо:

!?BR&v997=-1/v1222=2; [в "нулевом раунде" 2го боя]
!!BU:S9/1/3/0/-1/1; [призываем фанатика в 3й гекс]

Фаталист · 03.06.2013 18:39

ZVSE
!?BR&v997=-1/v1222=1;
!!BU:S137/1/2/0/-1/1 S170/1/172/0/-1/1;
!?LE22/33/0&999;
!!VRv1222:S1;
!!IF:M^Сообщение №1^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=1;
!!HE-1:N?v1360;
!!HE-1:C0/0/?v1361/?v1371 C0/1/?v1362/?v1372 C0/2/?v1363/?v1373 C0/3/?v1364/?v1374 C0/4/?v1365/?v1375 C0/5/?v1366/?v1376 C0/6/?v1367/?v1377;
!!BA:M1/0/143/2 M1/1/143/3 M1/2/143/4 M1/3/142/1 M1/4/143/4 M1/5/143/3 M1/6/143/2;
;...
!?BR&v997=-1/v1222=2;
!!BU:S170/1/2/0/-1/1 S170/1/18/0/-1/1 S170/1/19/0/-1/1 S137/1/70/0/-1/1 S137/1/87/0/-1/1 S137/1/104/0/-1/1 S171/1/154/0/-1/1 S171/1/155/0/-1/1 S171/1/172/0/-1/1 S143/5/32/1/-1/1 S143/5/66/1/-1/1 S143/5/82/1/-1/1 S143/5/99/1/-1/1 S143/5/116/1/-1/1 S143/5/134/1/-1/1 S143/5/168/1/-1/1;
!?BA53&v1222=1;
!!BA:H0/?y1;
!!HEy1:O?y2;
!!VRv1222&y2=-1:S0;
!!FU&y2=-1:E;
!!VRv1222:S2;
!!IF:M^Сообщение №2^;
!!HE-1:T22/33/0/0/1;
!?BA52&v1222=2;
!!BA:M0/0/170/1 M0/1/170/1 M0/2/137/1 M0/3/183/1 M0/4/137/1 M0/5/171/1 M0/6/171/1 M1/0/142/2 M1/1/143/5 M1/2/193/2 M1/3/178/1 M1/4/193/2 M1/5/143/5 M1/6/142/2;
;...
!?BA53&v1222=2;
!!HEv1360:O?y1;
!!FU&y1<0:E;
!!HEv1360:C0/0/v1361/v1371 C0/1/v1362/v1372 C0/2/v1363/v1373 C0/3/v1364/v1374 C0/4/v1365/v1375 C0/5/v1366/v1376 C0/6/v1367/v1377;
!!IF:M^Сообщение №3^;
!!VRv1222:S0;

Вот что получилось после редактирования... Спасибо 132

И теперь последний скрипт, который понадобится для карты. Допустим есть в n/n/n координатах конкретный монстр, так вот если на него напасть, нужно чтобы высветилось сообщение с выбором да/нет и если ответ да, то сражение с монстром визуального не должно быть (автобоя тоже) и его засчитали как убитого (чтобы после сдать задание), а если ответить нет, то должно после этого появиться ещё одно сообщение после которого бой и после битвы дался бонус в виде одной характеристики. Сможете?

Algor · 03.06.2013 19:27

(03.06.2013 18:39)Фаталист Wrote: Допустим есть в n/n/n координатах конкретный монстр, так вот если на него напасть, нужно чтобы высветилось сообщение с выбором да/нет и если ответ да, то сражение с монстром визуального не должно быть (автобоя тоже) и его засчитали как убитого (чтобы после сдать задание), а если ответить нет, то должно после этого появиться ещё одно сообщение после которого бой и после битвы дался бонус в виде одной характеристики. Сможете?

Задание выдается стандартное в хижине провидца? Типа уничтожить монстра в координатах a/b/c? Если да, то:

!?OB10/11/0&999; [при посещении игроком-человеком объекта в координатах 10/11/0]
!!IF:Q1/21/27/2^Вот это удача! Золотой дракон спит! Можно незаметно подкрасться и прикончить его, а можно победить его в честном бою получив опыт сражения с драконами и ценные знания. Прикончить дракона во сне?^;
!!UN&1:O10/11/0/1; [при положительном ответе удаляем монстра...]
!!OB10/11/0&1:S; [...запрещаем посещать объект в координатах 10/11/0...]
!!FU&1:E; [... и выходим]
!!VRv1223:S1; [v1223=1, если будет бой]
!!IF:M^Победить дракона в честном бою! Поступок достойный героя! - об этом Вы думаете, доставая любимый боевой рог, звук которого может поднять и мертвого.^;
!$OB10/11/0&999/v1223=1; [после посещения объекта в координатах 10/11/0 и проведения боя]
!!IF:Q1/31/1/34/1/1^Славная победа! Вы чувствуете себя сильнее... и мудрее.^;
!!HE-1:Fd1/d/d/d1; [+1 к атаке и знанию героя]
!!UN:R1; [обновляем карту]

Фаталист · 03.06.2013 19:53

Algor,

Quote:Задание выдается стандартное в хижине провидца? Типа уничтожить монстра в координатах a/b/c? Если да, то:

Да, именно то, что в хижине провидца. По поводу скрипта, ещё нужно добавить чтобы при исходе с ответом да, герою дали артефакт.

Algor · 03.06.2013 20:13

(03.06.2013 19:53)Фаталист Wrote: Algor,
Quote:Задание выдается стандартное в хижине провидца? Типа уничтожить монстра в координатах a/b/c? Если да, то:
Да, именно то, что в хижине провидца. По поводу скрипта, ещё нужно добавить чтобы при исходе с ответом да, герою дали артефакт.

...
!!HE-1&1:A4/21; [... даем герою Шлем Хаоса ... ]
!!FU&1:E; [... и выходим]
...

Фаталист · 03.06.2013 20:20

Algor, Вот, теперь со скриптами всё

Я примерно к завтрашнему вечеру закончу карту и выложу.

Фаталист · 03.06.2013 22:47

Тут небольшая проблем-ка, можно добавить сообщение высвечивающиеся после выбора ответа 'да'? Изначальная идея немного не красиво вышла, без этого сообщения.

Algor · 03.06.2013 23:10

...
!!HE-1&1:A4/21; [... даем герою Шлем Хаоса ... ]
!!IF&1:M^Сообщение после ответа "да"^;
!!FU&1:E; [... и выходим]
...

Threaded Mode \| Linear Mode Ваши вопросы по ERM-скриптам
Author	Message