ZVSE
ERMS_ScriptDate=31.8(August).2004
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.8.11.911


** Architect ERM Script v1.2 created by Tetral00.
** This script adds architects in your towns.
** To activate architect, click the right mouse button
** on Village Hall, Town Hall, City Hall or Capitol.

** Requires WoG version 3.58 or later using ERM version 2.80 or later.

** Variables used: (v1-v8), v2900-v2947, (z1-z10)
** ERT Z Variables used: z190000-z190010
** Functions used: 29000-29040
** Timers used: 29
** Dialogs used: 29
** WoG Options used: 90


** Получить путь к изображению архитектора для города x1
** Результат сохраняется в z[x2]
!?FU29000;
!!CA0/x1:T?y1;
!!VRzx2:S^^;
!!VRzx2&y1=0:S^..\data\s\archcas.jpg^;
!!VRzx2&y1=1:S^..\data\s\archram.jpg^;
!!VRzx2&y1=2:S^..\data\s\archtow.jpg^;
!!VRzx2&y1=3:S^..\data\s\archinf.jpg^;
!!VRzx2&y1=4:S^..\data\s\archnec.jpg^;
!!VRzx2&y1=5:S^..\data\s\archdun.jpg^;
!!VRzx2&y1=6:S^..\data\s\archstr.jpg^;
!!VRzx2&y1=7:S^..\data\s\archfor.jpg^;
!!VRzx2&y1=8:S^..\data\s\archele.jpg^;

** Установить тип x2 архитектора в городе с номером x1
** Если архитектора в городе нет - 0
** Если архитектор есть, но отдыхает - 1
** Если архитектор строит город, рапортуя каждый день - 2
** Если архитектор строит город, рапортуя о нехватке ресурсов - 3
** Если архитектор строит город, рапортуя только об окончании строительства - 4
!?FU29001;
!!VRy1:S2900 +x1;
!!VRvy1:Sx2;

** Получить тип архитектора в городе с номером x1.
** Возвращаемое значение - в v1.
!?FU29002;
!!VRy1:S2900 +x1;
!!VRv1:Svy1;

** Установить тип x1 архитектора во всех городах
!?FU29006;
!!DO29005/0/47/1:Px1;

!?FU29005;
!!FU29001:Px16/x1;

** Подсчет числа капитолиев игрока, которому принадлежит город x1
** (результат записывается в v1)
!?FU29007;
!!CA0/x1:O?y1;
!!VRv1:S0;
!!OW:Wy1/?y2;
!!VRy2:-1;
!!DO29008/0/y2/1:Py1;

!?FU29008;
!!OW:Wx1/x16/?y1;
!!CA0/y1:B3/13;
!!VRv1&1:+1;

** Определить, сколько рядом с городом x1 клеток с водой
** (результат записывается в v1)
!?FU29009;
!!CA0/x1:P?y1/?y2/?y3;
!!VRv1:S0;
!!VRy2:+1; // 0/1/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;
!!VRy2:+1; // 0/2/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;
!!VRy1:-1; // -1/2/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;
!!VRy1:+2; // 1/2/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;
!!VRy2:-1; // 1/1/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;
!!VRy1:-2; // -1/2/0
!!TRy1/y2/y3:T?y4/?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!VRv1&y4=8:+1;

** Отнять у игрока x1 ресурсы
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore,
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems,
** v[x2+6] --- gold.
!?FU29010;
!!VRy1:Sx2 +0; // wood
!!VRy2:Svy1 *-1;
!!OW:Rx1/0/dy2;
!!VRy1:Sx2 +1; // mercury
!!VRy2:Svy1 *-1;
!!OW:Rx1/1/dy2;
!!VRy1:Sx2 +2; // ore
!!VRy2:Svy1 *-1;
!!OW:Rx1/2/dy2;
!!VRy1:Sx2 +3; // sulfur
!!VRy2:Svy1 *-1;
!!OW:Rx1/3/dy2;
!!VRy1:Sx2 +4; // crystal
!!VRy2:Svy1 *-1;
!!OW:Rx1/4/dy2;
!!VRy1:Sx2 +5; // gems
!!VRy2:Svy1 *-1;
!!OW:Rx1/5/dy2;
!!VRy1:Sx2 +6; // gold
!!VRy2:Svy1 *-1;
!!OW:Rx1/6/dy2;

** Рапортовать о завершении строительства города.
** Номер города - x1
!?FU29011;
!!CA0/x1:N?z2;
!!VRz1:S^%Z190010^;
!!FU29000:Px1/3; // получить путь к изображению архитектора
!!VRz4:S^^;
!!IF:D29/z1/z4/z4/z3/z4/z4/z4/z4/z4/z4/z4/z4/z4/z4/z4;
!!IF:E1/29;
!!FU29001:Px1/1;

** Нарисовать меню для уточнения варианта застройки.
** Номер города - x1.
!?FU29012;
!!FU29002:Px1; // получаем текущий режим архитектора
!!VRy1:Sv1;
!!VRy2:S1;
!!VRy2&y1=1:S2;
!!VRy2&y1=2:S4;
!!VRy2&y1=3:S8;
!!VRy2&y1=4:S16;
!!CA0/x1:N?z1;
!!VRz1:S^%Z190000^;
!!VRz2:S190001; // 0
!!VRz3:S190002; // 1
!!VRz4:S190003; // 2
!!VRz5:S190004; // 3
!!VRz6:S190005; // 4
!!IF&y1>0:G1/2/y2/1/2/3/4/5/6; // выберите режим застройки...
!!VRy2:S0;
!!VRy2&y1>0/v2=2:S1;
!!VRy2&y1>0/v2=4:S2;
!!VRy2&y1>0/v2=8:S3;
!!VRy2&y1>0/v2=16:S4;
!!IF&y1>0/y2=0:Q2^%Z190007^; // уволить архитектора?
!!VRy2&y1>0/y2=0/-2:S1;
!!FU29001:Px1/y2; // запоминаем новый режим архитектора
!!FU29015&y2>1:Px1; // построить здание на этом ходу, если можно
!!IF:V1/0;
!!IF&y1>0:V1/1; // устанавливаем флаг 1, если меню выводилось

** Определить, достаточно ли у игрока ресурсов,
** чтобы возвести постройку x2 в городе с номером x1 стоимостью:
** v[x3+0] --- wood, v[x3+1] --- mercury, v[x3+2] --- ore,
** v[x3+3] --- sulfur, v[x3+4] --- crystal, v[x3+5] --- gems,
** v[x3+6] --- gold.
** Если ресурсов игрока достаточно, установить флаг 1,
** если недостаточно, то сбросить флаг 1.
** Если x4=2, выдать сообщение.
** Если x4=3, выдать сообщение, если ресурсов недостаточно.
** Если x4=4, не выдавать никаких сообщений.
!?FU29013;
!!CA0/x1:T?y1; // в y1 - тип города
!!CA0/x1:O?y2;
!!OW:Ry2/0/?y10 Ry2/1/?y11 Ry2/2/?y12; // получить кол. ресур. игрока
!!OW:Ry2/3/?y13 Ry2/4/?y14 Ry2/5/?y15 Ry2/6/?y16;
!!VRy2:Sx3;
!!VRy20:Svy2; // получаем стоимость постройки
!!VRy2:+1;
!!VRy21:Svy2;
!!VRy2:+1;
!!VRy22:Svy2;
!!VRy2:+1;
!!VRy23:Svy2;
!!VRy2:+1;
!!VRy24:Svy2;
!!VRy2:+1;
!!VRy25:Svy2;
!!VRy2:+1;
!!VRy26:Svy2;
!!VRy30:Sy20 -y10; // вычитаем из стоимости постройки рес. игрока
!!VRy31:Sy21 -y11;
!!VRy32:Sy22 -y12;
!!VRy33:Sy23 -y13;
!!VRy34:Sy24 -y14;
!!VRy35:Sy25 -y15;
!!VRy36:Sy26 -y16;
!!VRy3:S0; // запоминаем в y3 единицу, если ресурсов хватает
!!VRy3&y30<=0/y31<=0/y32<=0/y33<=0/y34<=0/y35<=0/y36<=0:S1;
!!VRy4:S0; // запоминаем в y4 единицу, если нужно сообщение
!!VRy4&x4=2:S1;
!!VRy4&x4=3/y3=0:S1;
!!VRz1:S^^; // записывает в z1 количество ресурсов
!!FU29014&y4=1/y3=0:Py30/y31/y32/y33/y34/y35/y36;
!!FU29014&y4=1/y3=1:Py20/y21/y22/y23/y24/y25/y26;
!!CA0/x1&y4=1:N?z2; // в z2 - название города
!!UN&y4=1:N2/3/y1/x2; // в z3 - название здания
!!VRy5:Sy1 +22;
!!VRz4:S^^; // в z4 - сообщение
!!VRz4&y4=1/y3=0:S^%Z190008^;
!!VRz4&y4=1/y3=1:S^%Z190009^;
!!FU29000:Px1/5; // в z5 - путь к изображению архитектора
!!VRz6:S^^;
!!IF&y4=1/y3=0:D29/z4/z6/z6/z5/z6/z6/z6/z6/z6/z6/z6/z6/z6/z6/z6;
!!IF&y4=1/y3=0:E1/29; // сообщение, если нехватка ресурсов
!!IF&y4=1/y3=1:Q2/y5/x2/2^%Z4^; // сообщение, если ресурсов достаточно
!!VRy3&y4=1/y3=1/-2:S0;
!!IF:V1/0;
!!IF&y3=1:V1/1;

** Напечатать в строку слова x1 дерева, x2 ртути, .. x7 золота.
** Поместить результат в z1.
!?FU29014;
!!VRz1:S^^;
!!VRy1:S0;
!!VRz1&x1>0:+^%X1 wood^;
!!VRy1&x1>0:+1;
!!VRz1&y1>0/x2>0:+^, ^;
!!VRz1&x2>0:+^%X2 mercury^;
!!VRy1&x2>0:+1;
!!VRz1&y1>0/x3>0:+^, ^;
!!VRz1&x3>0:+^%X3 ore^;
!!VRy1&x3>0:+1;
!!VRz1&y1>0/x4>0:+^, ^;
!!VRz1&x4>0:+^%X4 sulfur^;
!!VRy1&x4>0:+1;
!!VRz1&y1>0/x5>0:+^, ^;
!!VRz1&x5>0:+^%X5 crystal^;
!!VRy1&x5>0:+1;
!!VRz1&y1>0/x6>0:+^, ^;
!!VRz1&x6>0:+^%X6 gems^;
!!VRy1&x6>0:+1;
!!VRz1&y1>0/x7>0:+^, ^;
!!VRz1&x7>0:+^%X7 gold^;
!!VRy1&x7>0:+1;

** Ежедневные постройки в городе с номером x1
!?FU29015;
!!FU29002:Px1; // получаем тип автозастройки (в y1)
!!VRy1:Sv1;
!!CA0/x1:O?y2; // узнаем тип игрока (AI строит сам)
!!OW:Iy2/?y3;
!!VRy1&y3=1:S1;
!!CA0/x1:R?y2; // узнаем, можно ли строить на этом ходу
!!VRy1&y2=1:S1;
!!CA0/x1:T?y2; // получаем тип города (в y2)
!!FU29007:Px1; // подсчет числа капитолиев текущего игрока
!!VRy3:Sv1;
!!FU29009:Px1; // подсчет числа клеток с водой около этого города
!!VRy4:Sv1;
!!VRv1:S-1;
!!FU29020&y1>1/y2=0:Px1/y3/y4; // узнаем что можно строить (Castle)
!!FU29021&y1>1/y2=1:Px1/y3/y4; // узнаем что можно строить (Rampart)
!!FU29022&y1>1/y2=2:Px1/y3/y4; // узнаем что можно строить (Tower)
!!FU29023&y1>1/y2=3:Px1/y3/y4; // узнаем что можно строить (Inferno)
!!FU29024&y1>1/y2=4:Px1/y3/y4; // узнаем что можно строить (Necropolis)
!!FU29025&y1>1/y2=5:Px1/y3/y4; // узнаем что можно строить (Dungeon)
!!FU29026&y1>1/y2=6:Px1/y3/y4; // узнаем что можно строить (Stronghold)
!!FU29027&y1>1/y2=7:Px1/y3/y4; // узнаем что можно строить (Fortress)
!!FU29028&y1>1/y2=8:Px1/y3/y4; // узнаем что можно строить (Conflux)
!!VRy5:Sv1;
!!FU29011&y1>1/y5=-1:Px1; // рапорт: город построен
!!FU29030&y5<>-1/y2=0:Py5/2; // и сколько это стоит (Castle)
!!FU29031&y5<>-1/y2=1:Py5/2; // и сколько это стоит (Rampart)
!!FU29032&y5<>-1/y2=2:Py5/2; // и сколько это стоит (Tower)
!!FU29033&y5<>-1/y2=3:Py5/2; // и сколько это стоит (Inferno)
!!FU29034&y5<>-1/y2=4:Py5/2; // и сколько это стоит (Necropolis)
!!FU29035&y5<>-1/y2=5:Py5/2; // и сколько это стоит (Dungeon)
!!FU29036&y5<>-1/y2=6:Py5/2; // и сколько это стоит (Stronghold)
!!FU29037&y5<>-1/y2=7:Py5/2; // и сколько это стоит (Fortress)
!!FU29038&y5<>-1/y2=8:Py5/2; // и сколько это стоит (Conflux)
!!FU29013&y5<>-1:Px1/y5/2/y1; // сравн. с ресурсами игрока
!!VRy6:S0;
!!VRy6&y5<>-1/1:S1;
!!CA0/x1:O?y2;
!!FU29010&y6=1:Py2/2; // отнять у игрока ресурсы за постройку
!!CA0/x1&y6=1:B6/y5; // строим здание, если хватило ресурсов
!!CA0/x1&y6=1:R1; // запрещем постройку др. зданий в этот день

** Ежедневные постройки во всех городах игрока x1
!?FU29017;
!!OW:Wx1/?y2;
!!VRy2:-1;
!!DO29016/0/y2/1:Px1;

!?FU29016;
!!OW:Wx1/x16/?y3;
!!FU29015:Py3;

** Проверка, построил ли город с номером x1 строение x2
** Причем считается, что строение x2 построено также если
** присутствует хотя бы одно из строений x2, x3, x4, x5, x6.
** Если построил, то устанавливается флаг 1
** Если не построил, то сбрасывается флаг 1 и в v1 записывается x2
** Пример: Fort построен, если присутствует хотя бы одно
** из строений Fort, Citadel, Castle.
!?FU29018;
!!CA0/x1:B3/x2;
!!CA0/x1&-1/x3<>-1:B3/x3;
!!CA0/x1&-1/x4<>-1:B3/x4;
!!CA0/x1&-1/x5<>-1:B3/x5;
!!CA0/x1&-1/x6<>-1:B3/x6;
!!VRv1&-1:Sx2;

** Пересылка переменных
** v[x1+0]:=x2, v[x1+1]:=x3, v[x1+2]:=x4 v[x1+3]:=x5,
** v[x1+4]:=x6, v[x1+5]:=x7, v[x1+6]:=x8.
!?FU29019;
!!VRy1:Sx1;
!!VRvy1:Sx2;
!!VRy1:+1;
!!VRvy1:Sx3;
!!VRy1:+1;
!!VRvy1:Sx4;
!!VRy1:+1;
!!VRvy1:Sx5;
!!VRy1:+1;
!!VRvy1:Sx6;
!!VRy1:+1;
!!VRvy1:Sx7;
!!VRy1:+1;
!!VRvy1:Sx8;


** Получить (в v1) номер строения, которое город типа Castle с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29020;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5/22; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/30/37; // Guardhouse
!!FU29018&v1=-1:Px1/33/40; // Barracks
!!FU29018&v1=-1:Px1/31/38; // Archers' Tower
!!FU29018&v1=-1:Px1/34/41; // Monastery
!!FU29018&v1=-1:Px1/36/43; // Portal of Glory
!!FU29018&v1=-1:Px1/21; // Stables
!!FU29018&v1=-1:Px1/35/42; // Training Grounds
!!FU29018&v1=-1:Px1/32/18/39/19; // Griffin Tower
!!FU29018&v1=-1:Px1/18/19; // Griffin Bastion
!!FU29018&v1=-1:Px1/43; // Upg. Portal of Glory
!!FU29018&v1=-1:Px1/40; // Upg. Barracks
!!FU29018&v1=-1:Px1/38; // Upg. Archers' Tower
!!FU29018&v1=-1:Px1/42; // Upg. Training Grounds
!!FU29018&v1=-1:Px1/39/19; // Upg. Griffin Tower
!!FU29018&v1=-1:Px1/41; // Upg. Monastery
!!FU29018&v1=-1:Px1/37; // Upg. Guardhouse
!!FU29018&v1=-1:Px1/1/2/3; // Mage Guild level 2
!!FU29018&v1=-1:Px1/2/3; // Mage Guild level 3
!!FU29018&v1=-1:Px1/3; // Mage Guild level 4
!!FU29018&v1=-1/y2>0:Px1/6; // Shipyard
!!FU29018&v1=-1/y2>0:Px1/17; // Lighthouse
!!FU29018&v1=-1:Px1/22; // Brotherhood of the Sword


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Castle.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29030;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=6:Px2/20/0/0/0/0/0/2000; // Shipyard
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/10/0/0/0/2000; // Lighthouse
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Griffin Bastion
!!FU29019&x1=21:Px2/10/0/0/0/0/0/2000; // Stables
!!FU29019&x1=22:Px2/5/0/0/0/0/0/500; // Brotherhood of the Sword
!!FU29019&x1=30:Px2/0/0/10/0/0/0/500; // Guardhouse
!!FU29019&x1=31:Px2/5/0/5/0/0/0/1000; // Archers' Tower
!!FU29019&x1=32:Px2/0/0/5/0/0/0/1000; // Griffin Tower
!!FU29019&x1=33:Px2/0/0/5/0/0/0/1000; // Barracks
!!FU29019&x1=34:Px2/5/2/5/2/2/2/3000; // Monastery
!!FU29019&x1=35:Px2/20/0/0/0/0/0/5000; // Training Grounds
!!FU29019&x1=36:Px2/0/10/0/10/10/10/20000; // Portal of Glory
!!FU29019&x1=37:Px2/0/0/5/0/0/0/1000; // Upg. Guardhouse
!!FU29019&x1=38:Px2/5/0/5/0/0/0/1000; // Upg. Archers' Tower
!!FU29019&x1=39:Px2/0/0/5/0/0/0/1000; // Upg. Griffin Tower
!!FU29019&x1=40:Px2/0/0/5/0/5/0/2000; // Upg. Barracks
!!FU29019&x1=41:Px2/2/2/2/2/2/2/1000; // Upg. Monastery
!!FU29019&x1=42:Px2/10/0/0/0/0/0/3000; // Upg. Training Grounds
!!FU29019&x1=43:Px2/0/10/0/10/10/10/20000; // Upg. Portal of Glory


** Получить (в v1) номер строения, которое город типа Rampart с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29021;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/17/21; // Mystic Pond
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/30/37; // Centaur Stables
!!FU29018&v1=-1:Px1/32/39; // Homestead
!!FU29018&v1=-1:Px1/34/24/41/25; // Dendroid Arches
!!FU29018&v1=-1:Px1/33/40; // Enchanted Spring
!!FU29018&v1=-1:Px1/35/42; // Unicorn Glade
!!FU29018&v1=-1:Px1/31/18/38/19; // Dwarf Cottage
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/36/43; // Dragon Cliffs
!!FU29018&v1=-1:Px1/18/19; // Miner's Guild
!!FU29018&v1=-1:Px1/22; // Treasure
!!FU29018&v1=-1:Px1/24/25; // Dendroid Saplings
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/43; // Upg. Dragon Cliffs
!!FU29018&v1=-1:Px1/42; // Upg. Unicorn Glade
!!FU29018&v1=-1:Px1/39; // Upg. Homestead
!!FU29018&v1=-1:Px1/41/25; // Upg. Dendroid Arches
!!FU29018&v1=-1:Px1/40; // Upg. Enchanted Spring
!!FU29018&v1=-1:Px1/38/19; // Upg. Dwarf Cottage
!!FU29018&v1=-1:Px1/37; // Upg. Centaur Stables
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1:Px1/21; // Fountain of Fortune


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Rampart.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29031;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/2/2/2/2/2/2/2000; // Mystic Pond
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Miner's Guild
!!FU29019&x1=21:Px2/0/0/0/0/10/0/1500; // Fountain of Fortune
!!FU29019&x1=22:Px2/5/0/10/0/0/0/5000; // Treasure
!!FU29019&x1=24:Px2/0/0/0/0/0/0/2000; // Dendroid Saplings
!!FU29019&x1=30:Px2/10/0/0/0/0/0/500; // Centaur Stables
!!FU29019&x1=31:Px2/5/0/0/0/0/0/1000; // Dwarf Cottage
!!FU29019&x1=32:Px2/10/0/0/0/0/0/1500; // Homestead
!!FU29019&x1=33:Px2/0/0/0/0/10/0/2000; // Enchanted Spring
!!FU29019&x1=34:Px2/0/0/0/0/0/0/2500; // Dendroid Arches
!!FU29019&x1=35:Px2/5/0/5/0/0/10/4000; // Unicorn Glade
!!FU29019&x1=36:Px2/0/0/30/0/20/0/10000; // Dragon Cliffs
!!FU29019&x1=37:Px2/5/0/0/0/0/0/1000; // Upg. Centaur Stables
!!FU29019&x1=38:Px2/5/0/0/0/0/0/1000; // Upg. Dwarf Cottage
!!FU29019&x1=39:Px2/10/0/0/0/0/0/1500; // Upg. Homestead
!!FU29019&x1=40:Px2/0/0/0/0/5/0/2000; // Upg. Enchanted Spring
!!FU29019&x1=41:Px2/0/0/0/0/0/0/1500; // Upg. Dendroid Arches
!!FU29019&x1=42:Px2/0/0/0/0/5/0/3000; // Upg. Unicorn Glade
!!FU29019&x1=43:Px2/0/0/30/0/20/0/20000; // Upg. Dragon Cliffs


** Получить (в v1) номер строения, которое город типа Tower с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29022;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/30/37; // Workshop
!!FU29018&v1=-1:Px1/32/39; // Golem Factory
!!FU29018&v1=-1:Px1/31/18/38/19; // Parapet
!!FU29018&v1=-1:Px1/33/40; // Mage Tower
!!FU29018&v1=-1:Px1/35/42; // Golden Pavilion
!!FU29018&v1=-1:Px1/34/41; // Altar of Wishes
!!FU29018&v1=-1:Px1/36/43; // Cloud Temple
!!FU29018&v1=-1:Px1/18/19; // Sculptor's Wings
!!FU29018&v1=-1:Px1/43; // Upg. Cloud Temple
!!FU29018&v1=-1:Px1/42; // Upg. Golden Pavilion
!!FU29018&v1=-1:Px1/41; // Upg. Altar of Wishes
!!FU29018&v1=-1:Px1/39; // Upg. Golem Factory
!!FU29018&v1=-1:Px1/37; // Upg. Workshop
!!FU29018&v1=-1:Px1/38/19; // Upg. Parapet
!!FU29018&v1=-1:Px1/22; // Library
!!FU29018&v1=-1:Px1/40; // Upg. Mage Tower
!!FU29018&v1=-1:Px1/23; // Wall of Knowledge
!!FU29018&v1=-1:Px1/17; // Artifact Merchants
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1:Px1/21; // Lookout Tower


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Tower.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29032;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/0/0/0/0/10000; // Artifact Merchants
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Sculptor's Wings
!!FU29019&x1=21:Px2/5/0/0/0/0/0/1000; // Lookout Tower
!!FU29019&x1=22:Px2/5/5/5/5/5/5/1500; // Library
!!FU29019&x1=23:Px2/5/0/0/0/0/0/1000; // Wall of Knowledge
!!FU29019&x1=30:Px2/5/0/5/0/0/0/300; // Workshop
!!FU29019&x1=31:Px2/0/0/10/0/0/0/1000; // Parapet
!!FU29019&x1=32:Px2/5/0/5/0/0/0/2000; // Golem Factory
!!FU29019&x1=33:Px2/5/5/5/5/5/5/2500; // Mage Tower
!!FU29019&x1=34:Px2/5/0/5/0/6/6/3000; // Altar of Wishes
!!FU29019&x1=35:Px2/5/2/5/2/2/2/4000; // Golden Pavilion
!!FU29019&x1=36:Px2/10/0/10/0/0/10/5000; // Cloud Temple
!!FU29019&x1=37:Px2/0/0/0/0/0/0/1000; // Upg. Workshop
!!FU29019&x1=38:Px2/0/0/5/0/0/0/1500; // Upg. Parapet
!!FU29019&x1=39:Px2/5/5/5/0/0/0/2000; // Upg. Golem Factory
!!FU29019&x1=40:Px2/5/0/0/0/0/0/2000; // Upg. Mage Tower
!!FU29019&x1=41:Px2/5/0/0/0/0/0/2000; // Upg. Altar of Wishes
!!FU29019&x1=42:Px2/0/3/0/3/3/3/3000; // Upg. Golden Pavilion
!!FU29019&x1=43:Px2/5/0/5/0/0/30/25000; // Upg. Cloud Temple


** Получить (в v1) номер строения, которое город типа Inferno с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29023;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/30/18/37/19; // Imp Crucible
!!FU29018&v1=-1:Px1/31/38; // Hall of Sins
!!FU29018&v1=-1:Px1/33/40; // Demon Gate
!!FU29018&v1=-1:Px1/35/42; // Fire Lake
!!FU29018&v1=-1:Px1/34/41; // Hell Hole
!!FU29018&v1=-1:Px1/36/43; // Forsaken Palace
!!FU29018&v1=-1:Px1/32/24/39/25; // Kennels
!!FU29018&v1=-1:Px1/24/25; // Cages
!!FU29018&v1=-1:Px1/18/19; // Birthing Pools
!!FU29018&v1=-1:Px1/43; // Upg. Forsaken Palace
!!FU29018&v1=-1:Px1/42; // Upg. Fire Lake
!!FU29018&v1=-1:Px1/38; // Upg. Hall of Sins
!!FU29018&v1=-1:Px1/40; // Upg. Demon Gate
!!FU29018&v1=-1:Px1/37/19; // Upg. Imp Crucible
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/41; // Upg. Hell Hole
!!FU29018&v1=-1:Px1/39/25; // Upg. Kennels
!!FU29018&v1=-1:Px1/23; // Order of Fire
!!FU29018&v1=-1:Px1/22; // Castle Gate
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1:Px1/21; // Brimstone Storm clouds


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Inferno.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29033;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Birthing Pools
!!FU29019&x1=21:Px2/0/0/0/5/0/0/1000; // Brimstone Storm clouds
!!FU29019&x1=22:Px2/5/0/5/0/0/0/10000; // Castle Gate
!!FU29019&x1=23:Px2/5/0/0/0/0/0/1000; // Order of Fire
!!FU29019&x1=24:Px2/0/0/0/0/0/0/1000; // Cages
!!FU29019&x1=30:Px2/5/0/5/0/0/0/300; // Imp Crucible
!!FU29019&x1=31:Px2/0/0/5/0/0/0/1000; // Hall of Sins
!!FU29019&x1=32:Px2/10/0/0/0/0/0/1500; // Kennels
!!FU29019&x1=33:Px2/5/0/5/0/0/0/2000; // Demon Gate
!!FU29019&x1=34:Px2/0/0/0/0/0/0/3000; // Hell Hole
!!FU29019&x1=35:Px2/0/3/10/3/0/3/4000; // Fire Lake
!!FU29019&x1=36:Px2/10/20/10/0/0/0/15000; // Forsaken Palace
!!FU29019&x1=37:Px2/0/0/0/0/0/0/1000; // Upg. Imp Crucible
!!FU29019&x1=38:Px2/0/5/0/0/0/0/1000; // Upg. Hall of Sins
!!FU29019&x1=39:Px2/0/0/0/5/0/0/1500; // Upg. Kennels
!!FU29019&x1=40:Px2/5/0/5/0/0/0/2000; // Upg. Demon Gate
!!FU29019&x1=41:Px2/0/5/0/5/0/0/3000; // Upg. Hell Hole
!!FU29019&x1=42:Px2/0/5/5/5/0/5/3000; // Upg. Fire Lake
!!FU29019&x1=43:Px2/5/20/5/0/0/0/20000; // Upg. Forsaken Palace


** Получить (в v1) номер строения, которое город типа Necropolis с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29024;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/21; // Necromancy amplifier
!!FU29018&v1=-1:Px1/30/18/37/19; // Cursed Temple
!!FU29018&v1=-1:Px1/31/38; // Graveyard
!!FU29018&v1=-1:Px1/34/41; // Mausoleum
!!FU29018&v1=-1:Px1/33/40; // Estate
!!FU29018&v1=-1:Px1/35/42; // Hall of Darkness
!!FU29018&v1=-1:Px1/32/39; // Tomb of Souls
!!FU29018&v1=-1:Px1/36/43; // Dragon Vault
!!FU29018&v1=-1:Px1/22; // Skeleton Transformer
!!FU29018&v1=-1:Px1/18/19; // Unearthed Graves
!!FU29018&v1=-1:Px1/43; // Upg. Dragon Vault
!!FU29018&v1=-1:Px1/40; // Upg. Estate
!!FU29018&v1=-1:Px1/42; // Upg. Hall of Darkness
!!FU29018&v1=-1:Px1/41; // Upg. Mausoleum
!!FU29018&v1=-1:Px1/39; // Upg. Tomb of Souls
!!FU29018&v1=-1:Px1/37/19; // Upg. Cursed Temple
!!FU29018&v1=-1:Px1/38; // Upg. Graveyard
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1:Px1/17; // Cover of Darkness
!!FU29018&v1=-1/y2>0:Px1/6; // Shipyard


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Necropolis.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29034;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=6:Px2/20/0/0/0/0/0/2000; // Shipyard
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/0/0/0/0/1000; // Cover of Darkness
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Unearthed Graves
!!FU29019&x1=21:Px2/0/0/0/0/0/0/1000; // Necromancy amplifier
!!FU29019&x1=22:Px2/0/0/0/0/0/0/1000; // Skeleton Transformer
!!FU29019&x1=30:Px2/5/0/5/0/0/0/400; // Cursed Temple
!!FU29019&x1=31:Px2/0/0/5/0/0/0/1000; // Graveyard
!!FU29019&x1=32:Px2/5/0/5/0/0/0/1500; // Tomb of Souls
!!FU29019&x1=33:Px2/5/0/5/0/0/0/2000; // Estate
!!FU29019&x1=34:Px2/10/0/0/10/0/0/2000; // Mausoleum
!!FU29019&x1=35:Px2/10/0/10/0/0/0/6000; // Hall of Darkness
!!FU29019&x1=36:Px2/5/5/5/5/5/5/10000; // Dragon Vault
!!FU29019&x1=37:Px2/5/0/5/0/0/0/1000; // Upg. Cursed Temple
!!FU29019&x1=38:Px2/5/0/5/0/0/0/1000; // Upg. Graveyard
!!FU29019&x1=39:Px2/0/5/0/0/0/0/1500; // Upg. Tomb of Souls
!!FU29019&x1=40:Px2/5/0/0/0/10/10/2000; // Upg. Estate
!!FU29019&x1=41:Px2/0/0/5/5/0/0/2000; // Upg. Mausoleum
!!FU29019&x1=42:Px2/5/2/5/2/2/2/3000; // Upg. Hall of Darkness
!!FU29019&x1=43:Px2/5/20/5/0/0/0/15000; // Upg. Dragon Vault


** Получить (в v1) номер строения, которое город типа Dungeon с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29025;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/30/18/37/19; // Warren
!!FU29018&v1=-1:Px1/32/39; // Pillar of Eyes
!!FU29018&v1=-1:Px1/31/38; // Harpy Loft
!!FU29018&v1=-1:Px1/33/40; // Stilled Voices
!!FU29018&v1=-1:Px1/34/41; // Labyrinth
!!FU29018&v1=-1:Px1/35/42; // Manticore Lair
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/36/43; // Dragon Cave
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/43; // Upg. Dragon Cave
!!FU29018&v1=-1:Px1/42; // Upg. Manticore Lair
!!FU29018&v1=-1:Px1/38; // Upg. Harpy Loft
!!FU29018&v1=-1:Px1/41; // Upg. Labyrinth
!!FU29018&v1=-1:Px1/40; // Upg. Stilled Voices
!!FU29018&v1=-1:Px1/39; // Upg. Pillar of Eyes
!!FU29018&v1=-1:Px1/37/19; // Upg. Warren
!!FU29018&v1=-1:Px1/18/19; // Mushroom Rings
!!FU29018&v1=-1:Px1/21; // Mana Vortex
!!FU29018&v1=-1:Px1/22; // Portal of Summoning
!!FU29018&v1=-1:Px1/17; // Artifact Merchants
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1:Px1/23; // Battle Scholar Academy


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Dungeon.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29035;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/0/0/0/0/10000; // Artifact Merchants
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Mushroom Rings
!!FU29019&x1=21:Px2/0/0/0/0/0/0/1000; // Mana Vortex
!!FU29019&x1=22:Px2/0/0/5/0/0/0/2500; // Portal of Summoning
!!FU29019&x1=23:Px2/0/0/0/0/0/0/1000; // Battle Scholar Academy
!!FU29019&x1=30:Px2/10/0/0/0/0/0/400; // Warren
!!FU29019&x1=31:Px2/0/0/0/0/0/0/1000; // Harpy Loft
!!FU29019&x1=32:Px2/1/1/1/1/1/1/1000; // Pillar of Eyes
!!FU29019&x1=33:Px2/5/0/10/0/0/0/2000; // Stilled Voices
!!FU29019&x1=34:Px2/0/10/0/0/0/10/4000; // Labyrinth
!!FU29019&x1=35:Px2/5/5/5/5/0/0/5000; // Manticore Lair
!!FU29019&x1=36:Px2/15/0/15/20/0/0/15000; // Dragon Cave
!!FU29019&x1=37:Px2/5/0/0/0/0/0/1000; // Upg. Warren
!!FU29019&x1=38:Px2/0/0/0/2/2/0/1000; // Upg. Harpy Loft
!!FU29019&x1=39:Px2/1/1/1/1/1/1/1000; // Upg. Pillar of Eyes
!!FU29019&x1=40:Px2/5/0/0/0/0/0/1500; // Upg. Stilled Voices
!!FU29019&x1=41:Px2/0/0/5/0/0/5/3000; // Upg. Labyrinth
!!FU29019&x1=42:Px2/5/5/5/5/0/0/3000; // Upg. Manticore Lair
!!FU29019&x1=43:Px2/15/0/15/20/0/0/15000; // Upg. Dragon Cave


** Получить (в v1) номер строения, которое город типа Stronghold с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29026;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/0/1/2; // Mage Guild level 1
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/30/18/37/19; // Goblin Barracks
!!FU29018&v1=-1:Px1/31/38; // Wolf Pen
!!FU29018&v1=-1:Px1/34/41; // Cliff Nest
!!FU29018&v1=-1:Px1/36/43; // Behemoth Lair
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/32/39; // Orc Tower
!!FU29018&v1=-1:Px1/33/40; // Ogre Fort
!!FU29018&v1=-1:Px1/35/42; // Cyclops Cave
!!FU29018&v1=-1:Px1/43; // Upg. Behemoth Lair
!!FU29018&v1=-1:Px1/41; // Upg. Cliff Nest
!!FU29018&v1=-1:Px1/42; // Upg. Cyclops Cave
!!FU29018&v1=-1:Px1/40; // Upg. Ogre Fort
!!FU29018&v1=-1:Px1/39; // Upg. Orc Tower
!!FU29018&v1=-1:Px1/37/19; // Upg. Goblin Barracks
!!FU29018&v1=-1:Px1/38; // Upg. Wolf Pen
!!FU29018&v1=-1:Px1/18/19; // Mess Hall
!!FU29018&v1=-1:Px1/22; // Ballista Yard
!!FU29018&v1=-1:Px1/23; // Hall of Valhala
!!FU29018&v1=-1:Px1/1/2; // Mage Guild level 2
!!FU29018&v1=-1:Px1/2; // Mage Guild level 3
!!FU29018&v1=-1:Px1/17; // Escape Tunnel
!!FU29018&v1=-1:Px1/21; // Freelancer's Guild


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Stronghold.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29036;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/5/0/5/0/0/0/2000; // Escape Tunnel
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Mess Hall
!!FU29019&x1=21:Px2/0/0/0/0/0/0/1000; // Freelancer's Guild
!!FU29019&x1=22:Px2/5/0/0/0/0/0/1000; // Ballista Yard
!!FU29019&x1=23:Px2/0/0/0/0/0/0/1000; // Hall of Valhala
!!FU29019&x1=30:Px2/5/0/5/0/0/0/200; // Goblin Barracks
!!FU29019&x1=31:Px2/10/0/5/0/0/0/1000; // Wolf Pen
!!FU29019&x1=32:Px2/5/0/5/0/0/0/1000; // Orc Tower
!!FU29019&x1=33:Px2/20/0/0/0/0/0/2000; // Ogre Fort
!!FU29019&x1=34:Px2/0/0/10/0/0/0/2500; // Cliff Nest
!!FU29019&x1=35:Px2/0/0/20/0/20/0/3500; // Cyclops Cave
!!FU29019&x1=36:Px2/10/0/10/0/10/0/10000; // Behemoth Lair
!!FU29019&x1=37:Px2/5/0/5/0/0/0/1000; // Upg. Goblin Barracks
!!FU29019&x1=38:Px2/5/0/5/0/0/0/1000; // Upg. Wolf Pen
!!FU29019&x1=39:Px2/2/0/2/0/0/0/1000; // Upg. Orc Tower
!!FU29019&x1=40:Px2/5/0/5/0/0/5/2000; // Upg. Ogre Fort
!!FU29019&x1=41:Px2/5/0/5/0/0/0/2000; // Upg. Cliff Nest
!!FU29019&x1=42:Px2/5/0/5/0/0/0/3000; // Upg. Cyclops Cave
!!FU29019&x1=43:Px2/10/0/10/0/20/0/15000; // Upg. Behemoth Lair


** Получить (в v1) номер строения, которое город типа Fortress с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29027;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/0/1/2; // Mage Guild level 1
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/30/18/37/19; // Gnoll Hut
!!FU29018&v1=-1:Px1/31/38; // Lizard Den
!!FU29018&v1=-1:Px1/35/42; // Wyvern Nest
!!FU29018&v1=-1:Px1/32/39; // Serpent Fly Hive
!!FU29018&v1=-1:Px1/33/40; // Basilisk Pit
!!FU29018&v1=-1:Px1/36/43; // Hydra Pond
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/34/41; // Gorgon Lair
!!FU29018&v1=-1:Px1/18/19; // Captain's Quarters
!!FU29018&v1=-1:Px1/39; // Upg. Serpent Fly Hive
!!FU29018&v1=-1:Px1/41; // Upg. Gorgon Lair
!!FU29018&v1=-1:Px1/40; // Upg. Basilisk Pit
!!FU29018&v1=-1:Px1/43; // Upg. Hydra Pond
!!FU29018&v1=-1:Px1/42; // Upg. Wyvern Nest
!!FU29018&v1=-1:Px1/38; // Upg. Lizard Den
!!FU29018&v1=-1:Px1/37/19; // Upg. Gnoll Hut
!!FU29018&v1=-1:Px1/21/22; // Glyphs of Fear
!!FU29018&v1=-1:Px1/17; // Cage of Warlords
!!FU29018&v1=-1:Px1/22; // Blood Obelisk
!!FU29018&v1=-1/y2>0:Px1/6; // Shipyard
!!FU29018&v1=-1:Px1/1/2; // Mage Guild level 2
!!FU29018&v1=-1:Px1/2; // Mage Guild level 3


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Fortress.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29037;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=6:Px2/20/0/0/0/0/0/2000; // Shipyard
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/0/0/0/0/1000; // Cage of Warlords
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Captain's Quarters
!!FU29019&x1=21:Px2/0/0/0/0/0/0/1000; // Glyphs of Fear
!!FU29019&x1=22:Px2/0/0/0/0/0/0/1000; // Blood Obelisk
!!FU29019&x1=30:Px2/10/0/0/0/0/0/400; // Gnoll Hut
!!FU29019&x1=31:Px2/5/0/0/0/0/0/1000; // Lizard Den
!!FU29019&x1=32:Px2/5/2/0/2/0/0/1000; // Serpent Fly Hive
!!FU29019&x1=33:Px2/5/10/0/0/0/0/2000; // Basilisk Pit
!!FU29019&x1=34:Px2/10/5/10/5/0/0/2500; // Gorgon Lair
!!FU29019&x1=35:Px2/15/0/0/0/0/0/3500; // Wyvern Nest
!!FU29019&x1=36:Px2/10/0/10/10/0/0/10000; // Hydra Pond
!!FU29019&x1=37:Px2/10/0/0/0/0/0/1000; // Upg. Gnoll Hut
!!FU29019&x1=38:Px2/5/0/0/0/0/0/1000; // Upg. Lizard Den
!!FU29019&x1=39:Px2/0/2/0/2/0/0/1000; // Upg. Serpent Fly Hive
!!FU29019&x1=40:Px2/5/0/5/0/0/0/2000; // Upg. Basilisk Pit
!!FU29019&x1=41:Px2/5/0/5/0/0/0/2000; // Upg. Gorgon Lair
!!FU29019&x1=42:Px2/10/10/0/0/0/0/3000; // Upg. Wyvern Nest
!!FU29019&x1=43:Px2/10/0/10/20/0/0/15000; // Upg. Hydra Pond


** Получить (в v1) номер строения, которое город типа Conflux с
** номером x1 = 0..47 может сейчас строить,
** если число построек Capitol у данного игрока равно x2.
** а число клеток с водой поблизости равно x3.
** Если город полностью отстроен, в v1 будет -1.
!?FU29028;
!!VRy1:Sx2; // число капитолиев у владельца этого города
!!VRy2:Sx3; // число клеток с водой рядом с городом
!!VRv1:S-1;
!!VRx3:S-1; // не определенные параметры наследуются (?)
!!VRx4:S-1;
!!VRx5:S-1;
!!VRx6:S-1;
!!FU29018&v1=-1:Px1/5; // Tavern
!!FU29018&v1=-1:Px1/11/12/13; // Town Hall
!!FU29018&v1=-1:Px1/0/1/2/3/4; // Mage Guild level 1
!!FU29018&v1=-1:Px1/14; // Marketplace
!!FU29018&v1=-1:Px1/16; // Blacksmith
!!FU29018&v1=-1:Px1/12/13; // City Hall
!!FU29018&v1=-1:Px1/7/8/9; // Fort
!!FU29018&v1=-1:Px1/8/9; // Citadel
!!FU29018&v1=-1:Px1/30/18/37/19; // Magic Lantern
!!FU29018&v1=-1:Px1/32/39; // Altar of Water
!!FU29018&v1=-1:Px1/31/38; // Altar of Air
!!FU29018&v1=-1:Px1/33/40; // Altar of Fire
!!FU29018&v1=-1:Px1/34/41; // Altar of Earth
!!FU29018&v1=-1:Px1/9; // Castle
!!FU29018&v1=-1/y1=0:Px1/13; // Capitol
!!FU29018&v1=-1:Px1/15; // Resource Silo
!!FU29018&v1=-1:Px1/35; // Altar of Thought
!!FU29018&v1=-1:Px1/36; // Pyre
!!FU29018&v1=-1:Px1/18/19; // Garden of Life
!!FU29018&v1=-1:Px1/21; // Magic University
!!FU29018&v1=-1:Px1/43; // Upg. Pyre
!!FU29018&v1=-1:Px1/39; // Upg. Altar of Water
!!FU29018&v1=-1:Px1/38; // Upg. Altar of Air
!!FU29018&v1=-1:Px1/40; // Upg. Altar of Fire
!!FU29018&v1=-1:Px1/41; // Upg. Altar of Earth
!!FU29018&v1=-1:Px1/37/19; // Upg. Magic Lantern
!!FU29018&v1=-1:Px1/17; // Artifact Merchants
!!FU29018&v1=-1:Px1/1/2/3/4; // Mage Guild level 2
!!FU29018&v1=-1:Px1/42; // Upg. Altar of Thought
!!FU29018&v1=-1:Px1/2/3/4; // Mage Guild level 3
!!FU29018&v1=-1:Px1/3/4; // Mage Guild level 4
!!FU29018&v1=-1:Px1/4; // Mage Guild level 5
!!FU29018&v1=-1/y2>0:Px1/6; // Shipyard


** Получить стоимость строения с номером x1 (0..43)
** в городе типа Conflux.
** Стоимость записывается в переменные
** v[x2+0] --- wood, v[x2+1] --- mercury, v[x2+2] --- ore
** v[x2+3] --- sulfur, v[x2+4] --- crystal, v[x2+5] --- gems
** v[x2+6] --- gold
!?FU29038;
!!FU29019&x1=0:Px2/5/0/5/0/0/0/2000; // Mage Guild level 1
!!FU29019&x1=1:Px2/5/4/5/4/4/4/1000; // Mage Guild level 2
!!FU29019&x1=2:Px2/5/6/5/6/6/6/1000; // Mage Guild level 3
!!FU29019&x1=3:Px2/5/8/5/8/8/8/1000; // Mage Guild level 4
!!FU29019&x1=4:Px2/5/10/5/10/10/10/1000; // Mage Guild level 5
!!FU29019&x1=5:Px2/5/0/0/0/0/0/500; // Tavern
!!FU29019&x1=6:Px2/20/0/0/0/0/0/2000; // Shipyard
!!FU29019&x1=7:Px2/20/0/20/0/0/0/5000; // Fort
!!FU29019&x1=8:Px2/0/0/5/0/0/0/2500; // Citadel
!!FU29019&x1=9:Px2/10/0/10/0/0/0/5000; // Castle
!!FU29019&x1=11:Px2/0/0/0/0/0/0/2500; // Town Hall
!!FU29019&x1=12:Px2/0/0/0/0/0/0/5000; // City Hall
!!FU29019&x1=13:Px2/0/0/0/0/0/0/10000; // Capitol
!!FU29019&x1=14:Px2/5/0/0/0/0/0/500; // Marketplace
!!FU29019&x1=15:Px2/0/0/5/0/0/0/5000; // Resource Silo
!!FU29019&x1=16:Px2/5/0/0/0/0/0/1000; // Blacksmith
!!FU29019&x1=17:Px2/0/0/0/0/0/0/10000; // Artifact Merchants
!!FU29019&x1=18:Px2/0/0/0/0/0/0/1000; // Garden of Life
!!FU29019&x1=21:Px2/10/0/10/0/0/0/5000; // Magic University
!!FU29019&x1=30:Px2/5/0/5/0/0/0/300; // Magic Lantern
!!FU29019&x1=31:Px2/0/0/5/0/0/0/1500; // Altar of Air
!!FU29019&x1=32:Px2/0/0/5/0/0/0/1500; // Altar of Water
!!FU29019&x1=33:Px2/5/0/5/0/0/0/2000; // Altar of Fire
!!FU29019&x1=34:Px2/0/0/10/0/0/0/2000; // Altar of Earth
!!FU29019&x1=35:Px2/5/2/5/2/2/2/3000; // Altar of Thought
!!FU29019&x1=36:Px2/10/10/10/0/0/0/10000; // Pyre
!!FU29019&x1=37:Px2/0/0/0/0/0/0/1000; // Upg. Workshop
!!FU29019&x1=38:Px2/2/2/0/0/0/2/1500; // Upg. Altar of Air
!!FU29019&x1=39:Px2/0/5/5/0/0/0/2000; // Upg. Altar of Water
!!FU29019&x1=40:Px2/0/5/5/0/0/0/2000; // Upg. Altar of Fire
!!FU29019&x1=41:Px2/0/0/0/5/0/0/1000; // Upg. Altar of Earth
!!FU29019&x1=42:Px2/0/3/0/3/3/3/3000; // Upg. Altar of Thought
!!FU29019&x1=43:Px2/10/20/10/0/0/0/15000; // Upg. Pyre



** Активизация архитектора, если есть опция вогификации
!#UN:P90/?y1;
!#TM29&y1=1:S1/999/1/255;
!#FU29006&y1=1:P1;

** Постройки в городах текущего игрока
!?TM29;
!!OW:C?y1;
!!FU29017:Py1;
!!UN:R1;

** Включение/отключение режима автозастройки
!?CM1;
!!CM:F?y1 I?y2; // правый клик по Village / Town / City Hall
!!CA-1:U?y3;
!!FU29012&y1=512/y2>=10/y2<=13:Py3; // вывод меню
!!CM&y1=512/y2>=10/y2<=13/1:R0;
!!UN:R4;

** Если разрушенный город строится заново,
** в нем появляется архитектор.
!?OB98;
!!CAv998/v999/v1000:U?y1;
!!VRy2:S0; // определяем, построен ли в городе Village/Town/City Hall
!!CA0/y1:B3/10;
!!VRy2&1:S1;
!!CA0/y1:B3/11;
!!VRy2&1:S1;
!!CA0/y1:B3/12;
!!VRy2&1:S1;
!!CA0/y1:B3/13;
!!VRy2&1:S1;
!!FU29001&y2=0:Py1/1;