Threaded Mode | Linear Mode

Bes · 06.08.2020 20:22

(01.08.2020 03:28)Berserker Wrote: Да и плагин такой написать на ЕРМ — десяток строк.

вот знаешь ты как меня подковырнуть, пришлось эти десятки строк себе придумывать (и красоту ещё себе отдельно вылепливать, а это лишнее время, я ж без неё не могу)

ZVSE
; нажав [TAB], будет появляться диалог ввода, где можно писать ЕРМ-команды и выполнять их после ввода
!?FU(OnKeyPressed)&x1=9;
!!VRx2:S1; lock standart action [TAB]
!!VRz1:S^%T(cce.hint)^; текст над областью ввода (временно в z1)
!!FU(ERM_input):P1/?y1; вызываем диалог ввода
!!VRx2&y1=-2:S0; unlock standart action [TAB]
!?FU(ERM_input);
; x1 - EnableEscButton: BOOLEAN
; x2 - контроль кнопки Отмена
!!VRz-1:S^%T(cce.caption)^;
!!VRz-2:S^^; заглушка для остальных строк wog-диалога
!!IF:D9/-1/1/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2/-2;
!!IF:F9/-2/-2/-2/-2/x1;
!!IF:E1/9; вывод диалога id=9, v1 хранит выбор в диалоге
; Текст с окна ввода автоматом попадает в z1
!!VRx2&v1=-1:S-2;
!!FU&v1=-1:E; нажата кнопка Отмена
!!SN:F^ExecErmCmd^/z1; вызов ф-ции исполнения ЕРМ-кода
; далее введёные команды дублируем в ЛОГ игры
!!SN:Kz1/?y1; получить длину строки
!!SN&y1=0:G[в лог]; прыжок через весь код далее, если ничего не ввели или только один символ
; <-- блок для переноса ерм-кода, если было введено более одного ресивера
!!VRz-3:S^;^; искомый символ это ;
!!VRy1&y1>0:-1; учитываем что нумерация символов идёт с нуля
!!re i/0/y1:; цикл поиска символа из z-3
!!SN:Kz1/i/?z8; получение символа по порядку из z1
!!VRz8:M1/z8/0/1; сохранить только первый символ (БАГ: SN:K даёт 2 символа)
!!co&z8<>z-3:; завершить текущий круг цикла (символа ; пока нет)
!!VRz9:S^
^; записать в z9 перенос строки
!!SN:Kz1/i/z9; заменяем символ ; (его позиция сейчас в счётчике цикла) на перенос строки
!!en:;
; --> end
[:в лог]
!!IF:L1; показать z1 в ЛОГе, что вводили

Учитывая ограничение в 30 символов (на сегодня), ~~более двух команд подрят не написать, так что перенос сделал для одного раза~~. Ок, убрал ограничитель, учитывая, что, по-правде, можно и три, но это скорее из разряда тестинга диалога, чем из практической плоскости. Короче сам себя переубедил
Хотел было ещё и !! чтоб в логе видны были, да хрен с ними подумал, это уже перебор будет с перфекционизмом

Threaded Mode \| Linear Mode ERM-консоль » chalk.dll
Author	Message