Threaded Mode | Linear Mode

Valery · 28.08.2015 20:21

A script from Hawaiing, gives multiple melee attacks. Need hooker plugin.

!?BG0;[example]
!!SN:W^007.AttackA.Times^/0;[reset flag]
!!BG:A?y1 N?y2 E?y3;
!!FU|y1<>6:E;
!!BMy2:T?y4;
!!SN&y4=132:W^007.AttackA.Times^/2;[AzureDragon has 2 extra_attack_times]
********************HOOK_CODE******************************
!?BA0&1000;
!!SN:L^EraPlugins\erm_hooker.era^/?y1 Ay1/^SetHook^/?y2;
!!SN:Ey2/1/7381311/101310;
!?BA1&1000;
!!SN:L^EraPlugins\erm_hooker.era^/?y1 Ay1/^UnsetHook^/?y2;
!!SN:Ey2/1/7381311;
!?FU101310;
!!SN:X?y1/1;[edi]
!!SN:W^007.AttackA.Times^/?y30;
!!SN:W^007.AttackA.Times^/0;
!!FU&y30<1:E;
!!UN:Cy1/4/?y10;[y10=A_STACK]
!!VRy2:Sy1+8;
!!UN:Cy2/4/?y3; [y3=ebp]
!!VRy4:Sy3+8; [ebp+8]
!!UN:Cy4/4/?y5; y5=[ebp+08]
!!VRy6:Sy1+4;
!!UN:Cy6/4/?y20;[y20=D_STACK]10#
!!VRy11:Sy10+52; 11#
!!VRy12:Sy10+76;
!!VRy13:Sy10+656;
!!VRy14:Sy10+688;
!!VRy15:Sy10+704;
!!UN:Cy11/4/?y31;
!!UN:Cy12/4/?y32;
!!UN:Cy13/4/?y33;
!!UN:Cy14/4/?y34;
!!UN:Cy15/4/?y35;
!!VRy21:Sy20+52;
!!VRy22:Sy20+76;
!!UN:Cy21/4/?y41;
!!UN:Cy22/4/?y42;
!!FU|y31<0/y32<1/y41<0/y42<1/y33>0/y34>0/y35>0:E;
!!SN:E4461360/2/y10/y20/y5;
!!VRy30:-1;
!!SN&y30>0:G11;

Valery · 29.08.2015 14:33

From Hawaiing too, multiple shoot + multiple melee

ZVSE
*Extra <metee attack> or <shoot> for stack.
*need <erm_hooker.era>
*<SN:W^007.AttackA.Times^> flag holds the attack times.
*<SN:W^007.ShootA.Times^> flag holds the shoot times(not for 149#Tower)(and 146# is different from other shooters)
********************PUT YOUR CODE HERE******************************
!?BG0;[example]
!!SN:W^007.AttackA.Times^/0;[reset flag](or reset it at BG1)
!!SN:W^007.ShootA.Times^/0;[reset flag](or reset it at BG1)
!!BG:A?y1 N?y2 E?y3;
!!BMy2:T?y4;
!!if&y1=6:;
!!SN&y4=132:W^007.AttackA.Times^/2;[AzureDragon has 2 extra_attack_times]
!!en:;
!!if&y1=7:;
!!SN&y4=196:W^007.ShootA.Times^/2;[Dracolich has 2 extra_shoot_times]
!!en:;
********************HOOK_CODE******************************
!?BA0&1000;
!!SN:L^EraPlugins\erm_hooker.era^/?y1 Ay1/^SetHook^/?y2;
!!SN:Ey2/1/7381311/101310; [hook at <after metee_attack>]
!!SN:Ey2/1/4456346/101311; [hook at <after shoot>]
!?BA1&1000;
!!SN:L^EraPlugins\erm_hooker.era^/?y1 Ay1/^UnsetHook^/?y2;
!!SN:Ey2/1/7381311;
!!SN:Ey2/1/4456346;
!?FU101310;[extra_metee_attack]
!!SN:X?y1/1;[edi]
!!SN:W^007.AttackA.Times^/?y30;
!!SN:W^007.AttackA.Times^/0;
!!FU&y30<1:E;
!!UN:Cy1/4/?y10;[y10=A_STACK]
!!VRy2:Sy1+8;
!!UN:Cy2/4/?y3; [y3=ebp]
!!VRy4:Sy3+8; [ebp+8]
!!UN:Cy4/4/?y5; y5=[ebp+08]
!!VRy6:Sy1+4;
!!UN:Cy6/4/?y20;[y20=D_STACK]10#
!!VRy11:Sy10+52; 11#
!!VRy12:Sy10+76;
!!VRy13:Sy10+656;
!!VRy14:Sy10+688;
!!VRy15:Sy10+704;
!!VRy21:Sy20+52;
!!VRy22:Sy20+76;
!!UN:Cy11/4/?y31; 18#
!!UN:Cy12/4/?y32;
!!UN:Cy13/4/?y33;
!!UN:Cy14/4/?y34;
!!UN:Cy15/4/?y35;
!!UN:Cy21/4/?y41;
!!UN:Cy22/4/?y42;
!!FU|y31<0/y32<1/y41<0/y42<1/y33>0/y34>0/y35>0:E;
!!SN:E4461360/2/y10/y20/y5;
!!VRy30:-1;
!!SN&y30>0:G18;
!?FU101311;[extra_shoot]
!!SN:X?y1/1;[edi]
!!SN:W^007.ShootA.Times^/?y30;
!!SN:W^007.ShootA.Times^/0;
!!FU&y30<1:E;
!!VRy2:Sy1+4; esi
!!UN:Cy2/4/?y10;[A_STACK]
!!VRy3:Sy1+16; ebx
!!UN:Cy3/4/?y20;[D_STACK]
!!VRy11:Sy10+52;[8#]
!!VRy12:Sy10+76;
!!VRy13:Sy10+656;
!!VRy14:Sy10+688;
!!VRy15:Sy10+704;
!!VRy16:Sy10+216;
!!VRy21:Sy20+52;
!!VRy22:Sy20+76;
!!UN:Cy11/4/?y31;[BM:T]16#
!!UN:Cy12/4/?y32;[BM:N]
!!UN:Cy13/4/?y33;[BM:G62]
!!UN:Cy14/4/?y34;[BM:G70]
!!UN:Cy15/4/?y35;[BM:G74]
!!UN:Cy16/4/?y36;[BM:U3]
!!UN:Cy21/4/?y41;[BM:T]
!!UN:Cy22/4/?y42;[BM:N]
!!FU|y31<0/y32<1/y41<0/y42<1/y33>0/y34>0/y35>0/y36<1:E;
!!SN:E4453920/2/y10/y20;
!!VRy30:-1;
!!SN&y30>0:G16;

Valery · 09.11.2015 22:10

Change town buildings name and description, by hawaiing

!?PI;
!!VRz998:S^Super Star^;
!!VRz999:S^create by Hawaiing^;
!!FU222222:P0/37/0/998;[castle upgraded dwelling 1]
!!FU222222:P0/37/1/999;[description]
!_!FU222222:P0/37/1/100000;[ERT100000]
!?GM0;
...
!?FU222222;
*Change the building's name&description , ByHawaiing
*x1=TownType(0-8)
*x2=building_ID(0-43)
*x3=0 - building name,1- building description
*x4=z-var or ert index(1-1000,>=100000)
!!VRy10:S0;
!!VRy11:S0;
!!VRy12:S0;
!!if&x2<17:;[ID=0-16]
!!VRy10&x2=15:Sx1*44+6968420;[15=Resource Silo]
!!VRy11&x2=15:Sx1*44+6977692;
!!VRy10&x2<>15:Sx2*4+6972748;
!!VRy11&x2<>15:Sx2*4+6979212;
!!en:;
!!if&x2>=17/x2<30:;[ID=17-29]
!!VRy10:Sx1*11+x2*4+6968312;
!!VRy11:Sx1*11+x2*4+6977584;
!!en:;
!!if&x2>=30:;[ID=30-43]dwelling
!!VRy10:Sx1*14+x2*4+6972056;
!!VRy11:Sx1*14+x2*4+6973876;
!!en:;
!!VRy12&x4>0/x4<1001:Sx4*512+9597416;[Z-var]
!!if&x4>=100000:;[ERT]
!!SN:E7824928/1/x4;
!!VRy12:Sv1;
!!en:;
!!FU|y10=0/y11=0/y12=0:E;
!!UN&x3=0:Cy10/4/y12;
!!UN&x3=1:Cy11/4/y12;

Changing buildings cost, by Hawaiing:

!!FU101404:P0/30/0/?y1/?y2/?y3/?y4/?y5/?y6/?y7;[get <castle dwelling 1> cost]
y1-y7 sould be 0/0/10/0/0/0/500, see <Building.txt> pikeman.
!!FU101404:P0/30/1/0/0/5/0/0/0/5000;[set pikeman cost]
!?FU101404;
**get/set town buiding cost , Hawaiing
*x1=TownType 0-8
*x2=BuidingID 0-43
*x3=0 get value, 1 set value
*x4-x10=Resource value=Wood/Mercury/Ore/Sulfur/Crystal/Gems/Gold
!!FU|x1<0/x1>8/x2<0/x2>43:E;
!!FU&x2>25/x2<30:E;
!!if&x2>=0/x2<=16:;
!!VRy1:Sx2*28+6979936;
!!en:;
!!if&x2>=17/x2<=25:;
!!VRy2:Sx2-17*28;
!!VRy1:Sx1*252+y2+6980420;
!!en:;
!!if&x2>=30/x2<=43:;
!!VRy2:Sx2-30*28;
!!VRy1:Sx1*392+y2+6985856;
!!en:;
!!VRy3:Sy1; !!VRy4:Sy1+4;
!!VRy5:Sy1+8; !!VRy6:Sy1+12;
!!VRy7:Sy1+16; !!VRy8:Sy1+20;
!!VRy9:Sy1+24;
!!if&x3=0:;[get]
!!UN:Cy3/4/?x4 Cy4/4/?x5 Cy5/4/?x6 Cy6/4/?x7;
!!UN:Cy7/4/?x8 Cy8/4/?x9 Cy9/4/?x10;
!!el:;[set]
!!UN:Cy3/4/x4 Cy4/4/x5 Cy5/4/x6 Cy6/4/x7;
!!UN:Cy7/4/x8 Cy8/4/x9 Cy9/4/x10;
!!en:;

Threaded Mode \| Linear Mode Updating the erm help, please contribute
Author	Message