Wake of Gods Forum | Форум Во Имя Богов

**используются переменные:
** v7146-7148
** z49
** FU494 FU495

** w99 - статус для рытья колодцев. 0 - ничего, -1 - уже рыли
** 1 и более - номер дня начала стр-ва, используется скриптом



**START** **Бонусы за нейтралов** **START**

**1/3 опыта без битвы (даже при присоединении!)
**сделал так не потому, что лень или не получается проверить.
**в какой-нибудь версии на дипломатию и побег будут разные расценки

**Бонус золота после битвы (40% * level * count * hp)
**если существо слабее 3-го, считается 3-й уровень
**если золота получается меньше 600 то удваивается
!#VRv7146:S0; !#VRv7147:S0; !#VRv7148:S0;
!#VRz49:S^{Засыпанный} колодец^;

!?OB54;
!!OB998:U?i;
!!MO998:G?j;
!!MA:Pi/?k;
!!MA:Li/?l;
!!VRl:+1;
!!VRl&l<3:S3;
!!VRv7146:Sj *k *l *2 :5;
!!VRv7146&v7146<600: *2;
!!VRv7147:Sj *65536 +i *-1;
!!VRv7148:Sj *k :3; количество опыта

!?BA1&v7147<0;
!!VRv7147:*-1;

!$OB54&v7147<0;
!!VRv7146:S0;
!!FU&v7148=0:E;
!!VRv7147:*-1;
!!IF&1000:Q1/21/v7147/17/v7148/1^Местные жители довольны, что Вы положили конец проблемам, связанным с этими существами.^;
!!HE-1:Edv7148;
!!VRv7147:S0;
!!VRv7148:S0;

!$OB54&v7147>0;
!!OB998:T?i;
!!FU&i=54:E;
!!OW:R-1/6/dv7146;
!!IF&1000/v7146>0:Q1/21/v7147/6/v7146/1^Среди барахла, которое осталось здесь, Вы произвели масштабный обыск. Это дало положительные результаты!^;
!!VRi:Sv7146 :1000 -2 R7;
!!IF&i>0/1000:Q1/0/i/1^Еще тут есть древесина!^;
!!OW&i>0:R-1/0/di;
!!VRi:-10 R12;
!!IF&i>0/1000:Q1/2/i/1^Эти камни очень похожи на руду!^;
!!OW&i>0:R-1/2/di;
!!VRi:-10 R12;
!!VRj:Sv7147 &255; восстановление типа монстра
!!VRv7147:S0;
!!VRv7146:S0;
!!FU&i<=0:E; далее уникальные бонусы. Даже артефакты!
!!IF&j=143:Q1/5/i/1^{Сокровища}

Воры припрятали драгоценности!^;
!!OW&j=143:R-1/5/di;
!!IF&j>41/j<56:Q1/3/i/1^{Сокровища}

Создания ада прячут серу!^;
!!OW&j>41/j<56:R-1/3/di;
!!IF&j>14/j<28:Q1/4/i/1^{Сокровища}

А вот и кристаллы!^;
!!OW&j>14/j<28:R-1/4/di;
!!IF&j>27/j<32:Q1/1/i/1^{Сокровища}

Ртуть им понадобилась...^;
!!OW&j>27/j<32:R-1/1/di;
!!MA:Xj/?m;
!!VRm:&896; оставить все кроме необходимого
!!FU&m=0:E; выход, если монстрики хилые
!!UN:J6/2/?m; слабый артефактик
!!IF:Q1/8/m/1^{Сокровища}

Вы нашли наиполезнейший артефакт!!!^;
!!HE-1:A4/m;

**END** **Бонусы за нейтралов** **END**

**START** **Строительство и уничтожение знаков** **START**
**для героев с навыком "Логистика"

**строительство правым кликом по кнопке "Наземн./Подз. мир"
**стоимость 5 единиц дерева и 800 очков передвижения
**если выключен скрипт "надписи на знаках", то все бесполезно

**разрушение знаков: вы получаете 1 дерева
**и плюс 1 за каждый уровень навыка "Поместья"

**КОМПЬЮТЕР всегда рушит знаки и получает за них по 6 дерева
**независимо от навыков и т. д.
!$OB91&1000;
!!SG998:M?z1;
!!IF:Q1^%Z1

{Хотите уничтожить знак?}
{Вы получите 1 дерева}
{плюс 1 за каждый уровень}
{навыка Поместья}^;
!!FU&-1:E;
!!HE-1:S2/?i; проверка на навык логистика
!!IF&i=0:Q1/20/9/1^{Уничтожение знаков}

К сожалению, Ваш герой не обладает необходимым уровнем навыка Логистика.^;
!!FU&i=0:E;
!!HE-1:S13/?i;
!!VRi:+1;
!!UN:Ov998/v999/v1000/1;
!!IF:Q1/0/i/1^{Уничтожение знаков}

В ближайшей деревне Ваш герой обменял высококачественный брус с магической защитой от гниения, из которого был сделан знак, на {%Vi} единиц обычной древесины.^;
!!OW:R-1/0/di;
!!HE-1:Wd-500;

!$OB91&-1000; если компьютер
!!UN:Ov998/v999/v1000/1;
!!OW:R-1/0/d6;

!?CM;
!!CM:F?i;
!!FU&i<>512:E; Right Click
!!CM:I?i;
!!FU&i<>4:E; иконка смены миров
!!OW:A-1/?i;
! !IF&i=-1:M^{Строительство знаков}

К сожалению, Вы не выбрали героя для выполнения операции. Герой должен стоять на {том} месте, где будет находиться знак.^;
!!FU&i=-1:E;
!!HE-1:S2/?i; проверка на навык логистика
! !IF&i=0:Q1/20/9/1^{Строительство знаков}

К сожалению, {этот} герой не обладает необходимым уровнем навыка Логистика.^;
!!FU&i=0:E;
!!HE-1:W?i;
! !IF&i<400:M^{Строительство знаков}

К сожалению, Ваш герой слишком устал сегодня.^;
!!FU&i<400:E;
!!HE-1:P?v998/?v999/?v1000;
!!TR998:T?i/d/d/d/d/d/d/d;
! !IF&i>7:M^{Строительство знаков}

Этот ландшафт непригоден.^;
!!FU&i>7:E;
!!OB998:T?i;
!!IF&i=91:M^{Строительство знаков}

Здесь уже стоит знак.^;
! !IF&i<>0:M^{Строительство знаков}

Это место непригодно.^;
!!FU&i<>0:E;
!!OW:R-1/0/?i;
! !IF&i<5:Q1/0/5/1^{Строительство знаков}

У вас не хватает дерева.^;
!!FU&i<5:E;
!!IF:Q1/0/5/2^{Строительство знаков}

Вы {можете} разместить знак на этом месте.
У Вас хватает ресурсов.
Выбранный герой изучил {Логистику} и
обладает достаточным количеством
очков передвижения.
Установка будет стоить {5 дерева} и
{800 очков} передвижения.

Вы желаете установить знак?^;
!!FU&-1:E;
!!OW:R-1/0/d-5;
!!HE-1:Wd-800;
!!TR998:T?j/d/d/d/d/d/d/d;
!!UN:Iv998/v999/v1000/91/0/91/0/j/1;
!!VRj:S7788; отключить справку ровно на 1 раз
**END** **Строительство и уничтожение знаков** **END**

**информация по возможностям
!?CM;
!!CM:F?i;
!!FU&i<>512:E; Right Click
!!CM:I?i;
!!FU&i<>4:E; иконка смены миров
!!CM:R0; отменить стандартную реакцию
!!IF&j<>7788:Q1^{Новые возможности игры}
Автор: FBX

Вы желаете узнать о возможностях, которые теперь предоставляет эта кнопка?^;
!!IF&1/j<>7788:M^{Новые возможности игры}
Версия скрипта 1.01b
Автор: FBX

Некоторые {функции} вызываются правым кликом по кнопке "Подземный/Наземный мир".

1) {Теперь вы можете получить бонус} в виде золота (а иногда и дерева и руды) при победе над {нейтральными монстрами}. Бонус выше от существ больших уровней. Если монстр был отпущен или присоединен, дается {опыт} в размере 1/3 от боевого. Также есть дополнительные поощрения: за победу над созд. инферно - сера, а мощные существа - даже слабенький {артефакт} и т. д.

2) {ТЕПЕРЬ МНОГИЕ СТРОЕНИЯ НА КАРТЕ} могут подействовать {НЕ ТАК}, как Вы привыкли видеть, а гораздо интереснее. (Изредка эффект отрицательный.) Компьютер теперь может получить от некоторых объектов более сильный бонус. В общем, играйте и выигрывайте.
{Реализовано:} Сад Откровения, Камень Знаний, Звездная ось, Башня Марлетто, Лагерь наемников.
{Ожидается:} Расширение предыдущих + в список попадут еще.

3) Вы можете установить знак на любой свободной клетке карты. Для этого потребуется {5 единиц дерева}, знание как минимум {Основной Логистика} плюс немного очков передвижения (800). Что бы создание знаков имело смысл, нужно включить опцию замены текста на знаках. Зачем нужны знаки? Вы можете оставить заметку для себя, или для других при игре в Multiplayer. Такая функция не способна кардинально изменить геймплэй.
Вызывается правым кликом по кнопке "Подземный/Наземный мир".

4) Разрушение знаков. Компьютер уничтожает все знаки и получает по 6 дерева за каждый. Игрок может уничтожить знак, если обладает необходимым уровнем навыка логистика (основной). Без навыка {Поместья} дается 1 дерева, плюс один за каждый уровень навыка.

5) Засыпание колодцев требует {10 руды}, не менее 5000 опыта и {Основной Магия Земли}. Отнимаются все очки передвижения. Суть этой функции в принципиально новой возможности - лишения врага маны на его же территории. Тактические ситуации придумайте сами .

6) {Ожидается:} создание колодцев (не до конца продумана система ограничений)

7) Теперь Ваш герой может купить {Книгу Заклинаний} в Саду Откровения, Звездной оси или Школе Магии.
Везде разные цены. Будет модифицировано.

Пока эффект от этих разработок не такой ярковыраженный. В следующих версиях скрипта будет гораздо интереснее.^;
!!VRj:S0; сброс


**START** **Рытье и засыпание колодцев** **START**
**Засыпание убирает желтый квадрат, ставит красный.
**Стоит это всех очков передв. герою (не меньше 1000)
**Сменяется хинт. ТРЕБОВАНИЯ: Магия земли не ниже продв.
** 10 руды Опыт не меньше 5000

**РЫТЬЕ КОЛОДЦЕВ: нужно 5 руды, 5 дерева, Эксперт Маг.земли
** опыт >=18000, один раз для каждого героя.
**Через неделю после активации игрок получает золота
**(смотря какая сложность и день игры), колодец станет доступен

!$OB49&1000; после посещения колодца
!!IF:Q1/2/10/20/54/17/5000/2^{Засыпание колодцев}

Вы можете засыпать этот колодец.
Это стоит {10 единиц} руды.

Вашему герою необходимо:
знание {Магия земли};
не менее {5000} опыта.^;
!!FU&-1:E;
!!HE-1:E?i;
!!IF&i<5000:Q1/17/5000/1^{Засыпание колодцев}

Ваш герой слишком неопытен.^;
!!FU&i<5000:E;
!!OW:R-1/2/?i;
!!IF&i<10:Q1/2/10/1^{Засыпание колодцев}

Вы не обладаете необходимым количеством {руды} для выполнения операции.^;
!!FU&i<10:E;
!!HE-1:S17/?i;
!!IF&i=0:Q1/20/54/1^{Засыпание колодцев}

Нужно знать {Магия Земли} как минимум основной.^;
!!FU&i=0:E;
!!HE-1:W?i;
!!IF&i<1000:M^{Засыпание колодцев}

Ваш герой слишком устал сегодня. Попробуйте завтра, со свежими силами!^;
!!FU&i<1000:E;
!!HE-1:W0;
!!OW:R-1/2/d-10;
!!OB998:Hz49;
!!TR998:E1 P0;
!!IF:M^{Засыпание колодцев}

Теперь это засыпанный колодец. Вот и стоит ваш герой, как дурак, у засыпанного колодца!^;


**END** **Рытье и засыпание колодцев** **END**

**START** **Редкие случайности для разнообразия игры** **START**
**[ШАНС 2Камни знаний, сады откровения, звездные оси,
**башни марлетто и лагери наемников могут дать от -100% до 300%
!?OB32&1000;
!!VRz1:S^{Сад откровения}
Как правило, дает
{+1} знания^;
!!FU494:P2;
!?OB61&1000;
!!VRz1:S^{Звездная ось}
Как правило, дает
{+1} колдовской силы^;
!!FU494:P4;
!?OB51&1000;
!!VRz1:S^{Лагерь наемников}
Как правило, дает
{+1} атаки^;
!!FU494:P3;
!?OB23&1000;
!!VRz1:S^{Башня Марлетто}
Как правило, дает
{+1} защиты^;
!!FU494:P1;

!?FU494; x1 - type;
!!OB998:C?j;
!!HE-1:Vx1/j/?k; проверка
!!FU&k=1:E; выход, если посещено
!!VRi:S0 R39; случайное число от 0 до 39
!!FU&i>3:E; шанс где-то 10%
!!HE-1:Vx1/j/1; Типа посещено
!!IF&i=0:Q1/13/3/1^%Z1

Похоже, Вам не повезло. Тут ничем не смогут Вам помочь.^;
!!OB998&i=0:M-1/1/0;
!!FU&i=0:E; для оптимизации
**нулевой вариант - пустота
!!VRk&x1=1:S32; !!VRk&x1=2:S34; расстановка данных
!!VRk&x1=3:S31; !!VRk&x1=4:S33; 31-34 - коды картинок
!!HE-1:F?y1/?y2/?y3/?y4; запишем текущие навыки
!!VRm&i=1:S-1; если 1 вариант (м=0) то снижение параметра
!!VRm&i=2:S2; !!VRm&i=3:S3; если 2 или 3 то +1/+2 соответственно
!!VRy1&k=31:+m; !!VRy2&k=32:+m; вся суть
!!VRy3&k=33:+m; !!VRy4&k=34:+m;
!!IF&i=1:Q1/k/-1/1^%Z1

Похоже, Вам {крупно} не повезло. Перед тем, как посетить это место, Вы встретили мудреца, который очень многое вам рассказал. Особенно Вам запомнилось то, что информация, которую может дать учитель, может оказаться Вам известна. Раздумывая над услышанным, Вы стали путаться в своих знаниях...^;
!!IF&i=2:Q1/k/2/1^%Z1

Похоже, Вам повезло. Здесь Вам стали известны довольно интересные факты...^;
!!IF&i=3:Q1/k/3/1^%Z1

Похоже, Вам {крупно} повезло. Это место - просто кладезень ценной информации!^;
!!HE-1:Fy1/y2/y3/y4; сохраним навыки
!!OB998:M-1/1/0; отключим сообщение

!?OB100&-1000; немного читерства в пользу компа имба та еще
!!VRi:Sc :11 +1 *c *80 +1200; хи-хи - на первый день 2280
!!HE-1:Edi; а в начале 4-го месяца - 56600 - сами считайте!
**КАМЕНЬ ЗНАНИЙ: есть шанс на случайное значение
**опыта от -1000 до +3000
**есть шанс получить 15000 опыта
**есть шанс истратить ману на опыт
!?OB100&1000; камень учения
!!VRi:S0 R14;
!!FU&i>0:E;
!!ST998:N?j;
!!HE-1:V0/j/?i;
!!FU&i=1:E;
!!HE-1:V0/j/1;
!!VRi:S-1000 R4000;
!!IF&i<-50:Q1/17/i/1^{Камень учения}

Вместо ответов на вопросы Вы узнали страшное... Теперь Вы совершите меньше опрометчивых поступков, так как оказалось, что не все ваши знания достоверны.^;
!!IF&i>50/i<970:Q1/17/i/1^{Камень учения}

Камень вел себя как обычно. Но Вы с досадой заметили, что информации на нем гораздо меньше, чем обычно...^;
!!IF&i>1030:Q1/17/i/1^{Камень учения}

Вы были приятно удивлены ценнейшей информацией, которую открыл для Вас {Камень}. Оказывается, существует {заклинание}, способное зарядить камень новой энергией. Но где его искать - этого вам камешек не сообщил...^;
!!IF&i>=-50/i<=50:M^{Камень учения}

Камень ничего интересного для Вас не открыл.^;
!!IF&i>=970/i<=1030:Q1/17/15000/1^{Камень учения}

Это просто чудеса какие-то! Прям джек-пот...^;
!!VRi&i>=970/i<=1030:S15000; для такой ничтожной вероятности пустяки, зато сколько радости игроку ))
!!HE-1:Edi;
!!OB998:M-1/1/0;

!?OB100&1000; шанс истратить всю ману на опыт
!!VRi:S0 R21;
!!FU&i>0:E;
!!ST998:N?j;
!!HE-1:V0/j/?i;
!!FU&i=1:E; еще одна проверочка
!!HE-1:V0/j/1;
**начинается основная часть
!!HE-1:I?j; вот и мана
!!VRi:S109 -20 R40 *j; вот и опыт
!!IF:Q1/17/i/35/j/2^{Камень знаний}

Не успев подойти к {камню знаний}, Вы встретили мудреца, который рассказывал и рассказывал о великих подвигах, малоизвестных заклинаниях...

Вот одно из них повергло Вас в восторг. Оказывается, можно {заряжать} Камни Знаний новой энергией! Вы чуть не взлетели, быстро подходя к камню. Мудрец лишь сказал: "Я предупреждаю тебя, путник! Это проклятье, это утопия..."

У Вас есть {%Vj очков} магии. Вы хотите рискнуть всем ради знания?^;
!!IF&-1:Q1/17/1000/1^{Камень знаний}

"Ты достоин уважения, путник", -
- сказал старец, -
"Лишь немногие смогли устоять".^;
!!HE-1&-1:Ed1000;
!!FU&-1:E;
!!IF&j<5:Q1/35/5/1^{Камень знаний}

Тебе повезло, путник. У тебя не хватит магических сил...^;
!!FU&j<5:E;
**а вот результат жадности:
!!HE-1:I3; немного останется
!!VRj:Si :1000 -3;
!!HE-1&j>0:Tv998/v999/v1000/93/j; драка будет без маны...
!!HE-1:O?j;
!!FU&j=-1:E;
!!HE-1:Edi; опыт тоже чуть по-позже...
!!IF:M^{Проклятье!}^;
!!HE-1:Y27/d/20/1;
!!HE-1:Y28/d/8/1;
!!HE-1:Y6/10/8/1;
!!HE-1:Y8/d/8/1;
!!OB998:M-1/1/0;

!?OB22; ПОСЕЩЕНИЕ СКЕЛЕТА - коррекция
!!UN:J2/?i; сложность игры
!!VRj&-1000:S4 -i; для компа наоборот
!!VRj&1000:Si;
!!VRi:S0 Rj; расстановка вероятности.
!!SK998:S0; выключить артефакт
** 200%(невозможно) - нет изменений, 80%(легко) - артефакт есть всегда
!!FU&i>0:E;
!!UN:J6/2/?j; случайный артефакт
!!SK998:S1;
!!SK998:Aj; установить артефакт

!$OB22; ПОСЛЕ ПОСЕЩЕНИЯ СКЕЛЕТ ИСЧЕЗАЕТ
!!UN:Ov998/v999/v1000/1;

!$OB61; звездная ось - ПОКУПКА КНИГИ ЗАКЛИНАНИЙ
!!FU495:P3000;

!$OB32; сад откровения тоже
!!FU495:P3200;

!$OB47; школа магии
!!FU495:P1900;

!?FU495&-1000; для компа
!!HE-1:A2/0/?i/d;
!!HE-1&i=0:A4/1000;

!?FU495&1000; x1 - gold
!!HE-1:A2/0/?i/d;
!!FU&i>0:E; если есть книга заклов
!!IF:Q1/8/0/6/x1/2^{Книга заклинаний}

У Вас нет книги заклинаний! Какой ужас... Сейчас никто не ходит без Книги Заклинаний... Однако, мы можем вам помочь! Великолепный экземпляр, скажем, м-м-м... за {%X1 золотом}. Вы согласны?^;
!!FU&-1:E; ну и не надо
!!OW:R-1/6/?i;
!!IF&i<x1:Q1/6/x1/8/0/1^{Книга заклинаний}

Проблемы с золотом? Очень жаль. Приходите, когда будут деньги.^;
!!FU&i<x1:E;
!!VRi:-x1;
!!OW:R-1/6/i;
!!HE-1:A4/1000;
!!IF:Q1/8/0/1^{Книга заклинаний}

Вы приобрели книгу заклинаний. Дороговато, правда, стоила...^;

**END** **Редкие случайности для разнообразия игры** **END**